Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Gameplay.Turret

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431
00432
00433
00434
00435
00436
00437
00438
00439
00440
00441
00442
00443
00444
00445
00446
00447
00448
00449
00450
00451
00452
00453
00454
00455
00456
00457
00458
00459
00460
00461
00462
00463
00464
00465
00466
00467
00468
00469
00470
00471
00472
00473
00474
00475
00476
00477
00478
00479
00480
00481
00482
00483
00484
00485
00486
00487
00488
00489
00490
00491
00492
00493
00494
00495
00496
00497
00498
00499
00500
00501
00502
00503
00504
00505
00506
00507
00508
00509
00510
00511
00512
00513
00514
00515
00516
00517
00518
00519
00520
00521
00522
00523
00524
00525
00526
00527
00528
00529
00530
00531
00532
00533
00534
00535
00536
00537
00538
00539
00540
00541
00542
00543
00544
00545
00546
00547
00548
00549
00550
00551
00552
00553
00554
00555
00556
00557
00558
00559
00560
00561
00562
00563
00564
00565
00566
00567
00568
00569
00570
00571
00572
00573
00574
00575
00576
00577
00578
00579
00580
00581
00582
00583
00584
00585
00586
00587
00588
00589
00590
00591
00592
00593
00594
00595
00596
00597
00598
00599
00600
00601
00602
00603
00604
00605
00606
00607
00608
00609
00610
00611
00612
00613
00614
00615
00616
00617
00618
00619
00620
00621
00622
00623
00624
00625
00626
00627
00628
00629
00630
00631
00632
00633
00634
00635
00636
00637
00638
00639
00640
00641
00642
00643
00644
00645
00646
00647
00648
00649
00650
00651
00652
00653
00654
00655
00656
00657
00658
00659
00660
00661
00662
00663
00664
00665
00666
00667
00668
00669
00670
00671
00672
00673
00674
00675
00676
00677
00678
00679
00680
00681
00682
00683
00684
00685
00686
00687
00688
00689
00690
00691
00692
00693
00694
00695
00696
00697
00698
00699
00700
00701
00702
00703
00704
00705
00706
00707
00708
00709
00710
00711
00712
00713
00714
00715
00716
00717
00718
00719
00720
00721
00722
00723
00724
00725
00726
00727
00728
00729
00730

    class Turret extends BaseDevice
    	native;

    var TurretMotor		motor;
    var Character		driver;
    var bool			bGetOut;
    var Rotator			initialRotation;
    var protected float	currentPitch;
    var protected float	currentYaw;
    var protected int	targetPitch;
    var protected int	targetYaw;

    var() class<Weapon> weaponClass;
    var() Name			driverAnimation			"The animation that the driver plays when seated in the turret";
    var() bool			bCanBeManned			"Whether or not the turret can be manned by characters";
    var() int			seatedCollisionHeight	"The collision height of the seated character";
    var() int			seatedCollisionRadius	"The collision radius of the seated character";

    ////////// CAMERA //////////

    var() float	MaxViewPitch		"0 to ignore, or maximum pitch amount in degrees (from initial rotation)"; 	// internally converted to unreal rot units
    var() float	MaxViewYaw			"0 to ignore, or maximum yaw amount in degrees (from initial rotation)"; 	// internally converted to unreal rot units
    var() private float ViewRate			"Maximum turret rotation rate in degrees per second";						// internally converted to unreal rot units
    var() private float AIViewRate			"Maximum turret rotation rate in degrees per second, while an AI is manning the turret";	// internally converted to unreal rot units

    var() name rootBone;
    var() name seatBone;
    var() name pitchBone;
    var() int yawOffset				"Offset added to the yaw used for rotation display, may need to be tweaked in some cases";

    var() int yawAxis				"The axis of rotation used for the yaw bone may sometimes need to be tweaked: 0, 1, 2 = X, Y, Z";
    var() int pitchAxis				"The axis of rotation used for the pitch bone may sometimes need to be tweaked: 0, 1, 2 = X, Y, Z";
    var() bool bFlipYawDisplay		"Turn this on if the turret appears to turn the wrong way";
    var() bool bFlipPitchDisplay	"Turn this on if the turret appears to pitch the wrong way";

    // character stuff
    var int oldCollisionHeight;
    var int oldCollisionRadius;

    // weapon stuff
    var Weapon	weapon;
    var Weapon	oldDriverWeapon;

    var bool bWasBehindView;

    struct native TurretEntryData
    {
    	var () float radius;
    	var () float height;
    	var () class<TurretEntry> turretEntryClass;
    };
    var() TurretEntryData entry;
    var TurretEntry TurretEntry;

    replication
    {
    	reliable if (Role == ROLE_Authority)
    		weapon, driver, initialRotation;

    	reliable if (Role == ROLE_Authority && !bNetOwner)
    		targetPitch, targetYaw;

    	reliable if (Role == ROLE_Authority)
    		ClientDriverEnter, ClientDriverLeave;
    }

    function PostBeginPlay()
    {
    	CreateVisionNotifier();
    	CreateHearingNotifier();

    	Super.PostBeginPlay();

    	initTurretAI();

    	weapon = Spawn(weaponClass,self,,location);
    	weapon.equip();
    	weapon.gotostate('Held');
    }

    function PostLoadGame()
    {
    	super.PostLoadGame();

    	if (driver != None)
    	{
    		driver.enterManualAnimationState();
    		driver.bReplicateAnimations = true;
    		driver.LoopAnim(driverAnimation);
    	}
    }

    simulated function PostNetReceive()
    {
    	local Rotator newRot;

    	Super.PostNetReceive();

    	if (motor != None)
    	{
    		newRot.Pitch = targetPitch;
    		newRot.Yaw = targetYaw;

    		motor.setViewTarget(newRot);
    	}
    }

    simulated function PostNetBeginPlay()
    {
    	Super.PostNetBeginPlay();

    	MaxViewYaw = (MaxViewYaw / 360) * 65536;
    	MaxViewPitch = (MaxViewPitch / 360) * 65536;
    	ViewRate = (ViewRate / 360) * 65536;
    	AIViewRate = (AIViewRate / 360) * 65536;

    	motor = new class'TurretMotor'(self);

    	// only have entry triggers on server
    	if (Level.NetMode != NM_Client && bCanBeManned)
    	{
    		if(entry.turretEntryClass == None)
    			entry.turretEntryClass = class'TurretEntry';
    		TurretEntry = spawn(entry.turretEntryClass, self, ,GetBoneCoords(seatbone).Origin);
    		TurretEntry.setBase(self);
    		TurretEntry.setCollision(true, false, false);
    		TurretEntry.setCollisionSize(entry.radius, entry.height);

    		// Update useable points array
    		UseablePoints[0] = TurretEntry.GetUseablePoint();
    		UseablePointsValid[0] = UP_Valid;
    	}

    	initialRotation = Rotation;
    	targetPitch = Rotation.Pitch;
    	targetYaw = Rotation.Yaw;
    	currentPitch = Rotation.Pitch;
    	currentYaw = Rotation.Yaw;
    }

    simulated function IFiringMotor firingMotor()
    {
    	return motor;
    }

    // Returns the character (if it exists) that is controlling this rook (i.e. turret or vehicle)
    simulated function Character getControllingCharacter()
    {
    	return driver;
    }

    function initTurretAI()
    {
    	local int i;

    	vehicleAI = new class<Tyrion_ResourceBase>( DynamicLoadObject( "Tyrion.AI_VehicleResource", class'Class'));
    	mountAI = new class<Tyrion_ResourceBase>( DynamicLoadObject( "Tyrion.AI_GunnerResource", class'Class'));

    	vehicleAI.setResourceOwner( self );
    	mountAI.setResourceOwner( self );

    	for ( i = 0; i < goals.length; i++ )
    	{
    		if ( goals[i] != None )
    			goals[i].static.findResource( self ).assignGoal( goals[i] );
    	}

    	for ( i = 0; i < abilities.length; i++ )
    	{
    		if ( abilities[i] != None )
    			abilities[i].static.findResource( self ).assignAbility( abilities[i] );
    	}
    }

    // cleanup AI when turret dead
    event bool cleanupAI()
    {
    	if ( super.cleanupAI() )
    		return true;

    	vehicleAI.cleanup();
    	mountAI.cleanup();

    	vehicleAI.deleteSensors();
    	mountAI.deleteSensors();

    	vehicleAI.deleteRemovedActions();
    	mountAI.deleteRemovedActions();

    	return false;
    }

    // Cause all resources attached to this pawn to re-check their goals
    function rematchGoals()
    {
    	vehicleAI.bMatchGoals = true;
    	mountAI.bMatchGoals = true;
    }

    simulated function Destroyed()
    {
    	super.Destroyed();

    	if (weapon != None)
    		weapon.Destroy();

    	if (motor != None)
    		motor.Destroy();
    }

    simulated function Tick(float deltaSeconds)
    {
    	local bool gotOut;

    	Super.Tick(deltaSeconds);

    	// kick dead drivers
    	if (Role == ROLE_Authority)
    	{
    		if (driver != None && !driver.isAlive())
    			DriverLeave(true);
    	}

    	// stop firing if we have no occupant
    	if (driver == None && !bWasDeployed && weapon != None)
    		weapon.releaseFire(true);

    	// check if a driver exited the turret
    	if (bGetOut)
    	{
    		if (Level.NetMode != NM_Client)
    		{
    			gotOut = DriverLeave(true);
    			if (!gotOut )
    			{
    				Log("Couldn't Leave - staying in!");
    			}
    		}

    		bGetOut = false;
    	}

    	// update aim
    	// only update aim here if we are not human-controlled (AIs don't count)
    	// due to turret prediction, we must update human controlled turret aiming from the playercontroller
    	if (PlayerCharacterController(Controller) == None)
    	{
    		updateAim(deltaSeconds);
    	}

    	// AI debug display
    	if ( bShowTyrionCharacterDebug || bShowSensingDebug )
    		displayTyrionDebugHeader();
    	if ( bShowSensingDebug )
    		displayEnemiesList();
    	if ( bShowTyrionCharacterDebug && vehicleAI != None )
    	{
    		vehicleAI.displayTyrionDebug();
    		mountAI.displayTyrionDebug();
    	}
    }

    simulated function ClientDriverEnter(Controller c, Character driver)
    {
    	driver.SetPhysics(PHYS_None);

    	driver.bHardAttach = true;
    	driver.bCollideWorld = false;
    	driver.SetCollision(true, false, false);
    	AttachToBone(driver, seatBone);
    	driver.SetRelativeLocation(Vect(0,0,0));
    	driver.SetRelativeRotation(Rot(0,0,0));

    	if (Controller != None && motor != None)
    		Controller.SetRotation(motor.getViewRotation());
    }

    function DriverEnter(Character p)
    {
    	local Controller c;
    	local PlayerController pc;

    	pc = PlayerController(p.Controller);
    	c = p.Controller;

      	// set pawns current controller to control the vehicle pawn instead
    	driver = p;

    	// ... when moving out of fusion collision state is set back to what it was so must set physics to
    	// ... PHYS_None before updating collision
    	driver.SetPhysics(PHYS_None);

    	oldCollisionHeight = driver.CollisionHeight;
    	oldCollisionRadius = driver.CollisionRadius;
    	driver.SetCollisionSize(seatedCollisionRadius, seatedCollisionHeight);

    	driver.SetCollision(true, false, false);
    	driver.bCollideWorld = false;
    	driver.Velocity = vect(0,0,0);

    	driver.SetLocation(Location);

    	driver.SetPhysics(PHYS_None);

    	// snap turret yaw to player's view
    	if ( pc != None )
    	{
    		currentYaw = driver.Rotation.Yaw % 65536;
    		if (MaxViewYaw != 0)
    			currentYaw = Clamp(currentYaw, initialRotation.Yaw - MaxViewYaw, initialRotation.Yaw + MaxViewYaw);

    		currentPitch = driver.controller.rotation.pitch % 65536;
    		if (currentPitch > 32767)
    			currentPitch -= 65536;
    		if (MaxViewPitch != 0)
    			currentPitch = Clamp(currentPitch, initialRotation.Pitch - MaxViewPitch, initialRotation.Pitch + MaxViewPitch);

    		targetYaw = currentYaw;
    		targetPitch = currentPitch;

    		updateModelRotation();

    		weapon.AISpread = Rot(0.0, 0.0, 0.0);
    	}

    	// set playercontroller to view the vehicle
    	if (pc != None)
    	{
    		bWasBehindView = pc.bBehindView;

    		pc.ClientSetViewTarget(self);
    		pc.bBehindView = false;
    		pc.ClientSetBehindView(false);
    	}

    	// disconnect Controller from Driver and connect to KVehicle
    	c.Unpossess();

    	// keeps the driver relevant
    	c.Possess(self);

    	// set the driver's owner to be us, so that bOwnerNoSee will take effect
    	driver.SetOwner(c);

    	// save the driver's current weapon, and holster it
    	oldDriverWeapon = driver.weapon;
    	driver.motor.setWeapon(None);

    	// seat the driver
    	driver.enterManualAnimationState();
    	driver.bReplicateAnimations = true;
    	driver.LoopAnim(driverAnimation);
    	AttachToBone(driver, seatBone);
    	driver.SetRelativeLocation(Vect(0,0,0));
    	driver.SetRelativeRotation(Rot(0,0,0));

    	dispatchMessage(new class'MessageDriverEnter'(label, p.label));

    	ClientDriverEnter(c, driver);
    }

    // Called from when player wants to get out.
    function bool DriverLeave(bool bForceLeave)
    {
    	local PlayerController pc;
    	local Controller c;
    	local Vector leaveLoc, rotVec;
    	local Rotator r;

    	// do nothing if we're not being driven
    	if (driver == None)
    		return false;

    	pc = PlayerController(Controller);
    	c = Controller;

    	// Before we can exit, we need to find a place to put the driver.
    	// Iterate over array of possible exit locations.

    	driver.SetCollisionSize(oldCollisionRadius, oldCollisionHeight);

    	driver.bHardAttach = false;
    	driver.bCollideWorld = true;
    	driver.SetCollision(true, true, true);
    	driver.SetBase(None);

    	r.Yaw = currentYaw;
    	driver.SetRotation(r);

    	c.Unpossess();
    	// reconnect Controller to driver
    	c.Possess(driver);

    	Controller = None;

    	if (driver.isAlive())
    	{
    		ClientDriverLeave(c, driver, targetPitch, targetYaw);

    		driver.PlayWaiting();

    		driver.exitManualAnimationState();
    		driver.bReplicateAnimations = false;
    		driver.Acceleration = vect(0, 0, 24000);
    		driver.SetPhysics(PHYS_Movement);

    		updateModelRotation();

    		r.Yaw -= 16384;
    		rotVec = Vector(r);
    		leaveLoc = GetBoneCoords(seatBone).Origin;
    		leaveLoc += rotVec * driver.CollisionRadius * 2;

    		driver.SetLocation(leaveLoc);
    		if (driver.movementObject != None)
    		{
    			driver.movementObject.setEndPosition(leaveLoc);
    		}

    		// restore the driver's weapon
    		driver.motor.setWeapon(oldDriverWeapon);
    		oldDriverWeapon = None;
    	}

    	if (pc != None)
    	{
    		// set playercontroller to view the person that got out
    		pc.ClientSetViewTarget(driver);
    		if (!driver.isAlive())
    		{
    			pc.bBehindView = true;
    		}
    		else
    			pc.bBehindView = bWasBehindView;

    		pc.ClientSetBehindView(pc.bBehindView);
    	}

    	dispatchMessage(new class'MessageDriverLeave'(label, driver.label));

    	// turret now has no driver
    	driver = None;

    	return true;
    }

    simulated function ClientDriverLeave(Controller c, Character driver, float finalPitch, float finalYaw)
    {
    	driver.SetPhysics(PHYS_Movement);
    	driver.SetBase(None);
    	targetPitch = finalPitch;
    	targetYaw = finalYaw;
    }

    // returns true if the turret can sight the location given its view constraints
    function bool canTargetPoint(Vector targetLoc)
    {
    	local Vector fireLoc;
    	local Vector toTarget;
    	local Rotator toTargetRotation;

    	if (motor == None)
    		return false;

    	fireLoc = weapon.calcProjectileSpawnLocation(initialRotation);
    	toTarget = Normal(targetLoc - fireLoc);
    	toTargetRotation = Rotator(toTarget);

    	// test pitch
    	if (MaxViewPitch != 0)
    	{
    		if (Abs(toTargetRotation.Pitch - initialRotation.Pitch) > MaxViewPitch)
    		{
    			return false;
    		}
    	}

    	if (MaxViewYaw != 0)
    	{
    		if (Abs(toTargetRotation.Yaw - initialRotation.Yaw) > MaxViewYaw)
    		{
    			return false;
    		}
    	}

    	return true;
    }

    simulated function overrideCurrentRotation(Rotator newRotation)
    {
    	currentPitch = newRotation.Pitch;
    	currentYaw = newRotation.Yaw;
    }

    simulated function updateModelRotation()
    {
    	local Rotator newRot;

    	if (rootBone != '')
    	{
    		newRot = Rot(0,0,0);
    		if (yawAxis == 0)
    			newRot.Pitch = currentYaw - initialRotation.Yaw + yawOffset;
    		else if (yawAxis == 1)
    			newRot.Roll = currentYaw - initialRotation.Yaw + yawOffset;
    		else if (yawAxis == 2)
    			newRot.Yaw = currentYaw - initialRotation.Yaw + yawOffset;

    		if (bFlipYawDisplay)
    		{
    			newRot.Pitch *= -1;
    			newRot.Yaw *= -1;
    			newRot.Roll *= -1;
    		}

    		SetBoneRotation(rootBone, newRot);
    	}

    	if (pitchBone != '')
    	{
    		newRot = Rot(0,0,0);
    		if (pitchAxis == 0)
    			newRot.Pitch = currentPitch;
    		else if (pitchAxis == 1)
    			newRot.Roll = currentPitch;
    		else if (pitchAxis == 2)
    			newRot.Yaw = currentPitch;

    		if (bFlipPitchDisplay)
    		{
    			newRot.Pitch *= -1;
    			newRot.Yaw *= -1;
    			newRot.Roll *= -1;
    		}

    		SetBoneRotation(pitchBone, newRot);
    	}

    	if (TurretEntry != None)
    	{
    		TurretEntry.SetLocation(GetBoneCoords(seatBone).Origin);
    		UseablePoints[0] = TurretEntry.GetUseablePoint();
    	}

    	// manually set character pos on ded server
    	if (Level.NetMode == NM_DedicatedServer && driver != None)
    	{
    		driver.Move(GetBoneCoords(seatbone).Origin - driver.Location);
    	}
    }

    // Returns true if character successfully took control of turret.
    function bool TryToControl(Character p)
    {
    	local Controller C;
    	local Name stateName;

    	if (!bCanBeManned)
    		return false;

    	if (!p.armorClass.default.bCanUseTurrets)
    		return false;

    	stateName = GetStateName();
    	if (stateName != 'Damaged' && stateName != 'Active' && stateName != 'Initialization')
    		return false;

    	C = p.Controller;

    	if ( (driver == None) && (C != None) && (team() == None || team().isFriendly(p.team())) )
    	{
    		DriverEnter(p);
    		return true;
    	}
    	else
    	{
    		return false;
    	}
    }

    simulated function updateAim(float deltaSeconds)
    {
    	local float pitchInc;
    	local float yawInc;
    	local float pitchDiff;
    	local float yawDiff;
    	local Name stateName;

    	stateName = GetStateName();
    	if (stateName != 'Damaged' && stateName != 'Active')
    		return;

    	if (currentPitch != targetPitch || currentYaw != targetYaw)
    	{
    		pitchDiff = targetPitch - currentPitch;
    		yawDiff = targetYaw - currentYaw;

    		if (yawDiff > 0)
    		{
    			yawInc = FMin(yawDiff, getViewRate() * deltaSeconds);
    			if (MaxViewYaw == 0 || currentYaw + yawInc < initialRotation.Yaw + MaxViewYaw)
    				currentYaw += yawInc;
    		}
    		else if (yawDiff < 0)
    		{
    			yawInc = -FMin(-yawDiff, getViewRate() * deltaSeconds);
    			if (MaxViewYaw == 0 || currentYaw + yawInc > initialRotation.Yaw - MaxViewYaw)
    				currentYaw += yawInc;
    		}

    		if (pitchDiff > 0)
    		{
    			pitchInc = FMin(pitchDiff, getViewRate() * deltaSeconds);
    			if (MaxViewPitch == 0 || currentPitch + pitchInc < initialRotation.Pitch + MaxViewPitch)
    				currentPitch += pitchInc;
    		}
    		else if (pitchDiff < 0)
    		{
    			pitchInc = -FMin(-pitchDiff, getViewRate() * deltaSeconds);
    			if (MaxViewPitch == 0 || currentPitch + pitchInc > initialRotation.Pitch - MaxViewPitch)
    				currentPitch += pitchInc;
    		}

    		// update model rotation
    		updateModelRotation();
    	}

    	if (Controller != None && motor != None)
    		Controller.SetRotation(motor.getViewRotation());
    }

    simulated state Unpowered
    {
    	simulated function BeginState()
    	{
    		DriverLeave(true);

    		Super.BeginState();
    	}
    }

    simulated state Destructed
    {
    	simulated function BeginState()
    	{
    		DriverLeave(true);

    		Super.BeginState();
    	}
    }

    simulated state Disabled
    {
    	simulated function BeginState()
    	{
    		DriverLeave(true);

    		Super.BeginState();
    	}
    }

    simulated function onTeamChange()
    {
    	DriverLeave(true);
    }

    simulated function float getViewRate()
    {
    	if (driver == None || PlayerCharacterController(controller) == None)
    		return AIViewRate;
    	else
    		return ViewRate;
    }

    defaultproperties
    {
    	Mesh						= SkeletalMesh'BaseObjects.Turret'
    	bHardAttach					= false
    	bHidden						= false
    	bBlockActors				= true
    	bBlockHavok					= true
    	bBlockKarma					= false
    	bCollideActors				= true
    	bUseCylinderCollision		= false
    	bStatic						= false
    	CollisionRadius				= +0080.000000
    	CollisionHeight				= +0080.000000
    	bCollideWhenPlacing			= false
    	bOwnerNoSee					= true
    	bReplicateMovement			= false
    	bUpdateSimulatedPosition	= false
    	bNetNotify					= true
    	RemoteRole					= ROLE_SimulatedProxy
    	Physics						= PHYS_None

    	playerControllerState		= "PlayerTurreting"

    	entry						= (radius=50,height=50)
    	bGetOut						= false
    	weaponClass					= class'Spinfusor'
    	driverAnimation				= "pod_stand"

    	rootBone					= "base"
    	seatBone					= "character"
    	pitchBone					= "top"
    	pitchAxis					= 1
    	yawOffset					= 0
    	yawAxis						= 2

    	ViewRate					= 180
    	AIViewRate					= 180
    	MaxViewPitch				= 45
    	MaxViewYaw					= 0

    	seatedCollisionHeight		= 50
    	seatedCollisionRadius		= 36

    	AI_LOD_Level				= AILOD_MINIMAL

    	peripheralVision            = 0.1f				// nearly 180 degrees
    	peripheralVisionZAngle		= 1.2217f			// 70 degrees up/down
    	SightRadius					= 8000.0
    	VisionUpdateRange			= (Min=0.4,Max=0.6)

    	bWorldGeometry				= false

    	bCanBeManned				= true
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:24.000 - Creation time: st 23.5.2018 00:10:49.551 - Created with UnCodeX