Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# TribesGUI.PlayerProfile

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371

    //
    // class: PlayerProfile
    //
    // Models data for multiplayer profile settings. Handles interfaces for saving,
    // loading and deleting MP profiles.  An MP profile includes: name, sex, voice set,
    // skin, equipment loadouts, and possibly GameSpy login information.
    //
    class PlayerProfile extends Core.Object
    	native
    	transient
    	EditInlineNew
    	dependsOn(CustomPlayerLoadout);

    struct native LoadoutSlot
    {
    	var() config String			loadoutName;
    	var() config String			combatRoleClassName;
    	var() config String			packClassName;
    	var() config String			grenadeClassName;
    	var() config Array<String>	weaponClassNameList;
    	var() config bool			occupied;
    	var() config Array<CustomPlayerLoadout.SkinPreferenceMapping>	skinPreferences;
    };

    struct native AutoLoginInfo
    {
    	var() config string IP;
    	var() config string Port;
    	var() config string Username;
    	var() config string Password;
    	var() config bool   bAutologin;
    };

    var(Profile) config bool bStoreLogins;
    var(Profile) config array<AutoLoginInfo> LoginHistory;

    struct native ServerFavorite
    {
    	var() config string IP;
    	var() config string Port;
    };

    var(Profile) config array<ServerFavorite> serverFavorites;

    var(Profile) config String	playerName	"Name of the Player";
    var(Profile) config bool	bIsFemale	"Whether the player is female";
    var(Profile) config String	voiceSet	"Voice set the player uses";
    var(Profile) config String	skinName	"Player skin";

    var(Profile) config Array<LoadoutSlot>	loadoutSlots;
    var(Profile) config LoadoutSlot			activeLoadoutSlot;
    var(Profile) config Array<String>		buddyList;

    var(Profile) config bool	bReadOnly;
    var(Profile) config bool	bShownMPHelp;

    var(Profile) config bool	bUseStatTracking;
    var(Profile) config bool	bSaveStatTrackingPassword;
    var(Profile) config string	statTrackingNick;
    var(Profile) config string	statTrackingEmail;
    var(Profile) config string	statTrackingPassword;
    var			 config int		statTrackingID; // 0 if none / not resolved

    var(Profile) config bool	bUseTeamAffiliation;
    var(Profile) config bool	bSaveTeamPassword;
    var			 config int		affiliatedTeamId;
    var(Profile) config string	affiliatedTeamTag;
    var(Profile) config string	affiliatedTeamName;
    var(Profile) config string	affiliatedTeamPassword;

    var(Profile) config string	ownedTeamTag;
    var(Profile) config string	ownedTeamName;

    var private Array<CustomPlayerLoadout>	loadouts;
    var private CustomPlayerLoadout			activeLoadout;

    var GUIController	controller;
    var private String	configFilePath;

    cpptext
    {

    	// loads the profile data
    	void LoadProfileData(UGUIController* gc);

    }

    native function LoadProfileData(String profileName);

    simulated function Store()
    {
    	local int i;

    	if (bReadOnly)
    		return;

    	if (!bSaveStatTrackingPassword)
    		statTrackingPassword = "";

    	if (!bSaveTeamPassword)
    		affiliatedTeamPassword = "";

    	if(configFilePath == "")
    		configFilePath = "Profiles\\"$Name;

    	for(i = 0; i < loadouts.Length; ++i)
    		SlotFromLoadout(loadouts[i], loadoutSlots[i]);
    	if(activeLoadout != None)
    		SlotFromLoadout(activeLoadout, activeLoadoutSlot);

    	SaveConfig( , configFilePath);
    }

    simulated function CustomPlayerLoadout GetLoadoutAutoCreate(int slot)
    {
    	local CustomPlayerLoadout loadout;
    	local string newName;

    	if(loadouts.Length <= slot || loadouts[slot] == None)
    	{
    		newName = self.Name$"Loadout"$slot;
    		loadout = new(None, newName) class'CustomPlayerLoadout';
    		AddLoadout(loadout, slot);
    	}
    	else
    	{
    		loadout = loadouts[slot];
    	}

    	return loadout;
    }

    simulated private function AddLoadout(out CustomPlayerLoadout loadout, int slot)
    {
    	if(loadouts.Length <= slot)
    		loadouts.Length = slot + 1;
    	loadouts[slot] = loadout;

    	if(loadoutSlots.Length <= slot)
    		loadoutSlots.Length = slot + 1;

    //	if(loadoutSlots[slot].occupied == true)
    //	{
    		// occupied slot, load the loadout from the slot
    		LoadoutFromSlot(loadoutSlots[slot], loadout);
    //	}
    }

    simulated function CustomPlayerLoadout GetActiveLoadout()
    {
    	if(activeLoadout == None && activeLoadoutSlot.occupied == true)
    	{
    		// the active loadout slot is occupied:
    		activeLoadout = new class'CustomPlayerLoadout';
    		LoadoutFromSlot(activeLoadoutSlot, activeLoadout);
    	}

    	return activeLoadout;
    }

    simulated function SetActiveLoadout(CustomPlayerLoadout loadout)
    {
    	if(activeLoadout == loadout)
    		return;

    	if(activeLoadout != None)
    	{
    		activeLoadout = None;
    	}

    	activeLoadout = loadout;
    	SlotFromLoadout(activeLoadout, activeLoadoutSlot);
    }

    simulated function CustomPlayerLoadout GetLoadout(int slotIndex)
    {
    	local CustomPlayerLoadout loadout;

    	if((slotIndex >= loadouts.Length || loadouts[slotIndex] == None) &&
    		(slotIndex < loadoutSlots.Length/* && loadoutSlots[slotIndex].occupied == true*/))
    	{
    		// if we auto create here, we know we will get a valid loadout,
    		// because the slot is occupied
    		loadout = GetLoadoutAutoCreate(slotIndex);
    	}
    	else if(slotIndex < loadouts.Length)
    		loadout = loadouts[slotIndex];

    	return loadout;
    }

    simulated function String GetURLOptions(optional string originalURL)
    {
    	local string AdminURL, CurrentIP, CurrentPort;
    	local int i;

    	Div(originalURL, ":", CurrentIP, CurrentPort);

    	i = FindCredentials(CurrentIP, CurrentPort);
    	if (i != -1 && LoginHistory[i].bAutoLogin)
    	{
    		AdminURL = "?AdminName="$LoginHistory[i].UserName$"?Password="$LoginHistory[i].Password;
    		Log("SET ADMIN URL to "$AdminURL);
    	}

    	// originalURL contains the server IP address and port
    	return "Name=" $EncodeForURL(PlayerName)
    			$"?IsFemale=" $bIsFemale
    			$"?VoiceSet=" $voiceSet
    			$AdminURL;
    }

    simulated function SlotFromLoadout(CustomPlayerLoadout loadout, out LoadoutSlot newSlot)
    {
    	local int i;

    	if(loadout == None)
    	{
    		// no loadout == unoccupied slot
    		newSlot.occupied = false;
    		return;
    	}

    	newSlot.occupied = true;
    	newSlot.loadoutName = loadout.loadoutName;
    	newSlot.skinPreferences = loadout.skinPreferences;
    	if(newSlot.loadoutName == "")
    		newSlot.loadoutName = "Loadout";
    	if(loadout.combatRoleClass != None)
    		newSlot.combatRoleClassName = String(loadout.combatRoleClass.Outer.Name)$"."$String(loadout.combatRoleClass.Name);
    	else
    		log("Warning: CombatRoleClass was none for loadout "$loadout);
    	if(loadout.packClass != None)
    		newSlot.packClassName = String(loadout.packClass.Outer.Name)$"."$String(loadout.packClass.Name);
    	if(loadout.grenades.grenadeClass != None)
    		newSlot.grenadeClassName = String(loadout.grenades.grenadeClass.Outer.Name)$"."$String(loadout.grenades.grenadeClass.Name);
    	newSlot.weaponClassNameList.Length = loadout.weaponList.Length;
    	for(i = 0; i < loadout.weaponList.Length; ++i)
    	{
    		if(loadout.weaponList[i].weaponClass != None)
    			newSlot.weaponClassNameList[i] = String(loadout.weaponList[i].weaponClass.Outer.Name)$"."$String(loadout.weaponList[i].weaponClass.Name);
    	}
    }

    simulated function LoadoutFromSlot(LoadoutSlot slot, out CustomPlayerLoadout loadout)
    {
    	local int i;

    	loadout.loadoutName = slot.loadoutName;
    	loadout.skinPreferences = slot.skinPreferences;
    	if(loadout.loadoutName == "")
    		loadout.loadoutName = "Loadout";
    	loadout.combatRoleClass = Class<CombatRole>(DynamicLoadObject(slot.combatRoleClassName, class'class'));
    	if(slot.packClassName != "")
    		loadout.packClass = Class<Pack>(DynamicLoadObject(slot.packClassName, class'class'));
    	if(slot.grenadeClassName != "")
    		loadout.grenades.grenadeClass = Class<HandGrenade>(DynamicLoadObject(slot.grenadeClassName, class'class'));
    	loadout.weaponList.Length = slot.weaponClassNameList.Length;
    	for(i = 0; i < slot.weaponClassNameList.Length; ++i)
    	{
    		if(slot.weaponClassNameList[i] != "")
    			loadout.weaponList[i].weaponClass = Class<Weapon>(DynamicLoadObject(slot.weaponClassNameList[i], class'class'));
    	}
    }

    // returns true if user input is required to complete the stat-tracking login
    function bool needStatTrackingUserInput()
    {
    	return statTrackingNick == "" || statTrackingEmail == "" || statTrackingPassword == "";
    }

    // returns true if user input is required to complete the team affiliation login
    function bool needTeamAffiliationUserInput()
    {
    	return bUseTeamAffiliation && (affiliatedTeamTag == "" || affiliatedTeamPassword == "");
    }

    // Autologin for admins
    function int FindCredentials( coerce string IP, coerce string Port )
    {
    	local int i;

    	Log("Finding admin credentials for "$IP$":"$Port);
    	for ( i = 0; i < LoginHistory.Length; i++ )
    		if ( LoginHistory[i].IP == IP && LoginHistory[i].Port == Port )
    		{
    			Log("FOUND ADMIN credentials at index "$i);
    			return i;
    		}

    	Log("Couldn't find ADMIN CREDENTIALS");
    	return -1;
    }

    function SaveCredentials(string Username, string Password, string IP, string Port, bool bAutoLogin)
    {
    	local AutoLoginInfo NewInfo;
    	local int i;

    	if ( !bStoreLogins || IP == "" || Port == "" )
    		return;

    	Log("Saving credentials, "$IP@Port@Username@Password);

    	NewInfo.UserName = Username;
    	NewInfo.Password = Password;
    	if ( NewInfo.Password == "" )
    		return;

    	NewInfo.IP = IP;
    	NewInfo.Port = Port;
    	NewInfo.bAutoLogin = bAutoLogin;

    	i = FindCredentials(NewInfo.IP, NewInfo.Port);
    	if ( i == -1 )
    	{
    		i = LoginHistory.Length;
    		LoginHistory.Length = LoginHistory.Length + 1;
    	}

    	LoginHistory[i] = NewInfo;
    	Store();
    }

    function toggleServerFavorite(string IP, string Port)
    {
    	local int i;

    	// If it already exists, get rid of it (toggle it off)
    	for (i=0; i<serverFavorites.Length; i++)
    	{
    		if (serverFavorites[i].IP == IP && serverFavorites[i].Port == Port)
    		{
    			serverFavorites.Remove(i, 1);
    			return;
    		}
    	}

    	// Otherwise, it's a new favorite, so add it
    	serverFavorites.Length = serverFavorites.Length + 1;
    	serverFavorites[serverFavorites.Length - 1].IP = IP;
    	serverFavorites[serverFavorites.Length - 1].Port = Port;
    	Store();
    }

    function bool hasServerFavorite(string IP, string Port)
    {
    	local int i;

    	// If it already exists, get rid of it (toggle it off)
    	for (i=0; i<serverFavorites.Length; i++)
    	{
    		if (serverFavorites[i].IP == IP && serverFavorites[i].Port == Port)
    		{
    			return true;
    		}
    	}

    	return false;
    }

    defaultproperties
    {
    	playerName	= "Player"
    	bIsFemale	= false
    	bUseStatTracking = false
    	bSaveStatTrackingPassword = true
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: st 16.4.2014 10:20:44.000 - Creation time: st 23.5.2018 00:10:46.498 - Created with UnCodeX