Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Tyrion.AI_Grapple

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219

    //=====================================================================
    // AI_Grapple
    // Try to bring an opponent down to the ground or slow him down with the grappler
    //=====================================================================

    class AI_Grapple extends AI_CharacterAction implements IWeaponSelectionFunction
    	editinlinenew;

    //=====================================================================
    // Constants

    const REEL_IN_DIST = 750.0f;	// distance to reel in target to

    //=====================================================================
    // Variables

    var(Parameters) int rank "Rank of the grappler (1 or 2)";
    var(Parameters) editinline Name targetName "Label of target (any Pawn)";
    var(Parameters) class<Weapon> preferredWeaponClass "AI will use this weapon if at all possible";

    var(InternalParameters) editconst Pawn target;
    var(InternalParameters) editconst IWeaponSelectionFunction weaponSelection;
    var(InternalParameters) editconst IFollowFunction followFunction;

    var() float idealBlasterRange "Preferred distance at which to use the blaster";

    var BaseAICharacter ai;
    var Vector aimLocation;
    var ACT_Errorcodes errorCode;

    //=====================================================================
    // Functions

    //---------------------------------------------------------------------
    // callbacks from sub-goals;
    // they are only used to stop the action when any success/failure message
    // comes up that isn't an interruption
    // todo: automate this process? A new flag on goals/waitForGoals?
    /*
    function goalAchievedCB( AI_Goal goal, AI_Action child )
    {
    	super.goalAchievedCB( goal, child );

    	errorCode = ACT_SUCCESS;
    	runAction();
    }

    function goalNotAchievedCB( AI_Goal goal, AI_Action child, ACT_ErrorCodes anErrorCode )
    {
    	super.goalNotAchievedCB( goal, child, anErrorCode );

    	errorCode = anErrorCode;

    	if ( errorCode != ACT_INTERRUPTED )
    		runAction();
    }
    */
    //---------------------------------------------------------------------
    // function for determining what weapon to use

    function Weapon bestWeapon( Character ai, Pawn target, class<Weapon> preferredWeaponClass )
    {
    	local Weapon w;

    	// always use the blaster to shoot
    	w = Weapon( ai.nextEquipment( None, class'Blaster' ));
    	if ( w != None && w.hasAmmo() )
    		return w;

    	return ai.weapon;	// no weapon found: keep holding what you got
    }

    //---------------------------------------------------------------------
    // best range at which to shoot weapon

    function float firingRange( class<Weapon> weaponClass )
    {
    	return idealBlasterRange;
    }

    //---------------------------------------------------------------------
    // are conditions met for firing this weapon?

    function bool bShouldFire( BaseAICharacter ai, Weapon weapon )
    {
    	return true;
    }

    //---------------------------------------------------------------------

    function cleanup()
    {
    	super.cleanup();

    	weaponSelection = None;
    	followFunction = None;

    	// when GruntAttack deactivates, AI keeps on moving with his last direction
    	// (maybe there should be a default low-pri action that lands the AI?)
    	if ( class'Pawn'.static.checkAlive( resource.pawn() ) )
    		AI_Controller(resource.pawn().controller).stopMove();
    }

    //=====================================================================
    // State code

    state Running
    {
    Begin:
    	if ( rank != 1 && rank != 2 )
    	{
    		log( "AI ERROR: invalid rank" @ rank @ "given to grappler" @ Pawn.name );
    		fail( ACT_INVALID_PARAMETERS, true );
    	}

    	if ( target == None && targetName == '' )
    	{
    		log( "AI WARNING:" @ name @ "has no target" );
    		fail( ACT_INVALID_PARAMETERS, true );
    	}

    	ai = baseAICharacter();

    	if ( target == None )
    		target = Pawn(ai.findByLabel( class'Pawn', targetName, true ));

    	if ( pawn.logTyrion )
    		log( name @ "started." @ pawn.name @ "is grappling!" );

    	if ( target == None )
    	{
    		log( "AI WARNING:" @ name @ "can't find specified rook" );
    		fail( ACT_INVALID_PARAMETERS, true );
    	}

    	// start up attack goal (using the blaster)

    	(new class'AI_DirectAttackGoal'( characterResource(), achievingGoal.priority-1, target, self, preferredWeaponClass, followFunction )).postGoal( self );

    	// grappler control code
    	while( class'Pawn'.static.checkAlive( pawn ) &&  class'Pawn'.static.checkAlive( target ))
    	{
    		// should I grapple?
    		if ( !ai.bAttached && VDist( target.Location, pawn.Location ) <= ai.grapplerClass.default.maxRopeLength &&
    				ai.vision.isLocallyVisible( target ))
    		{
    			useResources( class'AI_Resource'.const.RU_ARMS );	// stop regular firing behavior

    			log( "!" @ ai.name @ "Switching to Grappler" );
    			ai.motor.setWeapon( Weapon( ai.nextEquipment( None, class'Grappler' )) );

    			Sleep( 1.0f );		// wait for weapon change
    			if ( class'Pawn'.static.checkDead( pawn ) || class'Pawn'.static.checkDead( target ) )
    				break;

    			//log( "!" @ ai.name @ "weapon equipped:" @ ai.weapon );
    			//log( "!" @ ai.name @ "Firing Grappler" );

    			// compute place to aim to
    			if ( ai.weapon == None )
    				aimLocation = target.Location;
    			else
    				aimLocation = ai.weapon.aimClass.static.getAimLocation( ai.weapon, target, 1.0f );

    			ai.motor.setViewRotation( Rotator(aimLocation - ai.Location) );
    			ai.motor.fire(true);

    			Sleep( 1.0f );		// wait for grapple to hit
    			if ( class'Pawn'.static.checkDead( pawn ) || class'Pawn'.static.checkDead( target ) )
    				break;

    			// should I reel in?
    			if ( ai.bAttached ) //&& ai.weapon.IsA( 'Grappler' ) )
    			{
    				if ( ai.proj != None && ai.proj.Base == target )	// Grappler hit the target?
    				{
    					//log( "!" @ ai.name @ "Reeling in" );
    					Grappler(ai.weapon).beginReelIn();

    					// todo: jetpack backwards to slow down target

    					while ( ai.bAttached &&
    							class'Pawn'.static.checkAlive( pawn ) &&  class'Pawn'.static.checkAlive( target ) &&
    							VDist( target.Location, pawn.Location ) > REEL_IN_DIST )
    						yield();

    					//log( "!" @ ai.name @ "Stopped reeling in" );
    					Grappler(ai.weapon).endReelIn();
    				}
    				else
    				{
    					//log( "!" @ ai.name @ "Detaching Grapple" );
    					ai.detachGrapple();
    				}
    			}
    			clearDummyWeaponGoal();			// resume regular firing behavior
    		}

    		yield();
    	}

    	if ( class'Pawn'.static.checkDead( target ) )
    	{
    		if ( pawn.logTyrion )
    			log( name @ "stopped. TARGET DEAD!" );
    		succeed();
    	}
    	else
    		fail( ACT_GENERAL_FAILURE );
    }

    //=====================================================================

    defaultproperties
    {
    	satisfiesGoal = class'AI_AttackGoal'

    	idealBlasterRange = 1500
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:54:00.000 - Creation time: st 23.5.2018 00:10:41.243 - Created with UnCodeX