Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# TribesAdmin.AdminIni

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431
00432
00433
00434
00435
00436
00437
00438
00439
00440
00441
00442
00443
00444
00445
00446
00447
00448
00449
00450
00451
00452
00453
00454
00455
00456
00457
00458
00459
00460
00461
00462
00463
00464
00465
00466
00467
00468
00469
00470
00471
00472
00473
00474
00475
00476
00477
00478
00479
00480
00481
00482
00483
00484
00485
00486
00487
00488
00489
00490
00491
00492
00493
00494
00495
00496
00497
00498
00499
00500
00501
00502
00503
00504
00505
00506
00507
00508
00509
00510
00511
00512
00513
00514
00515
00516
00517
00518
00519
00520
00521
00522
00523
00524
00525
00526
00527
00528
00529
00530
00531
00532
00533
00534
00535
00536
00537
00538
00539
00540
00541
00542
00543
00544
00545
00546
00547
00548
00549
00550
00551
00552
00553
00554
00555
00556
00557
00558
00559
00560
00561
00562
00563
00564
00565
00566
00567
00568
00569
00570
00571
00572
00573
00574
00575
00576
00577
00578
00579
00580
00581
00582
00583
00584
00585
00586
00587
00588
00589
00590
00591
00592
00593
00594
00595
00596
00597
00598
00599
00600
00601
00602
00603
00604
00605
00606
00607
00608
00609
00610
00611
00612
00613
00614
00615
00616
00617
00618
00619
00620
00621
00622
00623
00624
00625
00626
00627
00628
00629
00630
00631
00632
00633
00634
00635
00636
00637
00638
00639
00640
00641
00642
00643
00644
00645
00646
00647
00648
00649
00650
00651
00652
00653
00654
00655
00656
00657
00658
00659
00660
00661
00662
00663
00664
00665
00666
00667
00668
00669
00670
00671
00672
00673
00674
00675
00676
00677
00678
00679
00680
00681
00682
00683
00684
00685
00686
00687
00688
00689
00690
00691
00692
00693
00694
00695
00696
00697
00698
00699
00700
00701
00702
00703
00704
00705
00706
00707
00708
00709
00710
00711
00712
00713
00714
00715
00716
00717
00718
00719
00720
00721
00722
00723
00724
00725
00726
00727
00728
00729
00730
00731
00732
00733
00734
00735
00736
00737
00738
00739
00740
00741
00742
00743
00744
00745
00746
00747
00748
00749
00750
00751
00752
00753
00754
00755
00756
00757
00758
00759
00760
00761
00762
00763
00764
00765
00766
00767
00768
00769
00770
00771
00772
00773
00774
00775
00776
00777
00778
00779
00780
00781
00782
00783
00784
00785
00786
00787
00788
00789
00790
00791
00792
00793
00794
00795
00796
00797
00798
00799
00800
00801
00802
00803
00804
00805
00806
00807
00808
00809
00810
00811
00812
00813
00814
00815
00816
00817
00818
00819
00820
00821
00822
00823
00824
00825
00826
00827
00828
00829
00830
00831
00832
00833
00834
00835
00836
00837
00838
00839
00840
00841
00842
00843
00844
00845
00846
00847
00848
00849
00850
00851
00852
00853
00854
00855
00856
00857

    class AdminIni extends Engine.AdminBase Within Engine.PlayerController;

    var AccessControlIni	Manager;
    var TribesAdminUser		AdminUser;
    var GameConfigSet		ConfigSet;

    var protected string	NextMutators;
    var protected string	NextGameType;

    // Localization
    var localized string Msg_PlayerList;
    var localized string Msg_FinishGameEditFirst;
    var localized string Msg_FinishGameRestart;
    var localized string Msg_GameNoSupportBots;
    var localized string Msg_StatsNoBots;
    var localized string Msg_NextMapNotFound;
    var localized string Msg_ChangingMapTo;
    var localized string Msg_PlayerBanned;
    var localized string Msg_SessionBanned;
    var localized string Msg_PlayerKicked;
    var localized string Msg_NoBotGameFull;
    var localized string Msg_NoAddNamedBot;
    var localized string Msg_NoBotsPlaying;
    var localized string Msg_SetBotNeedVal;
    var localized string Msg_MutNeedGameEdit;
    var localized string Msg_NoMutatorInUse;
    var localized string Msg_NoUnusedMuts;
    var localized string Msg_AddedMutator;
    var localized string Msg_ErrAddingMutator;
    var localized string Msg_RemovedMutator;
    var localized string Msg_ErrRemovingMutator;
    var localized string Msg_MapListNeedGameEdit;
    var localized string Msg_MapRotationList;
    var localized string Msg_NoMapInRotation;
    var localized string Msg_NoMapsAdded;
    var localized string Msg_AddedMapToList;
    var localized string Msg_NoMapsRemoved;
    var localized string Msg_RemovedMapFromList;
    var localized string Msg_NoMapsFound;
    var localized string Msg_MapIsInRotation;
    var localized string Msg_MapNotInRotation;
    var localized string Msg_MustEndGameEdit;
    var localized string Msg_EditingClass;
    var localized string Msg_EditFailed;
    var localized string Msg_AlreadyEdited;
    var localized string Msg_NotEditing;
    var localized string Msg_EditingCompleted;
    var localized string Msg_EditingCancelled;
    var localized string Msg_UnknownParam;
    var localized string Msg_NoParamsFound;
    var localized string Msg_ParamModified;
    var localized string Msg_ParamNotModified;
    var localized string Msg_PlayerSpectified;
    var localized string Msg_TimeLimitChanged;
    var localized string Msg_TourneyModeEnabled;
    var localized string Msg_TourneyModeDisabled;
    var localized string Msg_ForceStart;
    var localized string Msg_TeamDamageEnabled;
    var localized string Msg_TeamDamageDisabled;

    event Created()
    {
    	if (AccessControlIni(Level.Game.AccessControl) != None)
    		Manager = AccessControlIni(Level.Game.AccessControl);

    	log("created admin ini: outer="$outer$" owner="$owner$" manager="$manager);
    }

    // Execute an administrative console command on the server.
    function DoLogin( string Username, string Password )
    {
        log("TribesAdmin.DoLogin: "$Username$" "$Password$" ("$Outer$")");

    	if (AdminUser == None && Manager.AdminLogin(Outer, Username, Password))
    	{
    		bAdmin = true;
    		AdminUser = Manager.GetLoggedAdmin(Outer);
    		Manager.AdminEntered(Outer, Username);
    	}
    }

    // promotes the target player controller to admin
    exec function DoPromote(PlayerController Target)
    {
    	if (Target == None)
    	{
    		log("DoPromote: Target is None");
    		return;
    	}

    	log("Promoting: "$Outer.PlayerReplicationInfo.PlayerName$" promotes "$Target.PlayerReplicationInfo.PlayerName);

    	if (Level.Game.AccessControl.AdminPromote(Outer, Target))
    	{
    		ForceAdmin();
    		Level.Game.AccessControl.AdminPromoted(Outer, Target, true);
    	}
    	else
    	{
    		Level.Game.AccessControl.AdminPromoted(Outer, Target, false);
    	}
    }

    function DoLogout()
    {
    	if (Manager.AdminLogout(Outer))
    	{
    		Manager.ReleaseConfigSet(ConfigSet, Self);
    		Manager.AdminExited(Outer);
    		bAdmin=false;
    	}
    }

    // TODO: Remove for release ?
    exec function PlayerList()
    {
    	local PlayerReplicationInfo PRI;

    	log(Msg_PlayerList);
    	ForEach DynamicActors(class'PlayerReplicationInfo', PRI)
    		log(PRI.PlayerName@"( ping"@PRI.Ping$")");
    }

    exec function RestartMap()
    {
    	if (CanPerform("Mr") || CanPerform("Mc"))	  // Mr = MapRestart, Mc = Map Change
    	{
    		if (ConfigSet == None)
    			// ClientTravel( "?restart", TRAVEL_Relative, false );
    			DoSwitch("?restart");
    		else
    			ClientMessage(Msg_FinishGameEditFirst);
    	}
    }

    exec function Switch( string URL )
    {
    	DoSwitch(URL);
    }

    function DoSwitch( string URL)
    {
    	// MJTEMP:  Allow any admin to change maps.  For some reason you weren't allowed to change maps when
    	//          auto-logging in as an admin.  Decided to allow all admins to change maps rather than not
    	//          have this working.  Should fix the underlying problem in the future.
    	//if (CanPerform("Mc"))
    	//{
    		if (ConfigSet == None)
    		{
    			// TODO: See which problems could be coming from setting CTFGame with DM Map.. etc
    			//       Find a way to avoid that problem.

    			// Rebuild the URL based on edited game settings
    			if (NextGameType != "" && Level.Game.ParseOption(URL, "Game") == "")
    				URL=URL$"?Game="$NextGameType;

    			if (NextMutators != "" && Level.Game.ParseOption(URL, "Mutator") == "")
    				URL=URL$"?Mutator="$NextMutators;

    			Level.ServerTravel( URL, false );
    		}
    		else
    			ClientMessage(Msg_FinishGameRestart);
    	//}
    }

    function GotoNextMap()
    {
    local string NextMap;
    local Engine.MapList MyList;
    local Engine.GameInfo G;

    	if (CanPerform("Mc"))
    	{
    		if (ConfigSet == None)
    		{

    			G = Level.Game;
    			if ( G.bChangeLevels && !G.bAlreadyChanged && (G.MapListType != "") )
    			{
    				// open a the nextmap actor for this game type and get the next map
    				G.bAlreadyChanged = true;
    				MyList = G.GetMapList(G.MapListType);
    				if (MyList != None)
    				{
    					NextMap = MyList.GetNextMap();
    					MyList.Destroy();
    				}
    				if ( NextMap == "" )
    					NextMap = GetMapName(G.MapPrefix, NextMap,1);

    				if ( NextMap != "" )
    				{
    					DoSwitch(NextMap);
    					ClientMessage(ReplaceTag(Msg_ChangingMapTo, "NextMap", NextMap));
    					return;
    				}
    			}
    			ClientMessage(Msg_NextMapNotFound);
    			Level.ServerTravel( "?Restart", false );
    		}
    		else
    			ClientMessage(Msg_FinishGameEditFirst);
    	}
    }

    exec function Kick( string Cmd, string Extra )
    {
    local array<string> Params;
    local array<PlayerReplicationInfo> AllPRI;
    local Controller	C, NextC;
    local int i;

    	if (CanPerform("Kp") || CanPerform("Kb"))		// Kp = Kick Players, Kb = Kick/Ban
    	{
    		if (Cmd ~= "List")
    		{
    			// Get the list of players to kick by showing their PlayerID
    			// TODO: Display Fixed Playername (no garbage chars in name)?
    			// TODO: Display Sorted ?
    			Level.Game.GameReplicationInfo.GetPRIArray(AllPRI);
    			for (i = 0; i<AllPRI.Length; i++)
    				ClientMessage(Right("   "$AllPRI[i].PlayerID, 3)$")"@AllPRI[i].PlayerName);
    			return;
    		}

    		if (Cmd ~= "Ban" || Cmd ~= "Session")
    			Params = SplitParams(Extra);
    		else if (Extra != "")
    			Params = SplitParams(Cmd@Extra);
    		else
    			Params = SplitParams(Cmd);

    		// go thru all Players
    		for (C = Level.ControllerList; C != None; C = NextC)
    		{
    			NextC = C.NextController;
    			// Allow to kick bots too, for now i dont
    			// What about Spectators ?? hummm ...
    			if (C != Owner && PlayerController(C) != None && C.PlayerReplicationInfo != None)
    			{
    				for (i = 0; i<Params.Length; i++)
    				{
    					if ((IsNumeric(Params[i]) && C.PlayerReplicationInfo.PlayerID == int(Params[i]))
    							|| MaskedCompare(C.PlayerReplicationInfo.PlayerName, Params[i]))
    					{
    						// Kick that player
    						if (Cmd ~= "Ban")
    						{
    							ClientMessage(ReplaceTag(Msg_PlayerBanned, "Player", C.PlayerReplicationInfo.PlayerName));
    							Manager.BanPlayer(PlayerController(C));
    						}
    						else if (Cmd ~= "Session")
    						{
    							ClientMessage(ReplaceTag(Msg_SessionBanned, "Player", C.PlayerReplicationInfo.PlayerName));
    							Manager.BanPlayer(PlayerController(C), true);
    						}
    						else
    						{
    							Manager.KickPlayer(PlayerController(C));
    							ClientMessage(ReplaceTag(Msg_PlayerKicked, "Player", C.PlayerReplicationInfo.PlayerName));
    						}
    						break;
    					}
    				}
    			}
    		}
    	}
    }

    exec function Map( string Cmd )
    {
    	if (Cmd ~= "Restart")
    	{
    		RestartMap();
    	}
    	else if (Cmd ~= "Next")
    	{
    		GotoNextMap();
    	}
    	else
    	{
    		DoSwitch(Cmd);
    	}
    }

    exec function User( string Cmd, string Extra)
    {
    	if (Cmd ~= "List")	// Admin User List *mask*
    	{
    		SendUserList(Extra);
    	}
    	else if (Cmd ~= "Del")	// Admin User Del *mask*
    	{
    		// TODO: Later .. need to make sure its acceptable to do so
    	}
    	else if (Cmd ~= "Logged") // List of currently logged admins
    	{
    		SendLoggedList();
    	}
    }

    // TODO: Mutators Logic should be separate from GameConfigSet since
    //       they are not associated to a game type.
    exec function Mutators( string Cmd, string Extra)
    {
    local array<string> Values;
    local int i;

    	if (CanPerform("Mu"))
    	{
    		// TODO: Separate Mutator stuff from ConfigSet ?
    		if  (ConfigSet == None)
    		{
    			ClientMessage(Msg_MutNeedGameEdit);
    			return;
    		}

    		if (Cmd ~= "Used")
    		{
    			// List Used Mutators
    			Values = ConfigSet.GetUsedMutators();
    			for (i = 0; i<Values.Length; i++)
    				ClientMessage(i$")"@Values[i]);
    			if (i == 0)
    				ClientMessage(Msg_NoMutatorInUse);
    		}
    		else if (Cmd ~= "Unused")
    		{
    			Values = ConfigSet.GetUnusedMutators();
    			for (i = 0; i<Values.Length; i++)
    				ClientMessage(i$")"@Values[i]);
    			if (i == 0)
    				ClientMessage(Msg_NoUnusedMuts);
    		}
    		else if (Cmd ~= "Add")
    		{
    			Split(Extra, " ", Values);
    			for (i = 0; i<Values.Length; i++)
    			{
    				if (ConfigSet.AddMutator(Values[i]))
    					ClientMessage(ReplaceTag(Msg_AddedMutator, "Mutator", Values[i]));
    				else
    					ClientMessage(ReplaceTag(Msg_ErrAddingMutator, "Mutator", Values[i]));
    			}
    		}
    		else if (Cmd ~= "Del")
    		{
    			Split(Extra, " ", Values);
    			for (i = 0; i<Values.Length; i++)
    			{
    				if (ConfigSet.DelMutator(Values[i]))
    					ClientMessage(ReplaceTag(Msg_RemovedMutator, "Mutator", Values[i]));
    				else
    					ClientMessage(ReplaceTag(Msg_ErrRemovingMutator, "Mutator", Values[i]));
    			}
    		}
    	}
    }

    exec function GetMapList( string Cmd, string Extra )
    {
    local array<string> Values;
    local Engine.MapList	Maps;
    local int i;

    	if (CanPerform("Ml"))
    	{
    		if (Cmd ~= "Used")
    		{
    			if (ConfigSet == None)
    			{
    				ClientMessage(ReplaceTag(Msg_MapRotationList, "Game", Level.Game.Acronym));
    				Maps = Level.Game.GetMapList(Level.Game.MapListType);
    			}
    			else
    			{
    				ClientMessage(ReplaceTag(Msg_MapRotationList, "Game", ConfigSet.GetGameAcronym()));
    				Maps = ConfigSet.GetMaps();
    			}
    			ClientMessage("-------------------");
    			if (Maps == None || Maps.Maps.Length == 0)
    				ClientMessage(Msg_NoMapInRotation);
    			else
    			{
    				for (i = 0; i<Maps.Maps.Length; i++)
    				{
    					ClientMessage(Right("   "$i, 4)$")"@Maps.Maps[i]);
    				}
    			}
    			return;
    		}

    		if  (ConfigSet == None)
    		{
    			ClientMessage(Msg_MapListNeedGameEdit);
    			return;
    		}

    		if (Cmd ~= "Add")
    		{
    			Values = ConfigSet.AddMaps(Extra);
    			if (Values.Length == 0)
    				ClientMessage(Msg_NoMapsAdded);
    			else
    				for (i = 0; i<Values.Length; i++)
    					ClientMessage(ReplaceTag(Msg_AddedMapToList, "Map", Values[i]));
    		}
    		else if (Cmd ~= "Del")
    		{
    			Values = ConfigSet.RemoveMaps(Extra);
    			if (Values.Length == 0)
    				ClientMessage(Msg_NoMapsRemoved);
    			else
    				for (i = 0; i<Values.Length; i++)
    					ClientMessage(ReplaceTag(Msg_RemovedMapFromList ,"Map", Values[i]));
    		}
    		else if (Cmd ~= "Find")
    		{
    			Values = ConfigSet.FindMaps(Extra);
    			if (Values.Length == 0)
    				ClientMessage(Msg_NoMapsFound);
    			else
    			{
    				for (i = 0; i<Values.Length; i++)
    				{
    					if (Left(Values[i], 1) == "+")
    						ClientMessage(ReplaceTag(Msg_MapIsInRotation, "Map", Mid(Values[i], 1)));
    					else
    						ClientMessage(ReplaceTag(Msg_MapNotInRotation, "Map", Values[i]));
    				}
    			}
    		}
    	}
    }

    exec function Game( string Cmd, string Extra )
    {
    local array<string> Params;
    local string LastParam, LastValue;
    local int p;

    	if (Cmd ~= "ChangeTo")	// Admin Game ChangeTo <gameclass>
    	{
    		if (CanPerform("Mt"))
    		{
    			if (ConfigSet != None)
    			{
    				ClientMessage(Msg_MustEndGameEdit);
    				return;
    			}
    			NextGameType = FindGameType(Extra);
    		}
    		return;
    	}

    	if (!CanPerform("Ms"))
    		return;

    	if (Cmd ~= "Edit")	// Admin Game Edit [CTF]
    	{
    		if (Manager.LockConfigSet(ConfigSet, Self))
    		{
    			if (ConfigSet.StartEdit(Extra))
    				ClientMessage(ReplaceTag(Msg_EditingClass, "Class", ConfigSet.GetEditedClass()));
    			else
    			{
    				ClientMessage(Msg_EditFailed);
    				Manager.ReleaseConfigSet(ConfigSet, Self);
    			}
    		}
    		else
    			ClientMessage(Msg_AlreadyEdited);
    		return;
    	}

    	if  (ConfigSet == None)
    	{
    		ClientMessage(Msg_NotEditing);
    		return;
    	}

    	if (Cmd ~= "EndEdit")
    	{
    		ConfigSet.EndEdit(true);
    		NextMutators = ConfigSet.NextMutators;
    //		Log("NextMutators="@NextMutators);
    		Manager.ReleaseConfigSet(ConfigSet, Self);
    		ClientMessage(Msg_EditingCompleted);
    	}
    	else if (Cmd ~= "CancelEdit")
    	{
    		ConfigSet.EndEdit(false);
    		Manager.ReleaseConfigSet(ConfigSet, Self);
    		ClientMessage(Msg_EditingCancelled);
    	}
    	else if (Cmd ~= "Get")
    	{
    		if (Instr(Extra, "*") == -1 && Instr(Extra, " ") == -1)
    		{
    			LastValue = ConfigSet.GetNamedParam(Extra);
    			if (LastValue == "")
    				ClientMessage(ReplaceTag(Msg_UnknownParam,"Value", Extra));
    			else
    				ClientMessage(Extra@"="@LastValue);
    		}
    		else
    		{
    			Params = ConfigSet.GetMaskedParams(Extra);
    			if (Params.Length == 0)
    				ClientMessage(Msg_NoParamsFound);
    			else
    				for (p = 0; p<Params.Length; p+=2)
    					ClientMessage(Params[p]@"="@Params[p+1]);
    		}
    	}
    	else if (Cmd ~= "Set")
    	{
    		p = Instr(Extra, " ");
    		if (p >= 0)
    		{
    			LastParam = Left(Extra, p);
    			LastValue = Mid(Extra, p+1);
    			if (ConfigSet.SetNamedParam(LastParam, LastValue))
    			{
    				ClientMessage(Msg_ParamModified);
    				return;
    			}
    		}
    		ClientMessage(Msg_ParamNotModified);
    	}
    }

    exec function SetJoinPassword( string Cmd )
    {
    	local array<string> Params;

    	Params = SplitParams(Cmd);
    	Manager.SetGamePassword( Params[0] );
    }

    exec function RemoveJoinPassword( string Cmd )
    {
    	Manager.SetGamePassword( "" );
    }

    exec function Spectify( string Cmd )
    {
    	local array<string> Params;
    	local PlayerController PC;

    	Params = SplitParams(Cmd);
    	PC = FindController(Params[0]);

    	if (PC != None && PlayerCharacterController(PC) != None && !PC.PlayerReplicationInfo.bIsSpectator)
    	{
    		PlayerCharacterController(PC).spectate();
    		ClientMessage(ReplaceTag(Msg_PlayerSpectified, "Player", PC.PlayerReplicationInfo.PlayerName));
    	}
    }

    exec function TeamChange( string Cmd )
    {
    	local PlayerController PC;
    	local string team;
    	local int TeamNum;
    	local array<string> Params;

    	Params = SplitParams(Cmd);
    	PC = FindController(Params[0]);
    	if (Params.Length > 1)
    		Team = Params[1];

    	//Log("Teamchange called on PC "$PC$" with team "$Team);

    	// Handle forcing to a particular team
    	if (Team != "")
    	{
    		TeamNum = int(Team);
    		PlayerCharacterController(PC).changeTeam(TeamNum, true);
    	}

    //	else if (PC.PlayerReplicationInfo.bIsSpectator)
    //		Level.Game.RestartPlayer(PC);
    	else
    		PlayerCharacterController(PC).switchTeam(true);
    }

    exec function SetTimeLimit( string Cmd )
    {
    	local array<string> Params;
    	local float duration;

    	Params = SplitParams(Cmd);
    	duration = float(Params[0]);
    	if (duration < 0)
    		duration = 0;
    	ConsoleCommand("set rounddata duration "$string(duration));
    	ClientMessage(ReplaceTag(Msg_TimeLimitChanged, "Value", ModeInfo(Level.Game).roundInfo.currentRound().duration));
    }

    exec function EnableTournamentMode( string Cmd )
    {
    	MultiplayerGameInfo(Level.Game).enableTournamentMode();
    	ClientMessage(Msg_TourneyModeEnabled);
    }

    exec function DisableTournamentMode( string Cmd )
    {
    	MultiplayerGameInfo(Level.Game).disableTournamentMode();
    	ClientMessage(Msg_TourneyModeDisabled);
    }

    exec function ForceStart( string Cmd )
    {
    	MultiplayerGameInfo(Level.Game).bForceStart = true;
    	ClientMessage(Msg_ForceStart);
    }

    exec function SetTeamDamage( string Cmd )
    {
    	local array<string> Params;
    	Params = SplitParams(Cmd);

    	MultiplayerGameInfo(Level.Game).setPlayerTeamDamagePercentage(float(Params[0]));
    	if (Params[0] == "0")
    		ClientMessage(Msg_TeamDamageEnabled);
    	else if (Params[0] == "1")
    		ClientMessage(Msg_TeamDamageDisabled);
    }

    protected function bool CanPerform(string priv)
    {
      return AdminUser != None && AdminUser.HasPrivilege(priv);
    }

    protected function SendUserList(string mask)	// Todo: Mask Feature
    {
    local TribesAdminUserList	uList;
    local int i;

    	uList = AdminUser.GetManagedUsers(Manager.Groups);
    	for (i=0; i<uList.Count(); i++)
    		ClientMessage(string(i)$uList.Get(i).UserName);
    }

    /// TODO: Check if should send ALL logged admins or only
    protected function SendLoggedList()
    {
    local TribesAdminUserList	uList;
    local int i;

    	uList = AdminUser.GetManagedUsers(Manager.Groups);
    	for (i=0; i<uList.Count(); i++)
    		if (Manager.IsLogged(uList.Get(i)))
    			ClientMessage(string(i)$uList.Get(i).UserName);
    }

    protected function string FindGameType(string GameType)
    {
    local class<GameInfo>	TempClass;
    local String 			NextGame;
    local int				i;

    	// Compile a list of all gametypes.
    	i = 0;
    	NextGame = Level.GetNextInt("Engine.GameInfo", 0);
    	while (NextGame != "")
    	{
    		TempClass = class<GameInfo>(DynamicLoadObject(NextGame, class'Class'));
    		if (TempClass != None)
    		{
    			if (GameType ~= string(TempClass))				break;
    			if (GameType ~= TempClass.default.Acronym)		break;
    			if (GameType ~= TempClass.default.DecoTextName)	break;
    			if (Right(string(TempClass), Len(GameType)+1) ~= ("."$GameType))			break;
    			if (Right(TempClass.default.DecoTextName, Len(GameType)+1) ~= ("."$GameType))	break;
    		}
    		NextGame = Level.GetNextInt("Engine.GameInfo", ++i);
    	}
    	return NextGame;
    }

    ////////////////////////////////////////////////////////////
    // TODO: Find Centralized place for the following functions
    ////////////////////////////////////////////////////////////

    // TODO: Improve mask wildcards .. "*" = Any Size, "?" = 1 char
    // Mask can be *|*Name|Name*|*Name*|Name
    protected function bool MaskedCompare(string SettingName, string Mask)
    {
    local bool bMaskLeft, bMaskRight;
    local int MaskLen;

    	if (Mask == "*" || Mask == "**")
    		return true;

    	MaskLen = Len(Mask);
    	bMaskLeft = Left(Mask, 1) == "*";
    	bMaskRight = Right(Mask, 1) == "*";

    	if (bMaskLeft && bMaskRight)
    		return Instr(Caps(SettingName), Mid(Caps(Mask), 1, MaskLen-2)) >= 0;

    	if (bMaskRight)
    		return Left(SettingName, MaskLen -1) ~= Left(Mask, MaskLen - 1);

    	if (bMaskRight)
    		return Right(SettingName, MaskLen -1) ~= Right(Mask, MaskLen - 1);

    	return SettingName ~= Mask;
    }

    // TODO: Add support for bPositiveOnly
    function bool IsNumeric(string Param, optional bool bPositiveOnly)
    {
    local int p;

    	p=0;
    	while (Mid(Param, p, 1) == " ") p++;
    	while (Mid(Param, p, 1) >= "0" && Mid(Param, p, 1) <= "9") p++;
    	while (Mid(Param, p, 1) == " ") p++;

    	if (Mid(Param, p) != "")
    		return false;

    	return true;
    }

    function array<string> SplitParams(string Params)
    {
    local array<string> Splitted;
    local string Delim;
    local int p, start;

    	while (Params != "")
    	{
    		p = 0;
    		while (Mid(Params, p, 1) == " ") p++;
    		if (Mid(Params, p) == "")
    			break;

    		// Special case: Delimited string
    		start = p;
    		if (Mid(Params, p, 1) == "\"")
    		{
    			p++;
    			start++;
    			while (Mid(Params, p, 1) != "" && Mid(Params, p, 1) != "\"")
    				p++;

    			// Do not accept unfinished quoted strings
    			if (Mid(Params, p, 1) == "\"")
    			{
    				Splitted[Splitted.Length] = Mid(Params, start, p-start);
    				p++;
    			}
    		}
    		else
    		{
    			while (Mid(Params, p, 1) != "" && Mid(Params, p, 1) != Delim)
    				p++;
    			Splitted[Splitted.Length] = Mid(Params, start, p-start);
    		}
    		Params = Mid(Params, p);
    	}
    	return Splitted;
    }

    function PlayerController FindController(string playerNameOrId)
    {
    	local Controller C, NextC;

    	for (C = Level.ControllerList; C != None; C = NextC)
    	{
    		NextC = C.NextController;
    		if (C != Owner && PlayerController(C) != None && C.PlayerReplicationInfo != None)
    		{
    			if ((IsNumeric(playerNameOrId) && C.PlayerReplicationInfo.PlayerID == int(playerNameOrId))
    					|| MaskedCompare(C.PlayerReplicationInfo.PlayerName, playerNameOrId))
    			{
    				return PlayerController(C);
    			}
    		}
    	}
    	return None;
    }

    function string ReplaceTag(string from, string tag, coerce string value)
    {
    local string rep;

    	rep = from;
    	ReplaceText(rep, "%"$tag$"%", value);
    	return rep;
    }

    defaultproperties
    {
    	Msg_PlayerList="Player List:"
    	Msg_FinishGameEditFirst="You must finish your Game Edit before restarting the map"
    	Msg_FinishGameRestart="You must finish your Game Edit before changing or restarting the map"
    	Msg_GameNoSupportBots="The current Game Type does not support Bots"
    	Msg_StatsNoBots="Cannot control bots when Worlds Stats are enabled"
    	Msg_NextMapNotFound="Next Map Not Found, Restarting Same Map"
    	Msg_ChangingMapTo="Changing Map to %NextMap%"

    	Msg_PlayerBanned="%Player% has been Banned from this server"
    	Msg_SessionBanned="%Player% has been Banned for this match"
    	Msg_PlayerKicked="%Player% has been kicked"
    	Msg_NoBotGameFull="Cannot add a bot, Game is full"
    	Msg_NoAddNamedBot="Can Only Add Named Bots once the Match has Started"
    	Msg_NoBotsPlaying="No Bots are currently playing"
    	Msg_SetBotNeedVal="This Command Requires a Numeric Value between 0 and 32"

    	Msg_MutNeedGameEdit="You must use 'Game Edit' command before 'Mutators' commands"
    	Msg_NoMutatorInUse="No Mutators in use"
    	Msg_NoUnusedMuts="Found No Unused Mutators"
    	Msg_AddedMutator="Added '%Mutator%' To Used Mutator List"
    	Msg_ErrAddingMutator="Error Adding '%Mutator%'To Used Mutator List"
    	Msg_RemovedMutator="Removed '%Mutator%' From Used Mutator List"
    	Msg_ErrRemovingMutator="Error Removing '%Mutator%' From Used Mutator List"

    	Msg_MapListNeedGameEdit="You must use 'Game Edit' command before 'MapList' command"
    	Msg_MapRotationList="List of maps in rotation for %Game%"
    	Msg_NoMapInRotation="No Maps in rotation list"
    	Msg_NoMapsAdded="No Maps Added to the List"
    	Msg_AddedMapToList="Added '%Map%' To Map Rotation List"
    	Msg_NoMapsRemoved="No Maps Removed from the List"
    	Msg_RemovedMapFromList="Removed '%Map%' From Map Rotation List"
    	Msg_NoMapsFound="No Maps were Found"
    	Msg_MapIsInRotation="Map '%Map%' Is In Map Rotation List"
    	Msg_MapNotInRotation="Map '%Map%' Is Not In Map Rotation List"

    	Msg_MustEndGameEdit="You must end your Game Edit first"
    	Msg_EditingClass="Editing %Class%"
    	Msg_EditFailed="Failed Starting To Edit"
    	Msg_AlreadyEdited="Game Already being edited by Someone Else"
    	Msg_NotEditing="You are not editing Game Settings, use 'Game Edit' first"
    	Msg_EditingCompleted="Editing Completed"
    	Msg_EditingCancelled="Editing Cancelled"
    	Msg_UnknownParam="Unknown Parameter : %Value%"
    	Msg_NoParamsFound="No Parameters found!"
    	Msg_ParamModified="Modification SuccessFull"
    	Msg_ParamNotModified="Could not Modify Parameter"

    	Msg_PlayerSpectified="%Player% has been put into spectator mode"
    	Msg_TimeLimitChanged="The time limit has been changed to %Value%"
    	Msg_TourneyModeEnabled="Tournament mode has been enabled"
    	Msg_TourneyModeDisabled="Tournament mode has been disabled"
    	Msg_ForceStart="The match has been forced to start"
    	Msg_TeamDamageEnabled="Team damage has been enabled"
    	Msg_TeamDamageDisabled="Team damage has been disabled"
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: èt 30.9.2004 16:35:16.000 - Creation time: st 23.5.2018 00:10:40.846 - Created with UnCodeX