Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# TribesGUI.TribesHUDScript

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281

    //================================================================
    // Class: TribesHUDScript
    //
    // A safe, client side script to allow users to write their own HUD
    // scripts without exposing core game objects which would facilitate cheating
    //
    //================================================================

    class TribesHUDScript extends TribesHUDScriptBase
    	native
    	abstract;

    var Array<HUDElement>	keyEventReceptors;
    var Array<HUDElement>	mouseEventReceptors;
    var int LastMouseX;
    var int LastMouseY;

    var bool				bIsChatEnabled;
    var bool				bIsQuickChatEnabled;
    var HUDChatEntry		chatEntry;
    var HUDQuickChatMenu	quickChatMenu;
    var HUDMessageWindow	messageWindow;
    var HUDContainer		messageContainer;

    var HUDContainer		quickChatMenuContainer;
    var QuickChatMenu		rootQuickChatMenuObject;
    var String				rootQuickChatMenuObjectName;
    var bool				bOldQuickChat;

    var HUDAnnouncerMessageWindow	AnnouncementsWindow;
    var bool						bIsAnnouncmentsEnabled;

    var HUDEventMessageWindow	EventMessageWindow;
    var bool					bEventMessagesEnabled;

    var bool bShowScoreboard;
    var HUDContainer scoreboardGroup;
    var LabelElement teamOneScoreLabel;
    var LabelElement teamOneLabel;
    var HUDCountDown countDown;
    var LabelElement teamTwoLabel;
    var LabelElement teamTwoScoreLabel;

    overloaded function Construct()
    {
    	super.Construct();

    	ConstructBaseComponents();
    }

    function PreShow(ClientSideCharacter csc)
    {
    	LocalData = csc;
    	InitElementHeirachy(self, None); // Has no parent
    	ForceNeedsLayout();
    }

    function ConstructBaseComponents()
    {
    	if(bEventMessagesEnabled)
    		EventMessageWindow = HUDEventMessageWindow(AddElement("TribesGui.HUDEventMessageWindow", "default_EventMessageWindow"));

    	if(bIsChatEnabled)
    	{
    		messageContainer = HUDContainer(AddElement("TribesGUI.HUDContainer", "default_MessageContainer"));
    		messageWindow = HUDMessageWindow(messageContainer.AddElement("TribesGUI.HUDMessageWindow", "default_MessageWindow"));
    		chatEntry = HUDChatEntry(messageContainer.AddElement("TribesGUI.HUDChatEntry", "default_ChatEntry"));
    		RegisterKeyEventReceptor(chatEntry);
    	}

    	if(bIsQuickChatEnabled)
    	{
    		quickChatMenuContainer = HUDContainer(AddElement("TribesGUI.HUDContainer", "default_QuickChatMenuContainer"));
    		quickChatMenu = HUDQuickChatMenu(quickChatMenuContainer.AddElement("TribesGUI.HUDQuickChatMenu", "default_QuickChatMenu"));
    		RegisterKeyEventReceptor(quickChatMenu);

    		// load up the root menu (only once!)
    		rootQuickChatMenuObject = QuickChatMenu(FindObject("RootQuickChatMenu", class'Gameplay.QuickChatMenu'));
    		if(rootQuickChatMenuObject == None)
    		{
    			rootQuickChatMenuObject = new (None, "RootQuickChatMenu") class'TribesGUI.QuickChatMenu';
    			rootQuickChatMenuObject.InitMenu();
    			quickChatMenu.InitMenu(rootQuickChatMenuObject, None, quickChatMenuContainer);
    		}
    	}

    	if(bIsAnnouncmentsEnabled)
    		AnnouncementsWindow = HUDAnnouncerMessageWindow(AddElement("TribesGui.HUDAnnouncerMessageWindow", "default_AnnouncementsWindow"));

    	if(bShowScoreboard)
    	{
    		scoreboardGroup	= HUDContainer(AddElement("TribesGUI.HUDContainer", "default_scoreboardGroup"));
    		teamOneScoreLabel = LabelElement(scoreboardGroup.AddElement("TribesGUI.LabelElement", "default_teamOneScore"));
    		teamOneLabel = LabelElement(scoreboardGroup.AddElement("TribesGUI.LabelElement", "default_teamOneLabel"));
    		countDown = HUDCountDown(scoreboardGroup.AddElement("TribesGUI.HUDCountDown", "default_countDown"));
    		teamTwoLabel = LabelElement(scoreboardGroup.AddElement("TribesGUI.LabelElement", "default_teamTwoLabel"));
    		teamTwoScoreLabel = LabelElement(scoreboardGroup.AddElement("TribesGUI.LabelElement", "default_teamTwoScore"));
    	}
    }

    function UpdateData(ClientSideCharacter c)
    {
    	super.UpdateData(c);

    	if(messageWindow != None)
    		messageWindow.ForcedMaxVisibleLines = -1;

    	if(bIsQuickChatEnabled)
    	{
    		// always cancel the menu if we are not enabled
    		if(! c.bQuickChat)
    			quickChatMenu.CancelAll();
    		else if(bOldQuickChat != c.bQuickChat)
    			quickChatMenu.OpenMenu();

    		bOldQuickChat = c.bQuickChat;
    	}

    	if(bShowScoreboard)
    		UpdateScoreboard();
    }

    // Updates the scoreboard at the top of the screen
    function UpdateScoreboard()
    {
    	local int scoreLimit;
    	local String scoreTextOwn, scoreTextOther;
    	local class<ModeInfo> modeClass;

    	modeClass = class<ModeInfo>(LocalData.gameClass);

    	// Don't do this in single player
    	if (modeClass == None)
    		return;

    	scoreLimit = modeClass.default.scoreLimit;

    	// Only display team information if a second team is present
    	if (LocalData.otherTeam != "" && modeClass.default.numTeams > 1)
    	{
    		TeamOneLabel.SetText(LocalData.ownTeam);
    		TeamTwoLabel.SetText(LocalData.otherTeam);
    		scoreTextOwn = string(LocalData.ownTeamScore);
    		scoreTextOther = string(LocalData.otherTeamScore);
    		if(scoreLimit > 0)
    		{
    			scoreTextOwn $= "/" $ string(scoreLimit);
    			scoreTextOther $= "/" $ string(scoreLimit);
    		}

    		teamOneScoreLabel.SetText(scoreTextOwn);
    		teamTwoScoreLabel.SetText(scoreTextOther);
    	}
    }

    function DoUpdate(Canvas canvas, float NewTimeSeconds)
    {
    	local bool bWasOverElement, bOverElement;
    	local int i;

    	if(screenWidth != canvas.SizeX || screenHeight != canvas.SizeY)
    		ForceNeedsLayout();

    	// check for mouse movement
    	if(LastMouseX != LocalData.MouseX || LastMouseY != LocalData.MouseY)
    	{
    		for(i = 0; i < mouseEventReceptors.Length; ++i)
    		{
    			bWasOverElement = mouseEventReceptors[i].PointInElement(LastMouseX, LastMouseY);
    			bOverElement = mouseEventReceptors[i].PointInElement(LocalData.MouseX, LocalData.MouseY);

    			if(bWasOverElement && ! bOverElement)
    				mouseEventReceptors[i].OnMouseExited(mouseEventReceptors[i]);
    			else if(! bWasOverElement && bOverElement)
    				mouseEventReceptors[i].OnMouseEntered(mouseEventReceptors[i]);
    		}
    	}

    	// do the data update + rendering
    	TimeSeconds = NewTimeSeconds;
    	UpdateData(LocalData);
    //	if(bNeedsLayout)
    		DoLayout(canvas);
    	Render(canvas);

    	// update previous values
    	LastMouseX = LocalData.MouseX;
    	LastMouseY = LocalData.MouseY;
    }

    function RegisterMouseEventReceptor(HUDElement element)
    {
    	mouseEventReceptors[mouseEventReceptors.Length] = element;
    }

    function UnRegisterMouseEventReceptor(HUDElement element)
    {
    	local int i;

    	for(i = 0; i < mouseEventReceptors.Length; ++i)
    	{
    		if(mouseEventReceptors[i] == element)
    		{
    			mouseEventReceptors.Remove(i, 1);
    			--i;
    		}
    	}
    }

    function RegisterKeyEventReceptor(HUDElement element)
    {
    	keyEventReceptors[keyEventReceptors.Length] = element;
    }

    function UnRegisterKeyEventReceptor(HUDElement element)
    {
    	local int i;

    	for(i = 0; i < keyEventReceptors.Length; ++i)
    	{
    		if(keyEventReceptors[i] == element)
    		{
    			keyEventReceptors.Remove(i, 1);
    			--i;
    		}
    	}
    }

    //Key events
    function bool KeyType( EInputKey Key, string Unicode, HUDAction Response )
    {
    	local int i;

    	for(i = 0; i < keyEventReceptors.Length; ++i)
    	{
    		if(keyEventReceptors[i].KeyType(Key, Unicode, Response))
    			return true;
    	}

    	return false;
    }

    function bool KeyEvent( EInputKey Key, EInputAction Action, FLOAT Delta, HUDAction Response )
    {
    	local int i;

    	if(Key == EInputKey.IK_LeftMouse && (Action == EInputAction.IST_Press || Action == EInputAction.IST_Repeat))
    	{
    		for(i = 0; i < mouseEventReceptors.Length; ++i)
    		{
    			if(mouseEventReceptors[i].PointInElement(LastMouseX, LastMouseY))
    			{
    				if(Action == EInputAction.IST_Press)
    					mouseEventReceptors[i].OnMouseClicked(mouseEventReceptors[i]);
    				else if(Action == EInputAction.IST_Repeat)
    					mouseEventReceptors[i].OnMouseDoubleClicked(mouseEventReceptors[i]);
    			}
    		}
    	}
    	else
    	{
    		for(i = 0; i < keyEventReceptors.Length; ++i)
    		{
    			if(keyEventReceptors[i].KeyEvent(Key, Action, Delta, Response))
    				return true;
    		}
    	}

    	return false;
    }

    defaultproperties
    {
    	bIsChatEnabled = true
    	bIsQuickChatEnabled = true
    	bEventMessagesEnabled = true
    	bIsAnnouncmentsEnabled = true

    	bRelativePositioning = true
    	bShowScoreboard = true
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: st 16.4.2014 10:20:46.000 - Creation time: st 23.5.2018 00:10:48.340 - Created with UnCodeX