Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Gameplay.Ragdoll

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360

    // the ragdoll class extends a pawn derived class to add support for ragdoll physics on death.

    class Ragdoll extends Rook
    	native;

    var(Ragdoll) float ragdollLifeSpan;			// Maximum time the ragdoll will be around.

    var(Ragdoll) class<HavokSkeletalSystem>	HavokParamsClass;

    var bool bPlayedDeath;

    var (Ragdoll) float jetpackDuration;        // amount of time to apply the jets for on death
    var (Ragdoll) float jetpackLinearForce;     // amount of jetpack force to apply to jetpack bone with linear only
    var (Ragdoll) float jetpackTwirlyForce;     // amount of jetpack force to apply to jetpack bone with rotational component

    var (Ragdoll) float ragdollScale;           // scale factor between ragdoll mass and actual mass. eg. 10 means that actual mass is 10x ragdoll mass (ragdoll 10 -> actually 100kilos)

    var (Ragdoll) float ragdollMaximumImpulse;  // any impulse above this amount is clamped. stops retarded ragdolls from oversized explosions from the designers =/

    var (Ragdoll) bool disableJetpackDeath;     // flag to disable jetpack death

    var (Ragdoll) float ragdollDeathLift;       // ragdoll lift on death impulse

    var bool jetpack;                           // true if jetpack is applying force
    var float jetpackTime;                      // time spend applying jetpack force to ragdoll so far
    var bool ragdollTouchedGround;              // true if the ragdoll has hit ground (go into twirly mode)
    var int ragdollTickCount;                   // tick count since ragdoll started

    var vector TearOffLocation;					// set on server to replicate a location change at the instant of death
    var bool bTearOffLocationValid;

    var vector ragdollInheritedVelocity;        // stored velocity for initial ragdoll velocity inheritance

    enum MovementState
    {
    	MovementState_Stand,
    	MovementState_Walk,
    	MovementState_Run,
    	MovementState_Sprint,
    	MovementState_Ski,
    	MovementState_Slide,
    	MovementState_Stop,
    	MovementState_Airborne,
    	MovementState_AirControl,
    	MovementState_Thrust,
    	MovementState_Swim,
    	MovementState_Float,
    	MovementState_Skim,
    	MovementState_ZeroGravity,
    	MovementState_Elevator,
    };

    var MovementState movement;                 // current movement state

    replication
    {
    	// infrequently changing variables
    	reliable if (ROLE == ROLE_Authority)
    		HavokParamsClass;

    	reliable if (bTearOff && bNetDirty && (Role==ROLE_Authority))
    		TearOffLocation, bTearOffLocationValid;
    }

    simulated function Tick(float DeltaTime)
    {
        local vector jetpackForce;
        local rotator jetpackRotation;
        local coords jetpackCoords;

    	super.Tick(DeltaTime);

    	if (Level.NetMode == NM_DedicatedServer)
    		return;

        // assume dead if bTearOff

        if (bTearOff)
        {
            if ( !bPlayedDeath )
                PlayDying(HitDamageType, TakeHitLocation);
        }

        // cool thrust on ragdoll

        if (bPlayedDeath && jetpack)
        {
            // start thrust effect on second tick into ragdoll (after physics change stops effects)

            ragdollTickCount++;

            if (ragdollTickCount==2)
                StartLoopingEffect("MovementThrust");

            // apply ragdoll thrust forces

            jetpackTime += deltaTime;

            if (jetpackTime<jetpackDuration)
            {
                // apply linear jetpack force

                if (havokSkeletalRotationSpeed<500 && vsize(velocity)<2000)
                {
                    jetpackRotation = GetBoneRotation('Bip01 Spine');

                    jetpackForce = (jetpackLinearForce / ragdollScale) * vector(jetpackRotation);

                    HavokImpartLinearForceAll(jetpackForce);
                }

                // apply twirly jetpack force if collided last update

                if (havokSkeletalRotationSpeed<50 || vsize(velocity)<500)
                {
                    jetpackCoords = GetBoneCoords('JetpackBone');
                    jetpackRotation = GetBoneRotation('JetpackBone');

                    if (jetpackCoords.origin==jetpackCoords.origin)
                        HavokImpartForce((-jetpackTwirlyForce / ragdollScale) * vector(jetpackRotation), jetpackCoords.origin);
                }
            }
            else
            {
    	        StopLoopingEffect("MovementThrust");

    	        jetpack = false;
    	    }
    	}
    }

    // Notes about how this replicates to clients:
    // - The server will get PlayDying called and go into ragdoll here. This function sets bTearOff to true
    // - bTearOff is replicated to clients, who in their Tick function detect it set to true and call PlayDying locally
    // - Dedicated servers need to just keep the player hanging around without it going into ragdoll

    simulated function PlayDying(class<DamageType> DamageType, vector HitLoc)
    {
    	if (bPlayedDeath)
    		return;

        bCanTeleport = false;
        bReplicateMovement = false;
        bTearOff = true;
        bPlayedDeath = true;

    	HitDamageType = DamageType;     // these are replicated
        TakeHitLocation = HitLoc;

        GotoState('Dying');

    	if ( Level.NetMode != NM_DedicatedServer )
    	{
    		if (StartHavokRagdoll())
    			return;
    	}

    	SetPhysics(PHYS_None);
    }

    simulated function bool StartHavokRagdoll()
    {
    	local HavokSkeletalSystem HavokSkeletal;
    	local Vector RagdollVelocity;
    	local vector lift;

    	if (HavokParamsClass == None)
    		return false;
    	HavokSkeletal = new HavokParamsClass;

    	HavokData = HavokSkeletal;

    	// inherit velocity and add extra upwards kick

    	velocity = ragdollInheritedVelocity;         // work around zeroed velocity bug in MP

    	if (velocity==velocity)
    	{
    	    RagdollVelocity = Velocity;
        }
        else
        {
            // NaN in velocity
            RagdollVelocity = vect(0,0,0);
        }

    	// apply tear off location
    	if (bTearOffLocationValid && TearOffLocation == TearOffLocation)
    		SetLocation(TearOffLocation);

    	// ragdoll physics are a client side visual effect
    	bClientHavokPhysics = true;
    	bEnableHavokBackstep = true;	// help with tunnelling probs

    	// disable collision cylinder proxy when in ragdoll

    	bHavokCharacterCollisions = false;

    	StopAnimating(true);
    	SetPhysics(PHYS_HavokSkeletal);

    	HavokSetLinearVelocityAll(RagdollVelocity);

    	//log("ragdoll velocity = "$ragdollVelocity);
    	//log("tear off = "$tearOffMomentum);

    	if (tearOffMomentum!=tearOffMomentum)       // NaN
    	    tearOffMomentum = vect(0,0,0);

        if (vsize(tearOffMomentum)<1)
        {
            //log("no tear off momentum: pushing forward to fall on face");

            tearOffMomentum = (vect(5000,0,0) >> rotation);
        }

    	unifiedAddImpulse(HavokSkeletal.TearOffImpulseScale * TearOffMomentum);

        velocity = unifiedGetVelocity();

        //log("lift velocity: "$velocity.z);

        if (velocity.Z > -10 && vsize(TearOffMomentum) > 5000)
        {
            lift.x = 0;
            lift.y = 0;
            lift.z = ragdollDeathLift * rand(10000) / 10000.0;

            unifiedAddImpulse(lift);

            //log("ragdoll lift applied: "$lift.z);
        }

    	// check for jetpack ragdoll

    	if (!disableJetpackDeath && (movement==MovementState_Thrust || movement==MovementState_ZeroGravity))
    	{
    		jetpack = true;
    		jetpackTime = 0;

            // randomize jetpack duration

            jetpackDuration = jetpackDuration*0.25 + jetpackDuration*0.75*rand(1000)/1000.0;

            //log("jetpack death: duration="$jetpackDuration);
    	}

    	return true;
    }

    State Dying
    {
    	function PostLoadGame()
    	{
    		Destroy();
    	}

        simulated function PostTakeDamage( float Damage, Pawn InstigatedBy, Vector Hitlocation, Vector Momentum, class<DamageType> damageType, optional float projectileFactor)
        {
            //log("ragdoll take damage: "$damage);

            ragdollTouchedGround = true;
     	    unifiedAddImpulse(Momentum);
        }

        simulated function BeginState()
    	{
    		local Character character;

    		Super.BeginState();

    		character = Character(self);

    		// Minimum life time of 4 seconds for client local ragdolls to guarantee it is not culled due to replication inefficiencies.
    		// Pre-matrure ragdoll cull causes the the controller spectating the death to go to 0, 0, 0.

    		if (Level.NetMode == NM_Client && character != None && character.bIsLocalCharacter)
    			SetTimer(4.0, false);
    		else
    			SetTimer(1.0, false);
     	}

        simulated function Timer()
    	{
    		ragdollLifespan -= 1.0;

    	    if (Level.NetMode==NM_DedicatedServer)
    	    {
    		    Destroy();
    		}
    		else if (ragdollLifespan > 0)
    		{
    			SetTimer(1.0, false);
    		}
    		else
    		{
    		    if (!PlayerCanSeeMe())
                {
                    // destroy ragdoll if not seen

                    Destroy();
                }
    		    else
                {
                    // set timer and check again later

    			    SetTimer(1.0, false);
                }
            }
    	}
    }

    // override unified physics methods to take ragdoll mass scale into account

    simulated function unifiedAddImpulse(Vector impulse)
    {
        if (vsize(impulse)>ragdollMaximumImpulse)
            impulse = normal(impulse) * ragdollMaximumImpulse;

        super.unifiedAddImpulse(impulse/ragdollScale);
    }

    simulated function unifiedAddImpulseAtPosition(Vector impulse, Vector position)
    {
        if (vsize(impulse)>ragdollMaximumImpulse)
            impulse = normal(impulse) * ragdollMaximumImpulse;

        super.unifiedAddImpulseAtPosition(impulse/ragdollScale, position);
    }

    simulated function unifiedAddForce(Vector force)
    {
        super.unifiedAddForce(force/ragdollScale);
    }

    simulated function unifiedAddForceAtPosition(Vector force, Vector position)
    {
        super.unifiedAddForceAtPosition(force/ragdollScale, position);
    }

    defaultproperties
    {
        ragdollLifeSpan=10

        jetpackDuration = 4
        jetpackLinearForce = 20000
        jetpackTwirlyForce = 250000

        ragdollScale = 20

        ragdollMaximumImpulse = 200000

        ragdollDeathLift = 50000
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:08.000 - Creation time: st 23.5.2018 00:10:46.673 - Created with UnCodeX