Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Tyrion.AI_Resource

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431
00432
00433
00434
00435
00436
00437
00438
00439
00440
00441
00442
00443
00444
00445
00446
00447
00448
00449
00450
00451
00452
00453
00454
00455
00456
00457
00458
00459
00460
00461
00462
00463
00464
00465
00466
00467
00468
00469
00470
00471
00472
00473
00474
00475
00476
00477
00478
00479
00480
00481
00482
00483
00484
00485
00486
00487
00488
00489
00490
00491
00492
00493
00494
00495
00496
00497
00498
00499
00500
00501
00502
00503
00504
00505
00506
00507
00508
00509
00510
00511
00512
00513
00514
00515
00516
00517
00518
00519
00520
00521
00522
00523
00524
00525
00526
00527
00528
00529
00530
00531
00532
00533
00534
00535
00536
00537
00538
00539
00540
00541
00542
00543
00544
00545
00546
00547
00548
00549
00550
00551
00552
00553
00554
00555
00556
00557
00558
00559
00560
00561
00562
00563
00564
00565
00566
00567
00568
00569
00570
00571
00572
00573
00574
00575
00576
00577
00578
00579
00580
00581
00582
00583
00584
00585
00586
00587
00588
00589
00590
00591
00592
00593
00594
00595
00596
00597
00598
00599
00600
00601
00602
00603
00604
00605
00606
00607
00608
00609
00610
00611
00612
00613
00614
00615
00616
00617
00618
00619
00620
00621
00622
00623
00624
00625
00626
00627
00628
00629
00630
00631
00632
00633
00634
00635
00636
00637
00638
00639
00640
00641
00642
00643
00644
00645
00646
00647
00648
00649
00650
00651
00652
00653
00654
00655
00656
00657
00658
00659
00660
00661
00662
00663
00664
00665
00666
00667
00668
00669
00670
00671
00672
00673
00674
00675
00676
00677
00678
00679
00680
00681

    //=====================================================================
    // AI_Resource
    // The Tyrion (Tribes 3 AI System) AI Control Mechanism
    //=====================================================================

    // A note on resource usage:
    //
    // Resources are hierarchical. Squads are made up of pawns which are made up of arms, legs,
    // and a head. Arms, legs, and head resources are called "leaf resources". Leaf resources
    // are the resources that actually do things in the world, characters and squads are just
    // collections of these resources.
    //
    // Only actions running on leaf resources actually "use" the resources. Character and squad
    // actions use resources only by virtue of the fact that they spawn child actions that run
    // on the character's or squad's leaf resources. Consequently, it's easy for character and
    // squad actions to share a resource. They can run in parallel and won't conflict unless two
    // of them start a child action on the same leaf resource at the same time.
    //
    // Every action has "resourceUsage" bits that indicate what resources it requires. Squad
    // actions must have uniform usage of resources across their members (i.e. you can't have
    // a single squad action that needs the arms of Pawn A and the legs of Pawn B).
    //
    // For an action to run on a resource, the resources it requires must be available. Resource
    // checking occurs in two places: When an action is chosen for a pending goal (inside
    // "processGoals()") and when a new goal is added to a resource (in "resourceCheck()").
    // ProcessGoals() won't chose any action (including character and squad actions) unless
    // the resources specified by that action are currently available. ResourceCheck() will
    // interrupt an action running on a resources if this resource is a leaf resource and
    // the new goal has a higher priority.

    class AI_Resource extends Engine.Tyrion_ResourceBase
    	native
    	editinlinenew
    	abstract;

    import class Engine.Canvas;
    import class Engine.HUD;

    //=====================================================================
    // Constants

    // Optional resources
    const OPTIONAL_RESOURCE_PRIORITY = 20;	// maximum priority for an optional resource

    // Resource usage bits - specify the leaf nodes of the resource hierarchy
    // character parts
    const RU_HEAD		= 1;
    const RU_ARMS		= 2;
    const RU_LEGS		= 4;

    // vehicle parts
    const RU_MOUNT		= 8;

    // base installation parts
    // ...

    //=====================================================================
    // Variables

    var array<AI_RunnableAction> idleActions;
    var array<AI_RunnableAction> runningActions;
    var array<AI_RunnableAction> removedActions;	// actions waiting to be deleted
    var AI_Action usedByAction;					// the action that is "using" this resource; only leaf resources (legs/arms/head etc) can be used
    var array<AI_Sensor> sensors;				// the sensors available to this resource
    var array<AI_SensorAction> sensorActions;	// the sensorActions running on this resource

    //=====================================================================
    // Functions

    //---------------------------------------------------------------------
    // Called before the resource is first ticked
    // (called explicitly by Actors that use AI_Resource's,
    // since objects don't have their own postBeginPlay()'s)
    // (called on first UAI_Resource.Tick)

    event init()
    {
    	local int i;
    	local AI_Goal goal;
    	local array<AI_Goal> removeGoals;

    	// designer-created goals have to be initialized...
    	for ( i = 0; i < goals.length; i++ )
    	{
    		goal = AI_Goal(goals[i]);

    		if ( goal.priorityFn() <= 0 )
    			removeGoals[removeGoals.length] = goal;		// removeGoals.push(goal)
    		else if ( goal.resource == None )	// goal not yet initialized
    			goal.init( self );
    	}

    	for ( i = 0; i < removeGoals.length; i++ )
    	{
    		if ( pawn().logTyrion )
    			log( "Removing" @ removeGoals[i].name @ "from" @ pawn().name @ "(priority <= 0)" );
    		removeGoal( removeGoals[i] );		// remove goals with 0 priority so they don't clog up resources
    	}

    	bUnInitialized = false;
    }

    //---------------------------------------------------------------------
    // clean up resource-related stuff when pawn dies

    function cleanup()
    {
    	local int i;
    	local AI_Goal goal;
    	local ActionBase action;

    	//if ( pawn() != None )
    	//	log( "Cleanup called on" @ name @ pawn().name );
    	//else
    	//	log( "Cleanup called on" @ name @ "(pawn unknown - ragdoll cleanup?)" );

    	for ( i = 0; i < goals.length; i++ )
    	{
    		goal = AI_Goal(goals[i]);
    		//log( "... considering" @ goal.name );

    		// de-link goals from sensor's recipient lists (in lieu of removing them alltogether)
    		if ( goal.activationSentinel != None && goal.activationSentinel.sensor != None )
    		{
    			goal.activationSentinel.deactivateSentinel( goal );
    			goal.activationSentinel.sensor = None;
    		}
    		if ( goal.deactivationSentinel != None && goal.deactivationSentinel.sensor != None )
    		{
    			goal.deactivationSentinel.deactivateSentinel( goal );
    			goal.deactivationSentinel.sensor = None;
    		}
    	}

    	//log( " idleActions:" @ idleActions.length );
    	while ( idleActions.length > 0 )
    	{
    		//log( "... considering idle" @ idleActions[0].name );
    		action = idleActions[0];
    		idleActions.remove(0, 1);			// remove element explicitly (so sensorActions get removed)
    		action.instantFail( ACT_RESOURCE_INACTIVE );
    	}

    	//log( " runningActions:" @ runningActions.length );
    	while ( runningActions.length > 0 )
    	{
    		//log( "... considering running" @ runningActions[0].name );
    		action = runningActions[0];
    		runningActions.remove(0, 1);		// remove element explicitly (so sensorActions get removed)
    		action.instantFail( ACT_RESOURCE_INACTIVE );
    	}

    	for ( i = 0; i < sensors.length; i++ )
    	{
    		//log( "... considering sensor" @ sensors[i].name @ sensors[i].recipients.length );
    		/*if ( sensors[i].recipients.length > 0 )
    		{
    			log( "    The following still have references to this sensor:" );
    			for ( j = 0; j < sensors[i].recipients.length; j++ )
    				log( "     " @ sensors[i].recipients[j].recipient.name );
    		}*/
    		sensors[i].cleanup();
    	}

    	// InstantFail doesn't remove sensor actions (even though they are in the "runningActions" list),
    	// so remove them here explicitly
    	//log( " sensorActions:" @ sensorActions.length );
    	for ( i = 0; i < sensorActions.length; i++ )
    	{
    		//log( "... considering sensorAction" @ sensorActions[i].name );
    		sensorActions[i].removeAction();
    	}
    	sensorActions.length = 0;

    	// remove remaining goals
    	while( goals.length > 0 )
    	{
    		//log( "... considering goal" @ goals[0].name );
    		removeGoal( AI_Goal(goals[0]) );
    	}

    	//log( "Cleanup FINISHED on" @ name @ pawn().name );
    }

    //---------------------------------------------------------------------
    // Delete all the sensors attached to this resource

    function deleteSensors()
    {
    	local int i;

    	for ( i = 0; i < sensors.length; i++ )
    	{
    		sensors[i].value.Delete();		// this would be in the sensor's destructor if we had one...
    		sensors[i].Delete();
    	}
    	sensors.length = 0;
    }

    //---------------------------------------------------------------------
    // Delete actions that have been removed from idle and running lists

    event deleteRemovedActions()
    {
    	local int i;

    	for ( i = 0; i < removedActions.length; i++ )
    	{
    		//log( "deleteRemovedActions: deleting" @ removedActions[i].name );
    		removedActions[i].Release();	// Comment out this line to disable AI action deletion
    	}
    	removedActions.length = 0;
    }

    //---------------------------------------------------------------------
    // increments refCount and returns object

    function AI_Resource myAddRef()
    {
    	AddRef();
    	return self;
    }

    //---------------------------------------------------------------------
    // Inform a resource that a particular pawn died
    // (Resources should not assume they will only get one of these messages per pawn death)

    function pawnDied( Pawn pawn )
    {
    	local int i;
    	local array<ActionBase> actions;

    	// collect actions (don't want to be iterating over lists that might change length)
    	for ( i = 0; i < runningActions.length; ++i )
    		actions[actions.length] = runningActions[i];

    	for ( i = 0; i < idleActions.length; ++i )
    		actions[actions.length] = idleActions[i];

    	// inform all actions
    	for ( i = 0; i < actions.length; ++i )
    	{
    		if ( !actions[i].bDeleted )
    			actions[i].pawnDied( pawn );
    	}
    }

    //----------------------------------------------------------------------
    // Chooses the best action from 'abilities' that satisfies 'goal'
    // Returns a copy of this action (or None) with a reference count of 1
    //
    // Note: to save on action copying, for now goal constraints are not taken into account when
    //       determining value of selectionHeuristic

    event AI_Action chooseAction( AI_Goal goal )
    {
    	local AI_Action bestAction;				// return value
    	local AI_Action action;
    	local array<AI_Action> matchingActions;	// sorted list of actions that match 'goal'
    	local int i, j;

    	// create a sorted list of actions that achieve 'goal'
    	for ( i = 0; i < abilities.length; i++ )
    	{
    		action = AI_Action(abilities[i]);

    		//log( "@@@" @ pawn().name @ action.name @ action.satisfiesGoal.name @ goal.class @ action.selectionHeuristic( goal ) );
    		//if ( ClassIsChildOf( goal.class, action.satisfiesGoal ) )
    		//	log( "@@@" @ action.name @ "sat's" @ goal.name @ usedByAction @ usedByAction.achievingGoal.priorityFn() @ goal.priorityFn() );

    		if ( ClassIsChildOf( goal.class, action.satisfiesGoal ) &&
    			( usedByAction == None ||											// resource not in use
    			  usedByAction.achievingGoal.priorityFn() < goal.priorityFn() ||	// resource doing something less important
    			  multipleActionsCheck( action ) ||									// the resource can handle multiple actions
    			  doesParentHaveResource( goal.parentAction )))						// the parent of the goal is already using the resource
    		{
    			action.heuristicValue = action.selectionHeuristic( goal );

    			if ( action.heuristicValue > 0 )
    			{
    				// insert 'action' into 'matchingActions', sorted by heuristicValue
    				for( j = 0; j < matchingActions.Length; ++j )
    				{
    					if ( matchingActions[j].heuristicValue < action.heuristicValue )
    						break;
    				}
    				matchingActions.insert(j, 1);
    				matchingActions[j] = action;
    			}
    		}
    	}

    	// find the action with the highest heuristicValue
    	for ( i = 0; i < matchingActions.length; i++ )
    	{
    		action = AI_Action( class'Engine.Tyrion_Setup'.static.shallowCopy( matchingActions[i] )).myAddRef();	// make a shallow copy
    		// log( "ChooseAction: Created new action" @ action.name @ "from" @ matchingActions[i] );

    		if ( setActionParameters( goal, action ) )	// returns false if parameters named in this goal couldn't be set
    		{
    			bestAction = action;
    			break;
    		}
    		else
    			action.Release();
    	}

    	return bestAction;
    }

    //----------------------------------------------------------------------
    // Makes sure a high priority goal isn't being prevented from running
    // because its resource is being used by a lower priority one;
    // if it is, interrupt the lower priority one
    // 'bestAction': if known, the action you want running on this goal

    event resourceCheck( AI_Goal goal, optional AI_Action bestAction )
    {
    	// Interrupt lower priority actions that are preventing this goal from being satisfied:
    	// 1. find out what actions match this goal
    	// 2. if the best one needs to use this resource but a lower priority action is claiming
    	//    the resource, interrupt the lower priority action

    	//log( "RESOURCE_CHECK: goal:" @ goal.name @ "action:" @ bestAction.name @ "usedBy:" @ usedByAction );

    	if ( usedByAction != None &&		// will only be non-None on leaf resources (there is no resource contention for non-leaf resources)
    		 goal.bInactive == false &&		// inactive goals don't need to be considered
    		 goal.priorityFn() > usedByAction.achievingGoal.priorityFn() &&	// new goal's priority is higher
    		 !doesParentHaveResource( goal.parentAction ) )					// parent isn't already using the resource
    	{
    		// possible optimization: store bestAction for use by processGoals() - if processGoals() is called on this tick
    		if ( bestAction == None )
    			bestAction = chooseAction( goal );	// if a new bestAction is created here it will get deleted at the end of this function...
    		else
    			bestAction.AddRef();				// ...but if it was passed in it its reference counts will remain unchanged

    		// the best action needs the resource (resource must be a leaf resource)
    		// old: if ( (bestAction.resourceUsage & bestAction.default.resourceUsage) != 0 )
    		if ( !multipleActionsCheck( bestAction ) )
    		{
    			if ( pawn().logTyrion )
    				log( "resourceCheck: Interrupting" @ usedByAction.name @
    					"(pri" @ usedByAction.achievingGoal.priorityFn() $
    					") to achieve" @ goal.name @ "(pri" @ goal.priorityFn() $ ")" );
    			if ( usedByAction == goal.parentAction )
    				log( "AI WARNING: Child action" @ bestAction.name @ "is interrupting its parent" @ goal.parentAction.name );

    			// invoke parent's "resources stolen" callback
    			if ( usedByAction.achievingGoal.parentAction != None )
    				usedByAction.achievingGoal.parentAction.resourceStolenCB( usedByAction.achievingGoal, self );

    			// free up resource
    			if ( usedByAction != None )
    				usedByAction.interruptAction();
    		}

    		if ( bestAction != None )
    			bestAction.Release();
    	}
    }

    //---------------------------------------------------------------------
    // Adds a sensor action to a resource

    function AI_SensorAction addSensorActionClass( class<AI_SensorAction> sensorActionClass )
    {
    	local AI_SensorAction sensorAction;

    	assert(sensorActionClass != None);
    	if ( !ClassIsChildOf( class, sensorActionClass.static.getResourceClass() ) )
    	{
    		log( "AI WARNING: addSensorActionClass:" @ class @ "is not a child of" @ sensorActionClass.static.getResourceClass() );
    		assert( ClassIsChildOf( class, sensorActionClass.static.getResourceClass() ) );
    	}

    	//log( name @ "added sensor action class:" @ sensorActionClass );

    	// allocate a new sensor action, but have it be idle

    	sensorAction = (new sensorActionClass( self )).myAddRef();
    	//log( "---" @ sensorAction @ "addreffed" );
    	sensorAction.setupSensors( self );
    	sensorAction.pauseAction();

    	sensorActions[sensorActions.length] = sensorAction;

    	return sensorAction;
    }

    //---------------------------------------------------------------------
    // Can this resource run "action" if it's already being used?
    // (default is "yes", but individual resources can define their own logic)
    // Note: check will never be called for non-leaf resources, since they can
    // always run multiple actions

    function bool multipleActionsCheck( AI_Action action )
    {
    	return true;
    }

    //----------------------------------------------------------------------
    // Is the parent of this action already using a leaf resource?

    function bool doesParentHaveResource( AI_Action parentAction )
    {
    	return false;
    }

    //----------------------------------------------------------------------
    // Return the corresponding action class for this type of resource

    function class<AI_RunnableAction> getActionClass();

    //----------------------------------------------------------------------
    // Wrapper function for setActionParametersInternal

    function bool setActionParameters( AI_Goal goal, AI_Action action )
    {
    	return setActionParametersInternal( goal, action );
    }

    //---------------------------------------------------------------------
    // Accessor functions

    event Pawn Pawn()
    {
    	return None;
    }

    #if IG_TRIBES3
    // returns the rook representing the vehicle mounted turret or the vehicle (for drivers) or the turret
    function Rook localRook()
    {
    	return Rook(pawn());	// returns the same value as pawn() by default
    }
    #endif

    //---------------------------------------------------------------------
    // Given the name of a goal, retrieve the object (or None)

    function AI_Goal findGoalByName( String gName )
    {
    	local AI_Goal goal;
    	local int i;

    	for ( i = 0; i < goals.length; i++ )
    	{
    		goal = AI_Goal(goals[i]);
    		if ( gName ~= goal.goalName )
    			return goal;
    	}

    	return None;
    }

    //----------------------------------------------------------------------
    // Set parameters in 'action' to those specified by 'goal', if possible
    //
    // Notes on goal constraints:
    // - goal constraints are parameters of the action that matches the goal
    // - goal constraints steer the the action, giving the poster of the goal some control
    //   on the execution of the action
    // - when goal constraints are set, the action uses their values, instead of filling them in itself

    private native function bool setActionParametersInternal( Object goal, Object action );

    //----------------------------------------------------------------------
    // Adds a goal to the AI_Resource
    // low-level function - don't call this directly!
    // 'parentAction' can be None for top-level goals
    // Does an implicit "AddRef" on the goal that was added

    function addGoal( AI_Action parent, AI_Goal goal )
    {
    	goal.AddRef();
    	goals[goals.length] = goal;	// goals.push(goal)
    	goal.parentAction = parent;

    	if ( parent != None )
    	{
    		// childGoals.Push( self )
    		parent.childGoals[parent.childGoals.length] = goal;
    	}

    	if ( goal.bInactive == false )
    		bMatchGoals = true;
    }

    //-----------------------------------------------------------------------
    // Removes a goal from this AI_Resource
    // low-level function - don't call this directly!
    // clears achievingAction
    // Does an implicit "Release" on the goal that was removed (which means goal may be invalid after this call!!)
    // It's ok to call removeGoal on a goal that's already been removed.

    function removeGoal( AI_Goal goal )
    {
    	local int i;

    	goal.cleanup();

    	if ( goal.parentAction != None )
    	{
    		for ( i = 0; i < goal.parentAction.childGoals.length; i++ )
    			if ( goal.parentAction.childGoals[i] == goal )
    			{
    				//log( "-> removing" @ goal.name @ "from child list of" @ goal.parentAction.name );
    				goal.parentAction.childGoals.remove( i, 1 );	// removes element - shifts the rest
    				break;
    			}
    	}

    	if ( goal.activationSentinel != None && goal.activationSentinel.sensor != None )
    	{
    		goal.activationSentinel.deactivateSentinel( goal );
    		goal.activationSentinel.sensor = None;
    	}
    	if ( goal.deactivationSentinel != None && goal.deactivationSentinel.sensor != None )
    	{
    		goal.deactivationSentinel.deactivateSentinel( goal );
    		goal.deactivationSentinel.sensor = None;
    	}

    	// Check to see if bMatchGoals needs to be set after a goal is removed.
    	// If a goal is being achieved by an action that isn't using the resource,
    	// then removing that goal doesn't free up any resources. Consequently,
    	// no new goal matching has to be performed.
    	// (Note: goal's achievingAction slot must still be valid)

    	if ( usedByAction != None && goal.achievingAction == usedByAction )
    		bMatchGoals = true;

    	// A more general note:
    	// There are four cases when you might have to perform action-to-goal matching:
    	// 1. A goal was added (handled in addGoal)
    	// 2. A goal was removed (handled in removeGoal)
    	// 3. An action completed - because although the goals may not have changed,
    	//    resources may have been freed up (handled in handleGoalFailure/handleGoalSuccess)
    	//    When an action completes, all the sub-goals it posted have to be removed as well;
    	//    this is why removeAction calls removeGoal recursively
    	// 4. An action was interrupted - again, resources may have been freed up
    	//    (handled in interruptAction which calls handleGoalFailure)
    	// 5. A permanent inactive goal changes state
    	//    (handled in activate/deactivate/handleGoalFailure/handleGoalSuccess)
    	// The possibility still exists that bMatchGoals will be set to true unnecessarily,
    	// but no cases were it should have been set and wasn't will occur.

    	if ( goal.achievingAction != None )
    	{
    		//log( "-> removing" @ goal.achievingAction.name );
    		goal.achievingAction.removeAction();	// clears achievingAction
    	}

    	for ( i = 0; i < goals.length; i++ )
    		if ( goals[i] == goal )
    		{
    			goals.remove( i, 1 );				// removes element - shifts the rest
    			goal.bDeleted = true;
    			goal.parentAction = None;
    			//log( "->" @ goal.name @ "in" @ pawn().name @ "RELEASED" );
    			if (goal.Release() > 0)
    			{
    				//assert(!goal.Outer.IsA('Actor'));
    				goal.NullReferences();
    			}
    			break;
    		}
    }

    //---------------------------------------------------------------------
    // Mark all goals as achieved: this will reset the resource to have
    // only permanent goals (used when a mount loses its driver)

    event resetGoals()
    {
    	local int i, n;
    	local AI_Goal goal;

    	n = goals.length;
    	for ( i = 0; i < n; ++i )
    	{
    		goal = AI_Goal(goals[i]);
    		if ( goal.achievingAction != None )
    		{
    			//log( "-->" @ localRook().name @ "Calling succeed on" @ goal.name );
    			goal.achievingAction.instantSucceed();

    			// handle goals array length being modified
    			if ( goals.length != n )
    			{
    				n = goals.length;
    				--i;
    			}
    		}
    	}

    	bGoalsReset = true;
    }

    //---------------------------------------------------------------------
    // action/goal debug display function

    #if IG_TRIBES3			// Tribes version...
    function displayTyrionDebug()
    {
        local int i;
    	local Pawn debugPawn;
    	local AI_Goal goal;
    	local Color color;
    	local String inactiveString;

    	debugPawn = pawn();

    	if ( class'Pawn'.static.checkAlive( debugPawn ) && goals.length > 0 )
    	{
    		debugPawn.AddDebugMessage(" ");
    		debugPawn.AddDebugMessage( Name @ "Goals", class'Canvas'.static.MakeColor(255,255,255));

    		for ( i = 0; i < goals.length; i++ )
    		{
    			goal = AI_Goal(goals[i]);

    			if ( goal.bInactive )
    			{
    				color = class'Canvas'.static.MakeColor(0,255,200);
    				inactiveString = "INACTIVE";
    			}
    			else
    			{
    				color = class'Canvas'.static.MakeColor(0,255,0);
    				inactiveString = "";
    			}

    			debugPawn.AddDebugMessage( "  " $ goal.goalDebuggingString() @ "(" $ goal.priorityFn() $ ")" @ inactiveString, color );
    			if ( goal.achievingAction != None )
    				debugPawn.AddDebugMessage( "   " $ goal.achievingAction.actionDebuggingString(), class'Canvas'.static.MakeColor(200,200,200) );
    		}
    	}
    }
    #endif

    #if IG_SWAT				// SWAT version...
    function displayTyrionDebug()
    {
        local int i;
    	local Pawn debugPawn;

    	debugPawn = pawn();
        debugPawn.AddDebugMessage(" ");

    	if ( goals.length > 0 )
    	{
    		debugPawn.AddDebugMessage( Name $ " Goals", class'Canvas'.Static.MakeColor(255,255,255));
    		for ( i = 0; i < goals.length; i++ )
    			if ( !AI_Goal(goals[i]).bInActive )
    				debugPawn.AddDebugMessage("  " $ goals[i].goalDebuggingString());
    	}

    	if ( runningActions.length > 0 )
    	{
    		debugPawn.AddDebugMessage("Running " $ Name $ " Actions", class'Canvas'.Static.MakeColor(255,255,255));
    		for ( i = 0; i < runningActions.length; i++ )
    			debugPawn.AddDebugMessage("  " $ runningActions[i].actionDebuggingString());
    	}

    	if ( idleActions.length > 0 )
    	{
    		debugPawn.AddDebugMessage("Idle " $ Name $ " Actions", class'Canvas'.Static.MakeColor(255,255,255));
    		for ( i = 0; i < idleActions.length; i++ )
    			debugPawn.AddDebugMessage("  " $ idleActions[i].actionDebuggingString());
    	}
    }
    #endif

    //=======================================================================

    defaultproperties
    {
    	bMatchGoals = true
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: èt 7.10.2004 10:30:38.000 - Creation time: st 23.5.2018 00:10:41.608 - Created with UnCodeX