Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Tyrion.AI_Investigate

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102

    //=====================================================================
    // AI_Investigate
    // Move to a location and look around.
    // The action terminates more than "searchTime" seconds have elapsed
    //=====================================================================

    class AI_Investigate extends AI_MovementAction
    	editinlinenew;

    //=====================================================================
    // Constants

    //=====================================================================
    // Variables

    var(Parameters) editinline Name destinationName "A path node label";
    var(Parameters) float searchTime "How long (in seconds) to look for target at destination";

    var(InternalParameters) Pawn target;	// the pawn being looked for (can be None)
    var(InternalParameters) editconst Vector destination;

    var ACT_ErrorCodes errorCode;		// errorcode from child action
    var Actor node;						// destination node

    //=====================================================================
    // Functions

    //---------------------------------------------------------------------
    // Callbacks from Navigation System actions

    function actionSucceededCB( NS_Action child )
    {
    	super.actionSucceededCB( child );
    	errorCode = ACT_SUCCESS;
    }

    function actionFailedCB( NS_Action child, ACT_ErrorCodes anErrorCode )
    {
    	super.actionFailedCB( child, anErrorCode );
    	errorCode = anErrorCode;
    }

    //---------------------------------------------------------------------

    function cleanup()
    {
    	super.cleanup();

    	if ( class'Pawn'.static.checkAlive( resource.pawn() ) )
    		AI_Controller(resource.pawn().controller).stopMove();
    }

    //=====================================================================
    // State code

    state Running
    {
    Begin:
    	if ( destinationName != '' )
    	{
    		node = resource.pawn().findStaticByLabel( class'Pathfinding.PlacedNode', destinationName );

    		if ( node == None )
    		{
    			log( "AI WARNING:" @ name @ "(" @ resource.pawn().name @ ") can't find specified path node" @ destinationName );
    			fail( ACT_INVALID_PARAMETERS, true );
    		}

    		destination = node.Location;
    	}

    	if ( resource.pawn().logTyrion )
    		log( name @ "started." @ resource.pawn().name @ "is investigating" @ destination );

    	waitForAction( class'NS_MoveToLocation'.static.startAction( AI_Controller(resource.pawn().controller),
    					self, destination
    					/*, skiCompetency, jetCompetency, groundMovement, energyUsage */));

    	if ( errorCode != ACT_SUCCESS )
    	{
    		if ( resource.pawn().logTyrion )
    			log( name @ "(" @ resource.pawn().name @ ") couldn't get to investigation location" @ errorCode );
    		fail( errorCode );
    	}

    	if ( resource.pawn().logTyrion )
    		log( name $ ":" @ resource.pawn().name @ "is looking around." );

    	waitForGoal( (new class'AI_SearchGoal'( resource, achievingGoal.priority, target, GM_Walk )).postGoal( self ), true );

    	if ( resource.pawn().logTyrion )
    		log( name @ "stopped." );

    	succeed();
    }

    //=====================================================================

    defaultproperties
    {
    	satisfiesGoal = class'AI_InvestigateGoal'
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:54:00.000 - Creation time: st 23.5.2018 00:10:41.373 - Created with UnCodeX