Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Gameplay.TeamInfo

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431
00432
00433
00434
00435
00436
00437
00438
00439
00440
00441
00442
00443
00444
00445
00446
00447
00448
00449
00450
00451
00452
00453
00454
00455
00456
00457
00458
00459
00460
00461
00462
00463
00464
00465
00466
00467
00468
00469
00470
00471
00472
00473
00474
00475
00476
00477
00478
00479
00480
00481
00482
00483
00484
00485
00486
00487
00488
00489
00490
00491
00492
00493
00494
00495
00496
00497
00498
00499
00500
00501
00502
00503
00504
00505
00506
00507
00508
00509
00510
00511
00512
00513
00514
00515
00516
00517
00518
00519
00520
00521
00522
00523
00524
00525
00526
00527
00528
00529
00530
00531
00532
00533
00534
00535
00536
00537
00538
00539
00540
00541
00542
00543
00544
00545
00546
00547
00548
00549
00550
00551
00552
00553
00554
00555
00556
00557
00558
00559
00560
00561
00562
00563
00564
00565
00566
00567
00568
00569
00570
00571
00572
00573
00574
00575
00576
00577
00578
00579
00580
00581
00582
00583
00584
00585
00586
00587
00588
00589
00590
00591
00592
00593
00594
00595
00596
00597
00598
00599
00600
00601
00602
00603
00604
00605
00606
00607
00608
00609
00610
00611
00612
00613
00614
00615
00616
00617
00618
00619
00620
00621
00622
00623
00624
00625
00626
00627
00628
00629
00630
00631
00632
00633
00634
00635
00636
00637
00638
00639
00640
00641
00642
00643
00644
00645
00646
00647
00648
00649
00650
00651
00652

    class TeamInfo extends Engine.Info
    	placeable
    	native;

    const MAX_RESPAWN_VEHICLES_DEFINE = 10;

    struct native RoleData
    {
    	var() class<CombatRole>	role							"The role that this data applies to";
    	var() Mesh				mesh							"The mesh used for characters with this role when playing for this team";
    	var() Mesh				femaleMesh						"The mesh used for female characters with this role when playing for this team";
    	var() class<Jetpack>	jetpack							"The jetpack used for characters with this role when playing for this team";
    	var() class<Jetpack>	femaleJetpack					"The jetpack mesh used for female characters with this role when playing for this team";
    	var() Mesh				armsMesh						"The arms used for the characters with this role when playing for this team";
    	var() Material			armorIcon						"The Icon representation for this combat roles armor";
    };

    var() Array<RoleData>				combatRoleData;
    var() localized string				localizedName;
    var() Material						ownershipMaterial			"The material used for the ownership badge on Base Devices owned by this team";
    var() Material						baseDeviceIllumMaterial		"The material used for self-illumination on Base Devices owned by this team";
    var() Material						altOwnershipMaterial		"An alternate material used for the ownership badge on Base Devices owned by this team; if specified, overrides ownershipMaterial";
    var() Material						altBaseDeviceIllumMaterial	"An alternate material used for self-illumination on Base Devices owned by this team; if specified, overrides baseDeviceIllumMaterial";
    var() Color							territoryTendrilColor		"Color of this team's terriory capture tendril";

    var float							objectivesUpdateRate;
    var ObjectivesList					objectives;				// Team objectives
    var int								score;
    var bool							bWonLastRound;

    var const int						MAX_BASES;
    var	array<BaseInfo>					bases;					// Bases available for this team

    // Parallel arrays
    var	BaseInfo						respawnBases[10];			// bases which are available for respawn
    var string							respawnBaseNames[10];		// names of the respawn bases
    var Vector							respawnBaseLocations[10];	// locations of the respawn bases

    // 10 has been choosen - should be maximum number of respawn point vehicles available in any level
    var const int						MAX_RESPAWN_VEHICLES;
    var Vehicle							respawnVehicles[MAX_RESPAWN_VEHICLES_DEFINE];

    //var private SensorTower teamSensor;
    var private Array<SensorTower> sensorGrid;
    var(SensorSystem) float sensorGridRate;
    var private float lastUpdateTime;
    var private Array<Rook> detectedEnemies;
    var private Array<Rook> detectedFriendlies;
    var bool bSensorGridFunctional;

    var int numPlayerStarts;

    var() Material buggySkin;
    var() Material podSkin;
    var() Material tankSkin;
    var() Material assaultShipSkin;

    var() TeamInfo onlyDamagedByTeam			"Only the specified team will be able to damage members of this team.";

    var bool bNoMoreCarryables;

    var() color TeamColor;
    var() color TeamHighlightColor;
    var() color RelativeFriendlyTeamColor;
    var() color RelativeFriendlyHighlightColor;
    var() color RelativeEnemyTeamColor;
    var() color RelativeEnemyHighlightColor;

    var int TeamIndex;

    replication
    {
    	reliable if (ROLE == ROLE_Authority)
    		objectives, score, ownershipMaterial, sensorGridRate, bWonLastRound,
    		respawnVehicles, respawnBases, /*respawnBaseNames, respawnBaseLocations,*/
    		bNoMoreCarryables, bSensorGridFunctional, TeamIndex;
    }

    // PostBeginPlay
    function PostBeginPlay()
    {
    	Super.PostBeginPlay();

    	// init objectives
    	objectives = spawn(class'ObjectivesList');

    	if (ownershipMaterial == None)
    		ownershipMaterial = Material(DynamicLoadObject("BaseObjects.OwnershipScreen", class'Shader'));
    }

    function evaluatePlayerStarts()
    {
    	local PlayerStart p;

    	// Figure out how many playerStarts are left for this team after any filtering has taken place
    	ForEach DynamicActors(class'PlayerStart', p)
    	{
    		if (p.team == self || (p.baseInfo != None && p.baseInfo.team == self))
    			numPlayerStarts++;
    	}
    }

    simulated function String GetHumanReadableName()
    {
    	return localizedName;
    }

    // isFriendly
    // returns true if the given team is friendly to this team
    simulated function bool isFriendly(TeamInfo t)
    {
    	return t == self || t == None;
    }

    // getMeshForRole
    // returns the mesh that a character on this team should use for the given role
    simulated function Mesh getMeshForRole(class<CombatRole> c, bool bIsFemale)
    {
    	local int i;

    	for (i = 0; i < combatRoleData.Length; i++)
    	{
    		if (combatRoleData[i].role == c)
    		{
    			if (bIsFemale)
    				return combatRoleData[i].femaleMesh;
    			else
    				return combatRoleData[i].mesh;
    		}
    	}
    }

    // getJetpackMeshForRole
    // returns the jetpack mesh that a character of this team should use for the given role
    simulated function Jetpack getJetpackForRole(Actor ownerActor, class<CombatRole> c, bool bIsFemale)
    {
    	local int i;

    	for (i = 0; i < combatRoleData.Length; i++)
    	{
    		if (combatRoleData[i].role == c)
    		{
    			if (bIsFemale)
    			{
    				if (combatRoleData[i].femaleJetpack != None)
    					return Spawn(combatRoleData[i].femaleJetpack, ownerActor);
    				else
    					return None;
    			}
    			else
    			{
    				if (combatRoleData[i].jetpack != None)
    					return Spawn(combatRoleData[i].jetpack, ownerActor);
    				else
    					return None;
    			}
    		}
    	}
    }

    // getArmsMeshForRole
    // returns the arms mesh that a character of this team should use for the given role
    simulated function Mesh getArmsMeshForRole(class<CombatRole> c)
    {
    	local int i;

    	for (i = 0; i < combatRoleData.Length; i++)
    		if (combatRoleData[i].role == c)
    			return combatRoleData[i].armsMesh;
    }

    // GetArmorIconForRole
    // Returns the armor icon which this team should use for the given role
    simulated function Material GetArmorIconForRole(class<CombatRole> c)
    {
    	local int i;

    	for (i = 0; i < combatRoleData.Length; i++)
    		if (combatRoleData[i].role == c)
    			return combatRoleData[i].armorIcon;
    }

    function Tick(float Delta)
    {
    	// Level.IsEntry doesnt always work for some reason.
    	// Have to check the outer name
    	if(Level.Outer.Name == 'Entry')
    		return;

    	objectives.updateObjectives(objectivesUpdateRate, self);
    	tickSensors();
    }

    // -------------------------------------------------------------------------------------
    // Sensor System
    // -------------------------------------------------------------------------------------

    function addTeamSensor(SensorTower newTeamSensor)
    {
    	local int i;

    	for (i = 0; i < sensorGrid.Length; ++i)
    		if (sensorGrid[i] == newTeamSensor)
    			return;

    	sensorGrid[sensorGrid.Length] = newTeamSensor;
    }

    function removeTeamSensorSensorTower(SensorTower oldTeamSensor)
    {
    	local int i;

    	for (i = 0; i < sensorGrid.Length; ++i)
    	{
    		if (sensorGrid[i] == oldTeamSensor)
    		{
    			sensorGrid.Remove(i, 1);
    			return;
    		}
    	}
    }

    function bool sensorGridFunctional()
    {
    	local int i;

    	for (i = 0; i < sensorGrid.Length; ++i)
    		if (sensorGrid[i].isFunctional())
    		{
    			bSensorGridFunctional = true;
    			return true;
    		}

    	bSensorGridFunctional = false;
    	return false;
    }

    //function setTeamSensor(SensorTower newTeamSensor)
    //{
    //	teamSensor = newTeamSensor;
    //}

    // start point for all sensor ticking. we can optimise sensor code by making it native as neccesary in here
    native function tickSensors();

    function bool sensorIsFriendlyRook(Rook r)
    {
    	// use last occupant team if vehicle
    	if (r.isA('Vehicle') && Vehicle(r).lastOccupantTeam != None)
    		return isFriendly(Vehicle(r).lastOccupantTeam);

    	return isFriendlyRook(r);
    }

    function bool isFriendlyRook(Rook r) // Handles vehicles (i.e. an enemy vehicle with a friendly driver is a friend)
    {
    	if (r.getControllingCharacter() != None)
    		return isFriendly(r.getControllingCharacter().team());
    	else
    		return isFriendly(r.team());
    }

    event updateSensors()
    {
    	local Rook currRook;
    	local Controller c;
    	local PlayerCharacterController pcc;

    	currRook = Rook(Level.pawnList);

    	detectedEnemies.Length = 0;
    	detectedFriendlies.Length = 0;

    	while (currRook != None)
    	{
    		if (currRook.canBeSensed() && currRook.isAlive())
    		{
    			if (sensorIsFriendlyRook(currRook))
    			{
    				detectedFriendlies[detectedFriendlies.Length] = currRook;
    			}
    			else if (sensorGridFunctional() && currRook.bIsDetectableByEnemies)
    			{
    				detectedEnemies[detectedEnemies.Length] = currRook;
    			}
    		}

    		currRook = Rook(currRook.nextPawn);
    	}

    	// Update the sensor info for each player member of the team
    	for (c = Level.ControllerList; c != None; c = c.nextController)
    	{
    		pcc = PlayerCharacterController(c);

    		if (pcc != None && pcc.Character != None && isFriendly(pcc.Character.team()))
    			updateTeamMemberSensorInfo(pcc);
    	}
    }

    function updateTeamMemberSensorInfo(PlayerCharacterController pcc)
    {
    	local SensorListNode sln;
    	local int i;

    	sln = pcc.detectedEnemyList;

    	// Update the currently sensed enemies
    	while (sln != None)
    	{
    		if (pcc.Pawn == sln.sensedRook || class'Pawn'.static.checkDead(sln.sensedRook))
    		{
    			pcc.removeDetectedEnemy(sln);
    		}
    		else
    		{
    			for (i = 0; i < detectedEnemies.length; ++i)
    			{
    				if (detectedEnemies[i] == sln.sensedRook)
    				{
    					sln.update();
    					break;
    				}
    			}

    			// If the rook is no longer being detected remove it from the list
    			if (i == detectedEnemies.length)
    				pcc.removeDetectedEnemy(sln);
    		}

    		sln = sln.next;
    	}

    	// Add any newly detected enemies to the characters detectedEnemyList
    	for (i = 0; i < detectedEnemies.length; ++i)
    	{
    		// If this rook hasn't been updated yet
    		if (!detectedEnemies[i].sensorUpdateFlag)
    			pcc.addDetectedEnemy(detectedEnemies[i]);

    		detectedEnemies[i].sensorUpdateFlag = false;
    	}

    	sln = pcc.detectedFriendlyList;

    	// Update the currently sensed friendlies
    	while (sln != None)
    	{
    		if (pcc.Pawn == sln.sensedRook || class'Pawn'.static.checkDead(sln.sensedRook))
    		{
    			pcc.removeDetectedFriendly(sln);
    		}
    		else
    		{
    			for (i = 0; i < detectedFriendlies.length; ++i)
    			{
    				if (detectedFriendlies[i] == sln.sensedRook)
    				{
    					sln.update();
    					break;
    				}
    			}

    			// If the rook is no longer being detected remove it from the list
    			if (i == detectedFriendlies.length)
    				pcc.removeDetectedFriendly(sln);
    		}

    		sln = sln.next;
    	}

    	// Add any newly detected friendlies to the characters detectedFriendlyList
    	for (i = 0; i < detectedFriendlies.length; ++i)
    	{
    		// If this rook hasn't been updated yet
    		if (!detectedFriendlies[i].sensorUpdateFlag)
    			pcc.addDetectedFriendly(detectedFriendlies[i]);

    		detectedFriendlies[i].sensorUpdateFlag = false;
    	}
    }

    // -------------------------------------------------------------------------------------
    // End Sensor System
    // -------------------------------------------------------------------------------------

    // -----------------------------------
    // Vehicle Respawn
    //

    function addVehicleRespawn(Vehicle respawnVehicle)
    {
    	local int index;

    	// verify not already there
    	for (index = 0; index < MAX_RESPAWN_VEHICLES; ++index)
    	{
    		if (respawnVehicles[index] == respawnVehicle)
    		{
    			warn("attempted to add" @ respawnVehicle @ "to respawn vehicle list but it is already there");
    			return;
    		}
    	}

    	// add it
    	for (index = 0; index < MAX_RESPAWN_VEHICLES; ++index)
    	{
    		if (respawnVehicles[index] == None)
    		{
    			respawnVehicles[index] = respawnVehicle;
    			break;
    		}
    	}
    	if (index == MAX_RESPAWN_VEHICLES)
    		warn("exceeded size of respawn vehicle array");

    	Log("added vehicle respawn" @ respawnVehicle @ "to" @ self);
    }

    // Can be called even if respawnVehicle has already been removed.
    function removeVehicleRespawn(Vehicle respawnVehicle)
    {
    	local int index;

    	// find the vehicle and remove it
    	for (index = 0; index < MAX_RESPAWN_VEHICLES; index++)
    	{
    		if (respawnVehicles[index] == respawnVehicle)
    		{
    			respawnVehicles[index] = None;
    			break;
    		}
    	}
    }

    simulated function bool validVehicleRespawnIndex(int index)
    {
    	return respawnVehicles[index] != None && respawnVehicles[index].canCharacterRespawnAt();
    }

    simulated function int getNumVehicleRespawns()
    {
    	local int index;
    	local int result;

    	for (index = 0; index < MAX_RESPAWN_VEHICLES; index++)
    		if (respawnVehicles[index] != None)
    			++result;

    	return result;
    }

    //
    // End Vehicle Respawn
    // -----------------------------------

    // -----------------------------------
    // Bases
    //

    function addBase(BaseInfo base)
    {
    	local int i;

    	// check first, to see if we have the base
    	for(i = 0; i < bases.Length; ++i)
    	{
    		if(bases[i] == base)
    			return;
    	}

    	// dont already have the base, add it
    	bases[bases.Length] = base;
    	Log("Added base "$base);

    	// update the respawn bases & names array
    	if(base.bValidRespawnBase && base.spawnArray != None)
    	{
    		for(i = 0; i < MAX_BASES; ++i)
    		{
    			if (respawnBases[i] == None)
    			{
    				Log("Added respawn base "$base$ " at index "$i);
    				respawnBases[i] = base;
    				respawnBaseNames[i] = string(respawnBases[i].label);
    				respawnBaseLocations[i] = respawnBases[i].spawnArray.Location;
    				break;
    			}
    		}
    	}
    }

    function removeBase(BaseInfo base)
    {
    	local int i;

    	// find the base and remove it, and allow multiple removes
    	for(i = 0; i < bases.Length; i++)
    	{
    		if(bases[i] == base)
    			bases.Remove(i, 1);
    	}

    	// update the base names array
    	if(base.bValidRespawnBase)
    	{
    		for(i = 0; i < MAX_BASES; ++i)
    		{
    			if(respawnBases[i] == base)
    			{
    				respawnBases[i] = None;
    				respawnBaseNames[i] = "";
    				respawnBaseLocations[i] = Vect(0,0,0);
    				break;
    			}
    		}
    	}
    }

    simulated function bool validRespawnBaseIndex(int index)
    {
    	return respawnBases[index] != None;
    }

    simulated function int getNumRespawnBases()
    {
    	local int i, numBases;

    	for (i=0; i<MAX_BASES; i++)
    	{
    		if (respawnBases[i] != None)
    			numBases++;
    	}

    	return numBases;
    }

    // End Bases
    // -----------------------------------

    function int numPlayers()
    {
    	local int i;
    	local int numPlayers;
    	local TribesReplicationInfo tri;

    	for (i=0; i<Level.Game.GameReplicationInfo.PRIArray.Length; i++)
    	{
    		tri = TribesReplicationInfo(Level.Game.GameReplicationInfo.PRIArray[i]);

    		if (tri != None && tri.team == self)
    			numPlayers++;
    	}

    	return numPlayers;
    }

    function int numActivePlayers()
    {
    	local PlayerCharacterController pc;
    	local int i;

    	ForEach Level.AllControllers(class'PlayerCharacterController', pc)
    	{
    		if (pc.Pawn != None && self == Rook(pc.Pawn).team())
    			i++;
    	}

    	return i;
    }

    function int numTotalLives()
    {
    	local PlayerCharacterController pc;
    	local int i;

    	ForEach Level.AllControllers(class'PlayerCharacterController', pc)
    	{
    		if (TribesReplicationInfo(pc.PlayerReplicationInfo).team == self)
    		{
    			// If respawnsLeft is < 0, then just return -1 to indicate that respawn
    			// restrictions are disabled
    			if (pc.livesLeft < 0)
    				return -1;

    			i += pc.livesLeft;
    		}
    	}

    	return i;
    }

    // PRECACHING
    simulated function UpdatePrecacheRenderData()
    {
    	local int i;
    	Super.UpdatePrecacheRenderData();

    	// precache all team mesh data
    	// NOTE: Only precache coree team meshes in MP matches
    	if (Level.NetMode != NM_Standalone)
    	{
    		for (i=0; i < combatRoleData.Length; ++i)
    		{
    			Level.AddPrecacheMesh(combatRoleData[i].mesh);
    			Level.AddPrecacheMesh(combatRoleData[i].femaleMesh);
    			Level.AddPrecacheMesh(combatRoleData[i].armsMesh);
    			Level.AddPrecacheMaterial(combatRoleData[i].armorIcon);
    			if (combatRoleData[i].jetpack != None)
    				Level.AddPrecacheStaticMesh(combatRoleData[i].jetpack.default.StaticMesh);
    			if (combatRoleData[i].femaleJetpack != None)
    				Level.AddPrecacheStaticMesh(combatRoleData[i].femaleJetpack.default.StaticMesh);
    		}

    		// precache vehicle skins
    		Level.AddPrecacheMaterial(buggySkin);
    		Level.AddPrecacheMaterial(podSkin);
    		Level.AddPrecacheMaterial(tankSkin);
    		Level.AddPrecacheMaterial(assaultShipSkin);
    	}

    	// precache ownership stuff
    	Level.AddPrecacheMaterial(ownershipMaterial);
    	Level.AddPrecacheMaterial(baseDeviceIllumMaterial);
    	Level.AddPrecacheMaterial(altOwnershipMaterial);
    	Level.AddPrecacheMaterial(altBaseDeviceIllumMaterial);
    }

    defaultproperties
    {
    	objectivesUpdateRate = 0.5
    	sensorGridRate	= 0.5

    	RemoteRole		= ROLE_SimulatedProxy
    	bAlwaysRelevant = true
    	bReplicateLabel = true
    	bHiddenEd		= true

    	MAX_BASES		= 10

    	MAX_RESPAWN_VEHICLES = 10

    	TeamColor			= (R=255,G=255,B=255,A=255)
    	TeamHighlightColor	= (R=255,G=255,B=0,A=255)
    	relativeFriendlyTeamColor=(R=20,G=220,B=20,A=255)
    	relativeFriendlyHighlightColor=(R=0,B=0,G=255,A=255)
    	relativeEnemyTeamColor=(R=220,G=20,B=20,A=255)
    	relativeEnemyHighlightColor=(R=255,G=0,B=0,A=255)
    	territoryTendrilColor = (R=255,G=255,B=255,A=255)
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: čt 9.9.2004 16:25:32.000 - Creation time: st 23.5.2018 00:10:47.537 - Created with UnCodeX