Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Gameplay.MPCarryableContainer

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431
00432
00433
00434
00435
00436
00437
00438
00439
00440
00441
00442
00443
00444
00445
00446
00447
00448
00449
00450
00451
00452
00453
00454
00455
00456
00457
00458
00459
00460
00461
00462
00463
00464
00465
00466
00467
00468
00469
00470
00471
00472
00473
00474
00475
00476
00477
00478
00479
00480
00481
00482
00483
00484
00485
00486
00487
00488
00489
00490
00491
00492
00493
00494
00495
00496
00497
00498
00499
00500
00501
00502
00503
00504
00505
00506
00507
00508
00509
00510
00511
00512
00513
00514
00515
00516
00517
00518
00519
00520
00521
00522
00523
00524
00525
00526
00527
00528
00529
00530
00531
00532
00533
00534
00535
00536
00537
00538
00539
00540
00541
00542
00543
00544
00545
00546
00547
00548
00549
00550
00551
00552
00553
00554
00555
00556
00557
00558
00559
00560
00561
00562
00563
00564
00565
00566
00567
00568
00569
00570
00571
00572
00573
00574
00575
00576
00577
00578
00579
00580
00581
00582
00583
00584
00585
00586
00587
00588
00589
00590
00591
00592
00593
00594
00595
00596
00597
00598
00599
00600
00601
00602
00603
00604
00605
00606
00607
00608
00609
00610
00611
00612
00613
00614
00615
00616
00617
00618
00619
00620
00621
00622
00623
00624
00625
00626
00627
00628
00629
00630
00631
00632
00633
00634
00635
00636
00637
00638
00639
00640
00641
00642
00643
00644
00645
00646
00647
00648
00649
00650
00651
00652
00653
00654
00655
00656
00657
00658
00659
00660
00661
00662
00663
00664
00665
00666
00667
00668
00669
00670
00671
00672
00673
00674
00675
00676
00677
00678
00679
00680
00681
00682
00683
00684
00685
00686
00687
00688
00689
00690
00691
00692
00693
00694
00695
00696
00697
00698
00699
00700
00701
00702
00703
00704
00705
00706
00707
00708
00709
00710
00711
00712
00713
00714
00715
00716
00717
00718
00719
00720
00721
00722
00723
00724
00725
00726
00727
00728
00729
00730
00731
00732
00733
00734
00735
00736
00737
00738
00739
00740
00741
00742
00743
00744
00745
00746
00747
00748
00749
00750
00751
00752
00753
00754
00755
00756
00757
00758
00759
00760
00761
00762
00763
00764
00765
00766
00767
00768
00769
00770
00771
00772
00773
00774
00775
00776
00777
00778
00779
00780
00781
00782
00783
00784
00785
00786
00787
00788
00789
00790
00791

    class MPCarryableContainer extends MPArea;

    enum EContainerObjectiveState
    {
    	COS_Empty,
    	COS_HalfFull,	// I'm an optimist
    	COS_Full
    };

    var() int numCarryables					"The number of carryables this container starts with";
    var() int maxCarryables					"The maximum number of carryables this container can hold before becoming full";
    var() int carryablesPerTeamPoint		"The number of carryables needed to score a team point";
    var() class<MPCarryable> carryableClass	"The class which is stored in this container";
    var() bool bAcceptThrownCarryables		"Does this container allow carryables to be thrown into it?";
    var() float timeBetweenWithdrawals		"The number of seconds you must wait in between each carryable withdrawal";
    var(LocalMessage) class<Engine.Localmessage> ContainerMessageClass "The class used for playing effects and displaying messages";

    var() Name deactivatedAnimation			"The animation to play when the container becomes inactive";
    var() Name activatedAnimation			"The looping animation to play while the container is active";
    var() Name fullAnimation				"The animation to play when the container becomes full";
    var() Name depositedAnimation			"The animation to play when the container accepts a deposit";
    var() Name withdrawnAnimation			"The animation to play when the container accepts a withdrawal";
    var() int fuelMaterialIndex				"The index at which the fuel material resides";
    var() int innerFuelMaterialIndex		"The index at which the inner fuel material resides";
    var() int numWithdrawnPerSpawn			"The number of carryables to withdraw from the container and give to a player each time the player spawns.";
    var() float	nearlyEmptyWithdrawScale	"When the container is less than 25% full, time between withdrawals will be scaled by this amount";
    var() float	nearlyFullWithdrawScale		"When the container is more than 75% full, time between withdrawals will be scaled by this amount";
    var() float	halfFullWithdrawScale		"When the container is between 25% and 75% full, time between withdrawals will be scaled by this amount";

    var(EffectEvents) Name	deactivatedEffectEvent	"The name of an effect event that plays once when the container becomes inactive";
    var(EffectEvents) Name	activatedEffectEvent	"The name of an effect event that plays once when the container becomes active";
    var(EffectEvents) Name	fullEffectEvent			"The name of an effect event that plays once when the container becomes full";
    var(EffectEvents) Name	depositedEffectEvent	"The name of an effect event that plays once when the container accepts a deposit";
    var(EffectEvents) Name	withdrawnEffectEvent	"The name of an effect event that plays once when the container accepts a withdrawal";
    var(EffectEvents) Name	activeEffectEvent		"The name of an effect event that loops while the container is active";

    var(Stats) class<Stat>	depositStat					"The stat awarded for depositing each carryable in this container.";

    var Shader fuelShader;
    var ControllableTexturePanner fuelTexPanner;
    var Shader innerFuelShader;
    var ControllableTexturePanner innerFuelTexPanner;

    var Array<MPCarryable> storedCarryables;

    var bool bFull;
    var float lastWithdrawAnnouncementTime;
    var() int	timeBetweenWithdrawAnnouncements;

    // Effect bools
    var bool			bFullEffect;
    var bool			bLocalFullEffect;
    var bool			bDepositEffect;
    var bool			bLocalDepositEffect;
    var bool			bWithdrawEffect;
    var bool			bLocalWithdrawEffect;
    var bool			bInactiveEffect;
    var bool			bLocalInactiveEffect;

    replication
    {
    	reliable if (Role == ROLE_Authority)
    		numCarryables, maxCarryables, bFullEffect, bDepositEffect, bWithdrawEffect, bInactiveEffect;
    }

    // PostBeginPlay
    simulated function PostBeginPlay()
    {
    	local int numStart;

    	Super.PostBeginPlay();

    	if (Level.NetMode != NM_Client)
    	{
    		// Handle the case where carryables were added in the editor.  AddNewCarryables() increases
    		// the value of numCarryables, so set it properly afterward
    		numStart = numCarryables;
    		numCarryables = 0;
    		addNewCarryables(numStart);
    		numCarryables = numStart;

    		areaTrigger.setTriggerFrequency(0.2);
    	}

    	buildControllableSkin();
    	evaluatePercentageContents(0);
    }

    function addNewCarryables(int numToAdd)
    {
    	local int i;
    	local MPCarryable c;

    	for (i=0; i<numToAdd; i++)
    	{
    		//Log("POST adding, i="$i$", numToAdd="$numToAdd);
    		c = spawn(carryableClass,,,Location);
    		if (c == None)
    		{
    			Log("Container error:  could not spawn carryable of class "$carryableClass);
    			continue;
    		}
    		c.GotoState('Locked');
    		c.homeLocation = Location;
    		addCarryable(c);
    	}
    }

    simulated function PostNetBeginPlay()
    {
    	super.PostNetBeginPlay();

    	// Update panner whenever the territory comes into relevancy
    	calcFuelPannerScale();
    }

    simulated function buildControllableSkin()
    {
    	// Build a controllable texture panner for the fuel shader
    	fuelShader = Shader(ShallowCopyMaterial(GetMaterial(fuelMaterialIndex), self));

    	if (fuelShader != None)
    	{
    		fuelTexPanner = new class'ControllableTexturePanner';
    		fuelTexPanner.PanDirection = Vector(TexPanner(fuelShader.SelfIllumination).PanDirection);
    		fuelTexPanner.Material = TexPanner(fuelShader.SelfIllumination).Material;

    		fuelShader.Diffuse = fuelTexPanner;
    		fuelShader.SelfIllumination = fuelTexPanner;
    		fuelShader.SelfIlluminationMask = fuelTexPanner;
    	}

    	Skins[fuelMaterialIndex] = fuelShader;

    	// Build a controllable texture panner for the inner fuel shader
    	//innerFuelShader = Shader(ShallowCopyMaterial(GetMaterial(innerFuelMaterialIndex), self));

    	if (innerFuelShader != None)
    	{
    		innerFuelTexPanner = new class'ControllableTexturePanner';
    		innerFuelTexPanner.PanDirection = Vector(TexPanner(Combiner(innerFuelShader.SelfIllumination).Material2).PanDirection);
    		innerFuelTexPanner.Material = TexPanner(Combiner(innerFuelShader.SelfIllumination).Material2).Material;

    		innerFuelShader.Diffuse = innerFuelTexPanner;
    		innerFuelShader.SelfIllumination = innerFuelTexPanner;
    		innerFuelShader.SelfIlluminationMask = innerFuelTexPanner;
    	}

    	Skins[innerFuelMaterialIndex] = innerFuelShader;
    	calcFuelPannerScale();
    }

    simulated function calcFuelPannerScale()
    {
    	fuelTexPanner.Scale = 0.5 + float(numCarryables) / float(maxCarryables) / 2.0;
    	//innerFuelTexPanner.Scale = 0.5 + float(numCarryables) / float(maxCarryables) / 2.0;
    	//Log(self$" set panner scale to "$fuelTexPanner.Scale);
    }

    simulated function PostNetReceive()
    {
    	Super.PostNetReceive();

    	updateContainerEffects();
    }

    simulated function updateContainerEffects()
    {
    	if (bFullEffect != bLocalFullEffect)
    	{
    		bLocalFullEffect = bFullEffect;
    		if (bFullEffect)
    		{
    			TriggerEffectEvent(fullEffectEvent);
    			//Log(self$" trying to play "$fullAnimation);
    			if (hasAnim(fullAnimation))
    			{
    				// Disable bWorldGeometry so that effect attachments in the Full animation work properly
    				if (bWorldGeometry)
    					bWorldGeometry = false;
    				PlayAnim(fullAnimation);
    			}
    		}
    		else
    		{
    			UnTriggerEffectEvent(fullEffectEvent);
    		}
    	}

    	if (bInactiveEffect != bLocalInactiveEffect)
    	{
    		bLocalInactiveEffect = bInactiveEffect;

    		if (bInactiveEffect)
    		{
    			TriggerEffectEvent(deactivatedEffectEvent);
    			Log(self$" playing "$deactivatedAnimation);
    			if (hasAnim(deactivatedAnimation))
    				PlayAnim(deactivatedAnimation);
    		}
    		else
    		{
    			if (hasAnim(activatedAnimation))
    				PlayAnim(activatedAnimation);
    		}
    	}

    	if (bWithdrawEffect != bLocalWithdrawEffect)
    	{
    		bLocalWithdrawEffect = bWithdrawEffect;
    		TriggerEffectEvent(withdrawnEffectEvent);
    		if (hasAnim(withdrawnAnimation))
    			PlayAnim(withdrawnAnimation);

    		// Update the panner
    		calcFuelPannerScale();
    	}

    	if (bDepositEffect != bLocalDepositEffect)
    	{
    		bLocalDepositEffect = bDepositEffect;
    		TriggerEffectEvent(depositedEffectEvent);
    		if (hasAnim(depositedAnimation))
    			PlayAnim(depositedAnimation);

    		// Update the panner
    		calcFuelPannerScale();
    	}
    }

    function evaluatePercentageContents(int numAdded)
    {
    	local int numStartedWith;
    	local float percentageStartedWith;
    	local float percentageLeft;

    	evaluateObjectiveState();

    	if (ContainerMessageClass == None || numAdded == 0)
    		return;

    	numStartedWith = numCarryables - numAdded;
    	percentageStartedWith = float(numStartedWith) / float(maxCarryables);
    	percentageLeft = float(numCarryables) / float(maxCarryables);

    	// Announce a change if the number of carryables passes the 25%, 50% or 75% mark

    	// Decreases
    	if (percentageLeft <= 0.25 && 0.25 < percentageStartedWith)
    		Level.Game.BroadcastLocalized(self, ContainerMessageClass, 3, team());
    	else if (percentageLeft <= 0.5 && 0.5 < percentageStartedWith)
    		Level.Game.BroadcastLocalized(self, ContainerMessageClass, 2, team());
    	else if (percentageLeft <= 0.75 && 0.75 < percentageStartedWith)
    		Level.Game.BroadcastLocalized(self, ContainerMessageClass, 1, team());

    	// Increases
    	else if (percentageLeft >= 0.75 && 0.75 > percentageStartedWith)
    		Level.Game.BroadcastLocalized(self, ContainerMessageClass, 1, team());
    	else if (percentageLeft >= 0.5 && 0.5 > percentageStartedWith)
    		Level.Game.BroadcastLocalized(self, ContainerMessageClass, 2, team());
    	else if (percentageLeft >= 0.25 && 0.25 > percentageStartedWith)
    		Level.Game.BroadcastLocalized(self, ContainerMessageClass, 3, team());

    	// Empty
    	else if (numCarryables == 0)
    		Level.Game.BroadcastLocalized(self, ContainerMessageClass, 4, team());
    }

    function evaluateObjectiveState()
    {
    	local float percentageLeft;

    	percentageLeft = float(numCarryables) / float(maxCarryables);

    	setObjectiveTally(numCarryables, maxCarryables);

    	// Set objective icon state
    	if (percentageLeft <= 0.25)
    	{
    		setObjectiveState(0);
    		timeBetweenWithdrawals = default.timeBetweenWithdrawals * nearlyEmptyWithdrawScale;
    	}
    	else if (percentageLeft <= 0.75)
    	{
    		setObjectiveState(1);
    		timeBetweenWithdrawals = default.timeBetweenWithdrawals * halfFullWithdrawScale;
    	}
    	else
    	{
    		setObjectiveState(2);
    		timeBetweenWithdrawals = default.timeBetweenWithdrawals * nearlyFullWithdrawScale;
    	}
    }

    function cleanup()
    {
    	local int i, numToRemove;
    	local MPCarryable c;

    	// Store in NumToRemove since numCarryables gets altered by removeCarryable()
    	numToRemove = storedCarryables.Length;
    	for (i=0; i<numToRemove; i++)
    	{
    		c = removeCarryable();
    		c.destroy();
    	}

    	super.cleanup();
    }

    function registerStats(StatTracker tracker)
    {
    	Super.registerStats(tracker);

    	tracker.registerStat(depositStat);
    }

    function addCarryable(MPCarryable c)
    {
    	storedCarryables.Length = storedCarryables.Length + 1;
    	storedCarryables[storedCarryables.Length-1] = c;
    	numCarryables++;
    	//Log("Carryable stored "$c$", "$storedCarryables[numCarryables-1]$", len = "$storedCarryables.Length$", numCarryables = "$numCarryables);

    	// If adding a carryable caused the number of carriers to increase beyond a scoring
    	// threshold, increase the number of team points
    	if(numCarryables % carryablesPerTeamPoint == 0 && team() != None)
    		scoreTeam(1);

    	//dispatchMessage(new class'MessageContainerDeposit'(label, c.lastCarrier.label, c.lastCarrier.getTeamLabel(), 1));
    	//c.clearCarrier();
    	c.homeContainer = self;
    	c.SetCollision(false);
    	c.bHidden = true;
    	c.GotoState('Locked');
    	//if (c.lastCarrier != None && c.lastCarrier.team() == team())
    	//{
    	//	c.lastCarrier.ClientMessage("You threw a carryable into the container!");
    	//	scoreIndividual(c.lastCarrier, 1);
    	//}

    	if (team() != None)
    		team().bNoMoreCarryables = !allowSpawn();
    }

    function addMetaCarryable(MPMetaCarryable meta)
    {
    	local int i;

    	// Just empty the metacarryable and put all contents into the container, even if this causes
    	// the container to overflow (ideally the overflow would break into denominations)
    	for (i=0; i<meta.carryables.Length; i++)
    	{
    		addCarryable(meta.carryables[i]);

    		if (meta.carryables[i].lastCarrier != None && meta.carryables[i].lastCarrier.team() == team())
    			awardStat(depositStat, meta.carryables[i].lastCarrier);
    	}
    	meta.destroy();
    }

    function MPCarryable removeCarryable()
    {
    	local MPCarryable removedCarryable;

    	// Just remove the last coin
    	removedCarryable = storedCarryables[storedCarryables.Length-1];
    	storedCarryables.Length = storedCarryables.Length - 1;
    	numCarryables--;

    	// If removing a carryable caused the number of carriers to decrease beyond a scoring
    	// threshold, decrease the number of team points
    	if((numCarryables + 1) % carryablesPerTeamPoint == 0 && team() != None && team().score > 0)
    		scoreTeam(-1);

    	removedCarryable.SetCollision(true);

    	//Log("Container removing "$removedCarryable);
    	return removedCarryable;
    }

    function int deposit(Character c)
    {
    	local int i, numAdded;

    	// Friendly touch:  deposit coins

    	// Don't deposit the player's permanent carryables and don't deposit beyond this container's maximum
    	for (i=c.numPermanentCarryables; i<c.carryables.Length && numCarryables < maxCarryables; i++)
    	{
    		addCarryable(c.carryables[i]);
    		//Log("Deposited "$c.carryables[i]);
    		numAdded++;
    	}

    	awardStat(depositStat, c, None, numAdded);
    	//c.ClientMessage("You deposited "$numAdded$" carryables!");
    	dispatchMessage(new class'MessageContainerDeposit'(label, c.label, getTeamLabel(), numAdded));

    	// If all carryables were deposited by the character, cleanup the character completely
    	if (c.numPermanentCarryables == 0 && numAdded == c.numCarryables)
    	{
    		//Log(c$" deposited ALL carryables = "$numAdded);
    		c.clearCarryables();
    	}
    	// Otherwise, only remove the carryables that were deposited
    	else
    	{
    		c.carryables.Length = c.carryables.Length - numAdded;
    		c.numCarryables = c.carryables.Length;

    		// Reset denomination attachment
    		c.carryableReference.attachDenomination();
    		//Log(c$" deposited SOME carryables = "$numAdded$", c.numCarryables = "$c.numCarryables$", len = "$c.carryables.Length$", ref = "$c.carryableReference);
    	}

    	bDepositEffect = !bDepositEffect;
    	updateContainerEffects();
    	evaluateContents();

    	//Log(self$" successfully deposited "$numAdded);
    	return numAdded;
    }

    function withdraw(Character c)
    {
    	local MPCarryable removedCarryable;

    	// Enemy touch:  steal coins
    	if (storedCarryables.Length <= 0)
    	{
    		//Log("Can't withdraw due to lack of carryables");
    		return;
    	}

    	if (c.carryableReference != None && !c.carryableReference.canCombineWith(carryableClass))
    	{
    		//Log("Can't withdraw due to existing carryableReference = "$c.carryableReference$" and class "$carryableClass);
    		return;
    	}

    	removedCarryable = removeCarryable();
    	//Log(self$" attempting withdrawal of "$removedCarryable);

    	removedCarryable.attemptPickup(c);

    	bWithdrawEffect = !bWithdrawEffect;
    	updateContainerEffects();

    	// Neutral containers become inactive when empty
    	if (team() == None && storedCarryables.Length == 0)
    		GotoState('Inactive');
    	else
    	{
    		evaluatePercentageContents(-1);
    	}

    	if (team() != None)
    		team().bNoMoreCarryables = !allowSpawn();
    }

    function bool allowSpawn()
    {
    	if (numWithdrawnPerSpawn > 0)
    		return numCarryables >= numWithdrawnPerSpawn;

    	return true;
    }

    function evaluateContents()
    {
    	if (storedCarryables.Length >= maxCarryables && team() != None)
    	{
    		GotoState('Full');
    	}
    	else
    	{
    		evaluatePercentageContents(1);
    	}
    }

    function onAreaEntered(Character c)
    {
    	// Do nothing by default
    }

    function onAreaExited(Character c)
    {
    	// Do nothing by default
    }

    function onAreaTick()
    {
    }

    function reset()
    {
    	local int i;

    	// Used in single player to reset the container
    	for(i=0; i<storedCarryables.Length; i++)
    	{
    		if (storedCarryables[i] != None)
    			storedCarryables[i].destroy();
    	}
    	storedCarryables.Length = 0;
    	numCarryables = 0;
    	GotoState('Active');
    }

    function onPlayerSpawned(Character c)
    {
    	local int i;

    	//Log("Withdrawing permanent carryables:  "$c.numPermanentCarryables);
    	if (storedCarryables.Length < c.numPermanentCarryables)
    	{
    		Log("Not enough carryables left for spawn withdrawal.");
    		return;
    	}

    	for (i=0; i<c.numPermanentCarryables; i++)
    	{
    		//Log(self$" automatically withdrawing for spawn");
    		withdraw(c);
    	}
    }

    // The container accepts deposits and withdrawals
     auto simulated state Active
    {
    	simulated function BeginState()
    	{
    		TriggerEffectEvent(activatedEffectEvent);
    		if (hasAnim(activatedAnimation))
    			LoopAnim(activatedAnimation);
    	}

    	function onAreaEntered(Character c)
    	{
    		if (c.team() == team())
    		{
    			if (c.carryableReference != None && c.numCarryables > c.numPermanentCarryables && c.carryableReference.canCombineWith(carryableClass))
    			{
    				// Deposit all the character's carryables
    				if (SecondaryMessageClass != None)
    				{
    					Level.Game.BroadcastLocalized(self, SecondaryMessageClass, 1, c.tribesReplicationInfo,,,string(c.numDroppableCarryables()));
    				}

    				deposit(c);
    			}
    		}
    		else if (numCarryables > 0 && !c.bDontAllowCarryablePickups && Vehicle(c.getMount()) == None && (c.carryableReference == None || c.numCarryables < c.carryableReference.maxCarried))
    		{
    			// Announce withdrawal as soon as the player enters
    			if (Level.TimeSeconds - lastWithdrawAnnouncementTime > timeBetweenWithdrawAnnouncements)
    			{
    				lastWithdrawAnnouncementTime = Level.TimeSeconds;
    				if (team() == None)
    					Level.Game.BroadcastLocalized(self, ContainerMessageClass, 5, c.team());
    				else
    					Level.Game.BroadcastLocalized(self, ContainerMessageClass, 6, c.team());
    			}
    		}
    	}

    	function onAreaExited(Character c)
    	{
    		local int carryableCount;

    		carryableCount = c.numDroppableCarryables();
    		if (c.team() != team() && carryableCount > 1 && SecondaryMessageClass != None && carryableCount != c.lastCarryableNumber)
    		{
    			c.lastCarryableNumber = carryableCount;
    			Level.Game.BroadcastLocalized(self, SecondaryMessageClass, 0, c.tribesReplicationInfo,,,string(carryableCount));
    		}
    	}

    	function onAreaTick()
    	{
    		local Character c;
    		//local MPCarryable carryable;
    		//local MPMetaCarryable meta;
    		//local bool bAdded;

    		// See if there are any characters withdrawing, or friendly players carrying fuel
    		ForEach areaTrigger.TouchingActors(class'Character', c)
    		{
    			if (c.team() != team() && storedCarryables.Length > 0 && !c.bDontAllowCarryablePickups && Vehicle(c.getMount()) == None)
    			{
    				// Give all players who have been in here long enough a carryable
    				if (areaTrigger.enoughTimeElapsedSinceMarkerTime(c, timeBetweenWithdrawals, true) && c.numDroppableCarryables() < carryableClass.default.maxCarried)
    				{
    					// Withdraw a carryable
    					//Log(self $" allowed carryable withdrawal");
    					withdraw(c);

    					if (Level.TimeSeconds - lastWithdrawAnnouncementTime > timeBetweenWithdrawAnnouncements)
    					{
    						lastWithdrawAnnouncementTime = Level.TimeSeconds;
    						if (team() == None)
    							Level.Game.BroadcastLocalized(self, ContainerMessageClass, 5, c.team());
    						else
    							Level.Game.BroadcastLocalized(self, ContainerMessageClass, 6, c.team());
    					}
    				}
    			}

    			// Automatically deposit if friendly
    			if (c.team() == team() && c.carryableReference != None && c.numCarryables > c.numPermanentCarryables && c.carryableReference.canCombineWith(carryableClass))
    			{
    				if (SecondaryMessageClass != None)
    				{
    					Level.Game.BroadcastLocalized(self, SecondaryMessageClass, 1, c.tribesReplicationInfo,,,string(c.numDroppableCarryables()));
    				}

    				deposit(c);
    			}
    		}

    		// Eat any carryables inside the area
    		//ForEach areaTrigger.TouchingActors(class'MPCarryable', carryable)
    		//{
    		//	meta = MPMetaCarryable(carryable);
    		//	if (!carryable.bHidden && meta == None && carryable.canCombineWith(carryableClass) )
    		//	{
    		//		Log(self$" eating "$carryable);
    		//		addCarryable(carryable);
    		//		bAdded = true;
    		//	}
    		//	else if (meta != None && carryable.canCombineWith(carryableClass))
    		//	{
    		//		Log(self$" eating meta "$meta);
    		//		addMetaCarryable(meta);
    		//		bAdded = true;
    		//	}

    		//	if (bAdded)
    		//		evaluateContents();
    		//}
    	}

    	simulated function Tick(float Delta)
    	{
    		super.Tick(Delta);

    		// Occasionally update the panner
    		calcFuelPannerScale();
    	}

    	//function OnAreaEnteredByActor(Actor a)
    	//{
    	//	local MPCarryable thrownCarryable;
    	//	local MPMetaCarryable meta;

    	//	// Allow carryables to be thrown into the container, if applicable
    	//	thrownCarryable = MPCarryable(a);

    	//	if (thrownCarryable != None && !thrownCarryable.bHidden && thrownCarryable.canCombineWith(carryableClass) && bAcceptThrownCarryables)
    	//	{
    	//		// If it's a metacarryable, empty it
    	//		// Assume it was THROWN since characters can't actually deposit metacarryables directly
    	//		meta = MPMetaCarryable(thrownCarryable);
    	//		if (meta != None)
    	//		{
    	//			addMetaCarryable(meta);
    	//		}
    	//		else
    	//		{
    	//			// It's not a metacarryable; just add it
    	//			addCarryable(thrownCarryable);
    	//			if (thrownCarryable.lastCarrier != None && thrownCarryable.lastCarrier.team() == team())
    	//				awardStat(depositStat, thrownCarryable.lastCarrier);
    	//		}
    	//		evaluateContents();
    	//	}
    	//}
    }

    // The container, for whatever reason, doesn't accept deposits or withdrawals
    state Inactive
    {
    	// Handle cases where a sytem adds a carryable back in (for example when a dropped
    	// carryable returns here after the depot has become inactive)
    	function addCarryable(MPCarryable c)
    	{
    		GotoState('Active');

    		Global.addCarryable(c);
    	}

    	function BeginState()
    	{
    		bInactiveEffect = true;
    		updateContainerEffects();
    		Level.Game.BroadcastLocalized(self, ContainerMessageClass, 7, team());
    		dispatchMessage(new class'MessageContainerEmpty'(label, getTeamLabel()));
    	}

    	function EndState()
    	{
    		bInactiveEffect = false;
    		updateContainerEffects();
    	}
    }

    // The container is full and will no longer accept deposits or withdrawals
    state Full extends Inactive
    {
    	function BeginState()
    	{
    		local int i;

    		bFullEffect = true;
    		bFull = true;
    		updateContainerEffects();
    		Level.Game.BroadcastLocalized(self, ContainerMessageClass, 0, team());
    		dispatchMessage(new class'MessageContainerFull'(label, getTeamLabel()));

    		// Destroy all the fuel that was in it
    		for (i=0; i<storedCarryables.Length; i++)
    		{
    			if (storedCarryables[i] != None)
    				storedCarryables[i].destroy();
    		}
    		storedCarryables.Length = 0;
    	}

    	function EndState()
    	{
    		bWorldGeometry = default.bWorldGeometry;
    		bFullEffect = false;
    		bFull = false;
    		updateContainerEffects();

    		Super.EndState();
    	}

    	// Don't allow deposits or withdrawals in this state
    	function int deposit(Character c)
    	{
    		return 0;
    	}

    	function withdraw(Character c)
    	{
    	}
    }

    // Don't allow deposits or withdrawals
    state Paused
    {
    }

    defaultproperties
    {
    	DrawType				= DT_StaticMesh
    	StaticMesh				= StaticMesh'Editor_res.TexPropCube'
    	bCollideActors			= true
    	bCollideWorld			= true
    //	bBlockActors			= true
    	bMovable				= false
    	bUseCylinderCollision	= false
    	bBlockPlayers			= false
    	bNetNotify				= true
    	carryablesPerTeamPoint		= 10
    	carryableClass				= class'MPCarryable'
    	maxCarryables				= 10
    	bAcceptThrownCarryables		= true
    	timeBetweenWithdrawals	= 2
    	fuelMaterialIndex		= 2
    	ContainerMessageClass	= class'MPContainerMessages'
    	timeBetweenWithdrawAnnouncements = 10
    	bAlwaysRelevant			= true

    	nearlyEmptyWithdrawScale = 1.5
    	nearlyFullWithdrawScale	= 0.5
    	halfFullWithdrawScale	= 1.0

    	deactivatedEffectEvent	= Deactivated
    	activatedEffectEvent	= Activated
    	fullEffectEvent			= Full
    	depositedEffectEvent	= Deposited
    	withdrawnEffectEvent	= Withdrawn
    	activeEffectEvent		= Active

    	NetUpdateFrequency		= 4
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:18.000 - Creation time: st 23.5.2018 00:10:45.853 - Created with UnCodeX