Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Tyrion.AI_Action

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431
00432
00433
00434
00435
00436
00437
00438
00439
00440
00441
00442
00443
00444
00445
00446
00447
00448
00449
00450
00451
00452
00453
00454
00455
00456
00457
00458
00459
00460
00461
00462
00463
00464
00465
00466
00467
00468
00469
00470
00471
00472
00473
00474
00475
00476
00477
00478
00479
00480
00481
00482
00483
00484
00485
00486
00487
00488
00489
00490

    //=====================================================================
    // AI_Action
    // The Tyrion Action class: *How* an AI does something
    //
    // Extends AI_RunnableAction with the ability to post and manage goals
    //=====================================================================

    class AI_Action extends AI_RunnableAction implements ISensorNotification
    	abstract
        native;

    //=====================================================================
    // Constants

    //=====================================================================
    // Variables

    var() const editconst class<AI_Goal> satisfiesGoal;	// class that this action satisfies
    var AI_Goal achievingGoal;							// goal being achieved by this action
    var array<AI_Goal> childGoals;						// child actions that are running
    var NS_Action nsChild;								// a Tyrion action can start a Cersei child (just one for now)
    var float heuristicValue;							// storage for selectionHeuristic()
    var int resourceUsage;								// bits indicate what leaf resources this action requires
    var int waitingForGoalsN;							// number of goal completions this action is waiting for

    //=====================================================================
    // Action Idioms

    //---------------------------------------------------------------------
    // Called by an action when it has successfully accomplished its goal
    // (No state code following this function is executed)

    latent function succeed()
    {
    	achievingGoal.markGoalAsAchieved();		// may release the goal
    	achievingGoal.notifyCompletion(true);

    	if (achievingGoal.parentAction != None )
    		achievingGoal.parentAction.goalAchievedCB( achievingGoal, self );

    	achievingGoal.handleGoalSuccess();

    	if ( achievingGoal.achievingAction != None )	// optimization: check if markGoalAsAchieved already called removeAction...
    		removeAction();

    	achievingGoal.Release();				// balances AddRef done in initAction
    	achievingGoal = None;

    	yield();
    }

    event instantSucceed()
    {
    	achievingGoal.markGoalAsAchieved();

    	if (achievingGoal.parentAction != None )
    		achievingGoal.parentAction.goalAchievedCB( achievingGoal, self );

    	achievingGoal.handleGoalSuccess();

    	if ( achievingGoal.achievingAction != None )	// optimization: check if markGoalAsAchieved already called removeAction...
    		removeAction();

    	achievingGoal.Release();				// balances AddRef done in initAction
    	achievingGoal = None;

    	// we need a goto state if the instantSucceed is called from state code
    	// (rather than the normal latent succeed function)
    	gotostate('');
    }

    //---------------------------------------------------------------------
    // Called by an action when it has failed at accomplishing its goal
    // bRemoveGoal: when true, goal is definitely removed (even if normally wouldn't be)
    // (called from callbacks)

    event instantFail( ACT_ErrorCodes errorCode, optional bool bRemoveGoal )
    {
    	if ( achievingGoal == None )
    		return;						// goal had instantFail called on it already

    	if ( bRemoveGoal )
    		achievingGoal.bTryOnlyOnce = true;

    	//log( "1." @ name @ "instantFail called with code" @ errorcode );

    	achievingGoal.markGoalAsFailed();
    	achievingGoal.notifyCompletion(false);

    	if (achievingGoal.parentAction != None )
    		achievingGoal.parentAction.goalNotAchievedCB( achievingGoal, self, errorCode );

    	achievingGoal.handleGoalFailure();

    	//log( "2." @ name @ "being removed by instantFail" );
    	removeAction();		// references achievingGoal

    	achievingGoal.Release();				// balances AddRef done in initAction
    	achievingGoal = None;

    	// we need a goto state if the instantSucceed is called from state code
    	// (rather than the normal latent succeed function)
    	gotostate('');
    }

    //---------------------------------------------------------------------
    // Called by an action when it has failed at accomplishing its goal
    // bRemoveGoal: when true, goal is definitely removed (even if normally wouldn't be)
    // (called from state code; no state code following this function is executed)

    latent function fail( ACT_ErrorCodes errorCode, optional bool bRemoveGoal )
    {
    	instantFail( errorCode, bRemoveGoal );
    	yield();
    }

    //---------------------------------------------------------------------
    // Action idiom: waitForGoal
    // Pauses goal poster until sub-goal 'goal' matches some action and
    // this matching action completes (fails or succeeds).
    // If "bTryOnlyOnce" is set, only tries to achieve the goal once

    latent function waitForGoal( AI_Goal goal, optional bool bTryOnlyOnce )
    {
    	waitingForGoalsN = 1;
    	goal.bWakeUpPoster = true;
    	goal.bTryOnlyOnce = bTryOnlyOnce;
    	pause();
    }

    //---------------------------------------------------------------------
    // Action idiom: interruptGoalIf
    // Keeps goal poster running in parallel, and should the function
    // 'goalTest' in the class 'condition' ever evaluate to true,
    // unposts 'goal'

    latent function interruptGoalIf( AI_Goal goal, class<IBooleanGoalCondition> condition )
    {
    	while ( !goal.hasCompleted() )
    		if ( condition.static.goalTest( goal ))
    		{
    			goal.unPostGoal( self );
    			break;
    		}
    		else
    		{
    			yield();
    		}
    }

    //---------------------------------------------------------------------
    // Action idiom: waitForAllGoals
    // continues execution when all goals have matched and succeeded or when
    // any goal has matched and failed

    latent function waitForAllGoals( optional AI_Goal goal1,
    					 optional AI_Goal goal2, optional AI_Goal goal3, optional AI_Goal goal4,
    					 optional AI_Goal goal5, optional AI_Goal goal6, optional AI_Goal goal7,
    					 optional AI_Goal goal8, optional AI_Goal goal9)
    {
    	waitingForGoalsN = 0;
    	if ( goal1 != None )
    	{
    		waitingForGoalsN++;
    		goal1.bWakeUpPoster = true;
    	}
    	if ( goal2 != None )
    	{
    		waitingForGoalsN++;
    		goal2.bWakeUpPoster = true;
    	}
    	if ( goal3 != None )
    	{
    		waitingForGoalsN++;
    		goal3.bWakeUpPoster = true;
    	}
    	if ( goal4 != None )
    	{
    		waitingForGoalsN++;
    		goal4.bWakeUpPoster = true;
    	}
    	if ( goal5 != None )
    	{
    		waitingForGoalsN++;
    		goal5.bWakeUpPoster = true;
    	}
    	if ( goal6 != None )
    	{
    		waitingForGoalsN++;
    		goal6.bWakeUpPoster = true;
    	}
    	if ( goal7 != None )
    	{
    		waitingForGoalsN++;
    		goal7.bWakeUpPoster = true;
    	}
    	if ( goal8 != None )
    	{
    		waitingForGoalsN++;
    		goal8.bWakeUpPoster = true;
    	}
    	if ( goal9 != None )
    	{
    		waitingForGoalsN++;
    		goal9.bWakeUpPoster = true;
    	}

    	pause();
    }

    // The goals list will not be cleaned up by the stack cleanup function
    // because is currently doesn't handle array parameters so the function
    // could cause crashes when saving the game.
    latent function waitForAllGoalsInList(array<AI_Goal> goals)
    {
    	local int i;

    	waitingForGoalsN = 0;

    	for( i = 0; i < goals.Length; ++i )
    	{
    		if (goals[i] != None)
    		{
    			waitingForGoalsN++;
    			goals[i].bWakeUpPoster = true;
    		}
    	}

    	pause();
    }

    //---------------------------------------------------------------------
    // Action idiom: waitForAnyGoals
    // continues execution when any one of the specified goals has matched and completed

    latent function waitForAnyGoal(AI_Goal goal1,
    					 optional AI_Goal goal2, optional AI_Goal goal3, optional AI_Goal goal4,
    					 optional AI_Goal goal5, optional AI_Goal goal6, optional AI_Goal goal7 )
    {
    	waitingForGoalsN = 1;
    	goal1.bWakeUpPoster = true;

    	if ( goal2 != None )
    		goal2.bWakeUpPoster = true;

    	if ( goal3 != None )
    		goal3.bWakeUpPoster = true;

    	if ( goal4 != None )
    		goal4.bWakeUpPoster = true;

    	if ( goal5 != None )
    		goal5.bWakeUpPoster = true;

    	if ( goal6 != None )
    		goal6.bWakeUpPoster = true;

    	if ( goal7 != None )
    		goal7.bWakeUpPoster = true;

    	pause();
    }

    //---------------------------------------------------------------------
    // Action idiom: waitForAllGoalsConsidered
    // continues execution when all one of the specified goals have been considered
    // by the goal matching process (whether an actionw as actually started to
    // achieve them or not)

    latent function waitForAllGoalsConsidered(AI_Goal goal1,
    					 optional AI_Goal goal2, optional AI_Goal goal3, optional AI_Goal goal4,
    					 optional AI_Goal goal5, optional AI_Goal goal6, optional AI_Goal goal7 )
    {
    	while ( !(( goal1 == None || goal1.wasConsidered() ) &&
    			  ( goal2 == None || goal2.wasConsidered() ) &&
    			  ( goal3 == None || goal3.wasConsidered() ) &&
    			  ( goal4 == None || goal4.wasConsidered() ) &&
    			  ( goal5 == None || goal5.wasConsidered() ) &&
    			  ( goal6 == None || goal6.wasConsidered() ) &&
    			  ( goal7 == None || goal7.wasConsidered() )) )
    		yield();
    }

    //---------------------------------------------------------------------
    // Action idiom: waitForResourcesAvailable
    // legspriority:  priority of the sub-goal that will be posted on the legs (0 if no goal)
    // armsPriority:  priority of the sub-goal that will be posted on the arms (0 if no goal)
    // headPriority:  priority of the sub-goal that will be posted on the arms (0 if no goal)
    //
    // todo: make event-based

    latent function waitForResourcesAvailable( int legsPriority, int armsPriority, optional int headPriority )
    {
    	while ( !resource.requiredResourcesAvailable( legsPriority, armsPriority, headPriority ) )
    		yield();
    }

    //=====================================================================
    // Functions

    //---------------------------------------------------------------------
    // ISensorNotification implementation

    function OnSensorMessage( AI_Sensor sensor, AI_SensorData value, Object userData );

    function AI_Resource getResource()
    {
    	return resource;
    }

    //---------------------------------------------------------------------
    // Initialize a new action
    // 'goal' is the AI_Goal the action is achieving
    // 'r' is the resource the action is running on
    // Typically called by the resource - sets achievingAction

    event initAction(AI_Resource r, AI_Goal goal)
    {
    	resource = r;
    	achievingGoal = goal;
    	goal.achievingAction = self;

    	achievingGoal.AddRef();				// Released when action succeeds or fails

    	GotoState( 'Running' );
    }

    //---------------------------------------------------------------------
    // increments refCount and returns object

    function AI_Action myAddRef()
    {
    	AddRef();
    	return self;
    }

    //---------------------------------------------------------------------
    // Interrupt an action
    // Stop a running (or idle) action; reclaim its resources
    // Typically called by the resource - clears achievingAction

    function interruptAction()
    {
    	// Remove this if "interruption callback" never gets used
    	if (achievingGoal.parentAction != None )
    		achievingGoal.parentAction.goalNotAchievedCB( achievingGoal, self, ACT_ErrorCodes.ACT_INTERRUPTED );

    	achievingGoal.markGoalAsFailed();

    	super.interruptAction();
    }

    //---------------------------------------------------------------------
    // Terminate an action
    // Typically called by the resource - clears achievingAction and usedByAction

    function removeAction()
    {
    	//@@@ log( "## Removing" @ name @ resource.pawn().name );

    	// Recursively remove all the child goals (and their actions)
    	while ( childGoals.length > 0 )
    	{
    		//log( name $ ". RemoveAction:" @ childGoals[0].name @ "removed from" @ childGoals[0].resource.name );
    		childGoals[0].resource.removeGoal( childGoals[0] );	// changes childGoals.length...
    	}

    	// remove any Cersei children
    	if ( nsChild != None )
    	{
    		nsChild.removeAction();
    		nsChild = None;
    	}

    	// fiddle with goals
    	achievingGoal.achievingAction = None;

    	if ( self == resource.usedByAction )
    		resource.usedByAction = None;

    	Super.removeAction();
    }

    //---------------------------------------------------------------------
    // Run an action
    // Typically called by the resource

    function runAction()
    {
    	if ( !resource.isActive() )
    	{
    		if ( (resource.pawn() != None) && resource.pawn().logTyrion )
    			log( name @ "stopped. Resource is dead" );

    		instantFail( ACT_RESOURCE_INACTIVE );
    		return;
    	}

    	Super.runAction();
    }

    //---------------------------------------------------------------------
    // Selection Heuristic
    // Returns a value in the range [0, 1], indicating how suitable this action is for achieving this goal

    #if IG_TRIBES3
    static
    #endif
    function float selectionHeuristic( AI_Goal goal )
    {
    	return 1.0;
    }

    #if IG_TRIBES3
    //---------------------------------------------------------------------
    // Add action to childAction list

    function setChildReference( NS_Action child )
    {
    	nsChild = child;
    }

    //---------------------------------------------------------------------
    // Remove action from childAction list

    function removeChildReference( NS_Action child )
    {
    	if ( nsChild == child )
    		nsChild = None;
    }

    //---------------------------------------------------------------------
    // Return the Cersei child?

    function NS_Action getChildReference()
    {
    	return nsChild;
    }
    #endif

    //---------------------------------------------------------------------
    // Callback: action 'child' achieved 'goal'
    // Note: When writing action-specific callbacks, call super.<callback> first

    function goalAchievedCB( AI_Goal goal, AI_Action child )
    {
    	if ( goal.bWakeUpPoster && ( --waitingForGoalsN == 0 ) && bIdle )
    	{
    		runAction();
    	}
    }

    //---------------------------------------------------------------------
    // Callback: action 'child' did not succeed in achieving 'goal'
    // ('errorCode' gives the reason)
    // Note: When writing action-specific callbacks, call super.<callback> first

    function goalNotAchievedCB( AI_Goal goal, AI_Action child, ACT_ErrorCodes errorCode )
    {
    	//log( name $ ".goalNotAchievedCB called with" @ goal.name );

    	if ( goal.bWakeUpPoster && bIdle )
    	{
    		runAction();
    	}
    }

    //---------------------------------------------------------------------
    // Callback: resource 'stolenResource' stolen from 'goal'
    // Note: When writing action-specific callbacks, call super.<callback> first

    function resourceStolenCB( AI_goal goal, AI_Resource stolenResource )
    {
    	if ( resource.pawn().logTyrion )
    		log( "---> resource" @ stolenResource.name @ "stolen from" @ goal.name );

    	if ( goal.bTerminateIfStolen )
    	{
    		if ( resource.pawn().logTyrion )
    			log( "--->" @ name @ "terminating" );
    		instantFail( ACT_REQUIRED_RESOURCE_STOLEN );
    	}
    }

    //=====================================================================

    defaultproperties
    {
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:54:12.000 - Creation time: st 23.5.2018 00:10:40.912 - Created with UnCodeX