Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Gameplay.JointControlledAircraft

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431
00432
00433
00434
00435
00436
00437
00438
00439
00440
00441
00442
00443
00444
00445
00446
00447
00448
00449
00450
00451
00452
00453
00454
00455
00456
00457
00458
00459
00460
00461
00462
00463
00464
00465
00466
00467
00468
00469
00470
00471
00472
00473
00474
00475
00476
00477
00478
00479
00480
00481
00482
00483
00484
00485
00486
00487
00488
00489
00490
00491
00492
00493
00494
00495
00496
00497
00498
00499
00500
00501
00502
00503
00504
00505
00506
00507
00508
00509
00510
00511
00512
00513
00514
00515
00516
00517
00518
00519
00520
00521
00522
00523
00524
00525
00526
00527
00528
00529
00530
00531
00532
00533
00534
00535
00536
00537
00538
00539
00540
00541
00542
00543
00544
00545
00546
00547
00548
00549
00550
00551
00552
00553
00554
00555
00556
00557
00558
00559
00560
00561
00562
00563
00564
00565
00566
00567
00568
00569
00570
00571
00572
00573
00574
00575
00576
00577
00578
00579
00580
00581
00582
00583
00584
00585
00586
00587
00588
00589
00590
00591
00592
00593
00594
00595
00596
00597
00598
00599
00600
00601
00602
00603
00604
00605
00606
00607
00608
00609
00610
00611
00612
00613
00614
00615
00616
00617
00618
00619
00620
00621
00622
00623
00624
00625
00626
00627
00628
00629
00630
00631
00632
00633
00634
00635
00636
00637
00638
00639
00640
00641
00642
00643
00644
00645
00646
00647
00648
00649
00650
00651
00652
00653
00654
00655
00656
00657
00658
00659
00660
00661
00662
00663
00664
00665
00666
00667
00668
00669
00670
00671
00672
00673
00674
00675
00676
00677
00678
00679
00680
00681
00682
00683

    // JointControlledAircraft

    class JointControlledAircraft extends Vehicle
    	abstract
    	dependsOn(PlayerCharacterController)
    	native;

    cpptext
    {
    	virtual void HavokPreStepCallback(FLOAT deltaTime);

    	virtual bool HavokInitActor();
    	virtual void HavokQuitActor();

    	virtual void PostEditChange();

    	void PostNetReceive();

    	bool isHavokInitialised();

    	// movement animation override
    	void UpdateMovementAnimation(FLOAT DeltaSeconds);

    	virtual void TickAuthoritative(float deltaSeconds);

    	class HkSimpleFlightAction* m_flightAction;

    	class hkGenericConstraint* m_hardPitchConstraint;
    }

    const JCA_LINEAR_VELOCITY_ACCURACY_FACTOR = 100;
    const JCA_LINEAR_VELOCITY_INVERSE_ACCURACY_FACTOR = 0.01;

    var (Animation) name idleAnimation;
    var (Animation) name leftAnimation;
    var (Animation) name rightAnimation;
    var (Animation) name forwardAnimation;
    var (Animation) name backAnimation;
    var (Animation) name upAnimation;
    var (Animation) name downAnimation;
    var (Animation) name spawningAnimation;
    var (Animation) name gearUpAnimation;
    var (Animation) float spawningBlendTime;
    var (Animation) float blendTime;
    var (Animation) float gearTraceLength;
    var (Animation) float gearUpBlendTime;

    // control forces
    var (JointControlledAircraft) float strafeThrustForce;
    var (JointControlledAircraft) float strafeForce;
    var (JointControlledAircraft) float forwardThrustForce;
    var (JointControlledAircraft) float forwardForce;
    var (JointControlledAircraft) float upThrustForce;
    var (JointControlledAircraft) float reverseForce;
    var (JointControlledAircraft) float reverseThrustForce;
    var (JointControlledAircraft) float strafeCombinedReduction;
    var (JointControlledAircraft) float forwardCombinedReduction;
    var (JointControlledAircraft) float diveThrustForce;
    var (JointControlledAircraft) float diveCombinedReduction;
    var (JointControlledAircraft) float thrustCombinedReduction;
    var (JointControlledAircraft) float downDiveForceScale;
    var (JointControlledAircraft) float aheadDiveForceScale;
    var (JointControlledAircraft) float forceScale;

    var (JointControlledAircraft) float clientControlJointStrength;
    var (JointControlledAircraft) float controlJointStrength;
    var (JointControlledAircraft) float clientDriverControlJointStrength;

    var (JointControlledAircraft) float flightControlDamping;

    var (JointControlledAircraft) float diveCounterGravityForceScale;
    var (JointControlledAircraft) float coastingCounterGravityForceScale;

    var (JointControlledAircraft) float coastingDamping;

    var (JointControlledAircraft) float angularBankScale;
    var (JointControlledAircraft) float linearBankScale;

    var int turningRightEffectIndex;
    var int turningLeftEffectIndex;
    var int divingEffectIndex;

    var (JointControlledAircraft) float flightRotationEffectMagnitude;

    var rotator viewRotationAI;

    enum AccelerationEffectStateEnum
    {
    	AES_ACCELERATING,
    	AES_DECELERATING,
    	AES_NONE
    };

    // effect states
    var bool ThrustingEffectState;
    var AccelerationEffectStateEnum AccelerationEffectState;

    // unlike thrusting diving is not always applied directly corresponding to input so this flag is used
    var bool divingForceApplied;

    // force applied to aircraft due to controls
    var vector outputControlForce;
    var float outputFlightYawAngle;
    var float outputFlightPitchAngle;

    var (JointControlledAircraft) float counterGravityForceScale;

    // animation states
    var bool strafeLeft;
    var bool strafeRight;
    var bool strafeForward;
    var bool strafeBack;
    var bool strafeUp;
    var bool strafeDown;
    var bool LandingGearUp;

    var rotator currentCameraRotation;

    struct native AircraftState
    {
    	var vector position;
    	var vector velocity;

    	// packed pitch and yaw
    	var int flightAngles;

    	var bool serverThrusting;
    	var bool serverDiving;
    	var PlayerCharacterController.EDigitalAxisInput serverStrafe;
    	var PlayerCharacterController.EDigitalAxisInput serverThrottle;
    };
    var vector replicatedControlForce;

    var AircraftState replicationAircraftState;
    var AircraftState oldReplicationAircraftState;

    var (JointControlledAircraft) bool constrainAircraftPitch;
    var (JointControlledAircraft) float minimumAircraftPitch;
    var (JointControlledAircraft) float maximumAircraftPitch;

    // unlike the above this is a physically hard constraint
    var (JointControlledAircraft) bool hardConstrainAircraftPitch;
    var (JointControlledAircraft) float hardAircraftPitchRange;

    // indicates the currect z axis rotation being applied by the low level flight physics
    var const float zAxisFlightRotation;

    ////////// NAVIGATION //////////

    var float navigationMaximumPitch;
    var float navigationMinimumPitch;
    var float navigationTurnRate;
    var float rotateMinimumPitch;
    var float rotateMaximumPitch;
    var float thrustThresholdPitch;
    var float throttleScale;

    // padding
    var transient noexport private const int padding[2];

    native function vector calculateOutputControlForce(rotator referenceRotation, float currentThrottleInput, float currentStrafeInput,
    		float currentThrustInput, bool currentDiveInput);

    native function setFlightForce(vector force);
    native function setFlightRotation(int yawAngle, int pitchAngle);

    native function setFlightControlStrength(float strength);

    native function setCounterGravityForceScale(float scale);

    replication
    {
    	reliable if (Role == ROLE_Authority)
    		replicationAircraftState;
    }

    simulated function postNetBeginPlay()
    {
    	super.postNetBeginPlay();

    	VehicleUpdateParams();
    }

    simulated function rotator getViewRotation()
    {
    	if (controller != None && !controller.bIsPlayer)
    		return viewRotationAI;

    	return rotationInput;
    }

    function setViewRotation(rotator r)
    {
    	viewRotationAI = r;
    }

    simulated event updateCameraRotation(float deltaSeconds)
    {
    	local float maxRotationDelta;
    	local rotator requiredRotationDelta;
    	local rotator actualrotationDelta;
    	local rotator rotationNormal;
    	local rotator currentCameraRotationNormal;

    	rotationNormal = rotation;
    	if (rotationNormal.Pitch > 16384)
    		rotationNormal.Yaw += 32768;
    	rotationNormal = Normalize(rotationNormal);
    	if (rotationNormal.Yaw < 0)
    		rotationNormal.Yaw += 65536;
    	if (rotationNormal.Pitch < 0)
    		rotationNormal.Pitch += 65536;

    	currentCameraRotationNormal = Normalize(currentCameraRotation);
    	if (currentCameraRotationNormal.Yaw < 0)
    		currentCameraRotationNormal.Yaw += 65536;
    	if (currentCameraRotationNormal.Pitch < 0)
    		currentCameraRotationNormal.Pitch += 65536;

    	maxRotationDelta = deltaSeconds * 70000;

    	requiredRotationDelta = rotationNormal - currentCameraRotationNormal;

    	if (requiredRotationDelta.Pitch > 32768)
    		requiredRotationDelta.Pitch -= 65536;
    	else if (requiredRotationDelta.Pitch < -32768)
    		requiredRotationDelta.Pitch += 65536;

    	if (requiredRotationDelta.Yaw > 32768)
    		requiredRotationDelta.Yaw -= 65536;
    	else if (requiredRotationDelta.Yaw < -32768)
    		requiredRotationDelta.Yaw += 65536;

    	if (requiredRotationDelta.Yaw < 0)
    		actualrotationDelta.Yaw = max(-maxRotationDelta, requiredRotationDelta.Yaw);
    	else
    		actualrotationDelta.Yaw = min(maxRotationDelta, requiredRotationDelta.Yaw);

    	if (requiredRotationDelta.Pitch < 0)
    		actualrotationDelta.Pitch = max(-maxRotationDelta, requiredRotationDelta.Pitch);
    	else
    		actualrotationDelta.Pitch = min(maxRotationDelta, requiredRotationDelta.Pitch);

    	currentCameraRotation.Pitch += actualrotationDelta.Pitch;
    	currentCameraRotation.Yaw += actualrotationDelta.Yaw;
    }

    function processInput()
    {
    	local rotator normalRotationInput;

    	// do nothing if no driver
    	if (positions[driverIndex].occupant == None)
    	{
    		outputControlForce = vect(0, 0, 0);
    		normalRotationInput = Normalize(Rotation);
    		outputFlightYawAngle = normalRotationInput.Yaw;
    		outputFlightPitchAngle = normalRotationInput.Pitch;

    		return;
    	}

    	outputControlForce = calculateOutputControlForce(rotationInput, ThrottleInput, StrafeInput, ThrustInput, DiveInput);

    	normalRotationInput = Normalize(rotationInput);

    	outputFlightYawAngle = normalRotationInput.Yaw;
    	outputFlightPitchAngle = normalRotationInput.Pitch;
    }

    function bool needToPushStateToClient()
    {
    	return true;
    }

    function pushStateToClient()
    {
    	local HavokRigidBodyState currentState;
    	local rotator workFlightRotation;

    	HavokGetState(currentState);

    	replicationAircraftState.velocity = currentState.LinVel * JCA_LINEAR_VELOCITY_ACCURACY_FACTOR;
    	replicationAircraftState.position = HavokGetCenterOfMass();

    	// pack flight angles
    	workFlightRotation.Pitch = outputFlightPitchAngle;
    	workFlightRotation.Yaw = outputFlightYawAngle;
    	replicationAircraftState.flightAngles = packPitchAndYaw(workFlightRotation);

    	// effects
    	replicationAircraftState.serverThrusting = (ThrustInput > 0);
    	replicationAircraftState.serverDiving = divingForceApplied;
    	replicationAircraftState.serverStrafe = class'PlayerCharacterController'.static.analogueToDigital(StrafeInput, 1);
    	replicationAircraftState.serverThrottle = class'PlayerCharacterController'.static.analogueToDigital(ThrottleInput, 1);

    	forceNetDirty();
    }

    simulated function applyOutput()
    {
    	local float constrainedPitch;

    	setFlightForce(outputControlForce * forceScale);

    	// apply pitch constraint
    	constrainedPitch = outputFlightPitchAngle;
    	if (constrainAircraftPitch)
    		constrainedPitch = clamp(constrainedPitch, minimumAircraftPitch, maximumAircraftPitch);

    	setFlightRotation(outputFlightYawAngle, constrainedPitch);

    	// set counter gravity force scale dependent on dive and driver state
    	if (DiveInput && positions[driverIndex].occupant == None)
    		warn("diving with no driver");
    	if (DiveInput)
    		setCounterGravityForceScale(diveCounterGravityForceScale);
    	else if (positions[driverIndex].occupant == None)
    		setCounterGravityForceScale(coastingCounterGravityForceScale);
    	else
    		setCounterGravityForceScale(counterGravityForceScale);
    }

    simulated function vector getControlJointAttachLocation()
    {
    	return location;
    }

    simulated event VehicleStateReceived()
    {
    	local rotator referenceRotation;
    	local float receivedThrustInput;
    	local rotator flightRotation;

    	// should never occur on server but just in case
    	if (Role == ROLE_Authority)
    		return;

    	super.vehicleStateReceived();

    	// retrieve packed flight angles
    	flightRotation = unpackPitchAndYaw(replicationAircraftState.flightAngles);
    	outputFlightPitchAngle = flightRotation.pitch;
    	outputFlightYawAngle = flightRotation.yaw;

    	// update desired state
    	currentDesiredHavokState.position = replicationAircraftState.position;
    	currentDesiredHavokState.velocity = replicationAircraftState.velocity * JCA_LINEAR_VELOCITY_INVERSE_ACCURACY_FACTOR;
    	currentDesiredHavokState.newState = true;

    	// calculate output control force
    	referenceRotation.Pitch = outputFlightPitchAngle;
    	referenceRotation.Yaw = outputFlightYawAngle;
    	if (replicationAircraftState.serverThrusting)
    		receivedThrustInput = 0;
    	replicatedControlForce = calculateOutputControlForce(referenceRotation,
    			class'PlayerCharacterController'.static.digitalToAnalogue(replicationAircraftState.serverThrottle, 1),
    			class'PlayerCharacterController'.static.digitalToAnalogue(replicationAircraftState.serverStrafe, 1),
    			receivedThrustInput, replicationAircraftState.serverDiving);
    }

    simulated function updateEffectsStates()
    {
    	local AccelerationEffectStateEnum tickAccelerationState;
    	local vector normalVelocity;
    	local vector normalForce;
    	local float dotForceVelocity;

    	super.updateEffectsStates();

    	// thrusting
    	if (!ThrustingEffectState && (
    			((Role == ROLE_Authority) && (ThrustInput > 0)) ||
    			((Role < ROLE_Authority) && (replicationAircraftState.serverThrusting))
    			))
    	{
    		ThrustingEffectState = true;
    		TriggerEffectEvent('ThrustBegun');
    	}
    	else if (ThrustingEffectState && (
    			((Role == ROLE_Authority) && (ThrustInput == 0)) ||
    			((Role < ROLE_Authority) && (!replicationAircraftState.serverThrusting))
    			))
    	{
    		ThrustingEffectState = false;
    		TriggerEffectEvent('ThrustEnded');
    	}

    	// acceleration

    	// ... determine acceleration state this tick
    	if (outputControlForce != vect(0,0,0))
    	{
    		if (Velocity == vect(0,0,0))
    		{
    			tickAccelerationState = AES_ACCELERATING;
    		}
    		else
    		{
    			normalVelocity = normal(velocity);
    			normalForce = normal(outputControlForce);
    			dotForceVelocity = normalVelocity dot normalForce;
    			if (dotForceVelocity > 0)
    			{
    				tickAccelerationState = AES_ACCELERATING;
    			}
    			else
    			{
    				tickAccelerationState = AES_DECELERATING;
    			}
    		}
    	}
    	else
    	{
    		tickAccelerationState = AES_NONE;
    	}

    	// ... update acceleration state based on tick accelration state
    	if (tickAccelerationState != accelerationEffectState)
    	{
    		switch (accelerationEffectState)
    		{
    		case AES_ACCELERATING:
    			UnTriggerEffectEvent('EngineAccelerating');
    			break;
    		case AES_DECELERATING:
    			UnTriggerEffectEvent('EngineDecelerating');
    			break;
    		}

    		accelerationEffectState = tickAccelerationState;

    		switch (accelerationEffectState)
    		{
    		case AES_ACCELERATING:
    			TriggerEffectEvent('EngineAccelerating');
    			break;
    		case AES_DECELERATING:
    			TriggerEffectEvent('EngineDecelerating');
    			break;
    		}
    	}

    	// set animation effect flgas
    	if (Role < ROLE_Authority)
    	{
    		strafeUp =  replicationAircraftState.serverThrusting;
    		strafeDown = replicationAircraftState.serverDiving;
    		strafeForward = replicationAircraftState.serverThrottle == DAI_Positive;
    		strafeBack = replicationAircraftState.serverThrottle == DAI_Negative;
    		strafeLeft = replicationAircraftState.serverStrafe == DAI_Positive;
    		strafeRight = replicationAircraftState.serverStrafe == DAI_Negative;
    	}
    	else
    	{
    		strafeUp = thrustInput>0;
    		strafeDown = diveInput;
    		strafeForward = ThrottleInput>0;
    		strafeBack = ThrottleInput<0;
    		strafeLeft = StrafeInput>0;
    		strafeRight = StrafeInput<0;
    	}
    }

    simulated function initialiseEffects()
    {
    	super.initialiseEffects();

    	addEffect('turningForceRight', false, turningRightEffectIndex);
    	addEffect('turningForceLeft', false, turningLeftEffectIndex);
    	addEffect('Diving', false, divingEffectIndex);
    }

    simulated function bool isEffectCauserActive(int effectCauserIndex)
    {
    	// clients use replicated information for basic effects
    	if (Role < ROLE_Authority)
    	{
    		switch (effectCauserIndex)
    		{
    		case throttleForwardEffectIndex:
    			return replicationAircraftState.serverThrottle == DAI_Positive;
    		case throttleBackEffectIndex:
    			return replicationAircraftState.serverThrottle == DAI_Negative;
    		case strafeLeftEffectIndex:
    			return replicationAircraftState.serverStrafe == DAI_Positive;
    		case strafeRightEffectIndex:
    			return replicationAircraftState.serverStrafe == DAI_Negative;
    		case thrustingEffectIndex:
    			return replicationAircraftState.serverThrusting;
    		case throttleForwardOrThrustEffectIndex:
    			return replicationAircraftState.serverThrottle == DAI_Positive || replicationAircraftState.serverThrusting;
    		case strafeLeftOrThrustEffectIndex:
    			return replicationAircraftState.serverStrafe == DAI_Positive || replicationAircraftState.serverThrusting;
    		case strafeRightOrThrustEffectIndex:
    			return replicationAircraftState.serverStrafe == DAI_Negative || replicationAircraftState.serverThrusting;
    		case divingEffectIndex:
    			return replicationAircraftState.serverDiving;
    		}
    	}

    	switch (effectCauserIndex)
    	{
    	case turningRightEffectIndex:
    		return zAxisFlightRotation > flightRotationEffectMagnitude;
    	case turningLeftEffectIndex:
    		return zAxisFlightRotation < -flightRotationEffectMagnitude;
    	case divingEffectIndex:
    		return divingForceApplied;
    	}

    	return super.isEffectCauserActive(effectCauserIndex);
    }

    simulated function clientOccupantEnter(ClientOccupantEnterData data)
    {
    	super.clientOccupantEnter(data);

    	// reset control joint strength
    	if (Level.NetMode == NM_Client)
    	{
    		setFlightControlStrength(clientDriverControlJointStrength);
    	}
    }

    simulated function clientDriverLeave(Controller c, Character oldDriver)
    {
    	Super.clientDriverLeave(c, oldDriver);

    	// reset control joint strength
    	if (Level.NetMode == NM_Client)
    	{
    		setFlightControlStrength(clientControlJointStrength);
    	}

    	// turn off all effects
    	if (ThrustingEffectState)
    	{
    		UnTriggerEffectEvent('Thrusting');
    		ThrustingEffectState = false;
    	}
    	switch (accelerationEffectState)
    	{
    	case AES_ACCELERATING:
    		UnTriggerEffectEvent('EngineAccelerating');
    		break;
    	case AES_DECELERATING:
    		UnTriggerEffectEvent('EngineDecelerating');
    		break;
    	}
    	accelerationEffectState = AES_NONE;
    }

    simulated function Destroyed()
    {
    	UnTriggerEffectEvent('EngineAccelerating');
    	UnTriggerEffectEvent('EngineDecelerating');
    	UnTriggerEffectEvent('Thrusting');
    	UnTriggerEffectEvent('Diving');

    	super.Destroyed();
    }

    simulated function bool specialCalcViewProcessing(out actor viewActor, out vector cameraLocation,
    		out rotator cameraRotation, int positionIndex)
    {
    //	cameraRotation = currentCameraRotation;

    	return super.specialCalcViewProcessing(viewActor, cameraLocation, cameraRotation, positionIndex);
    }

    simulated function tick(float deltaSeconds)
    {
    	local vector traceStart;
    	local vector traceEnd;
    	local vector dummy;

    	// apply replicated output force
    	if (Level.NetMode == NM_Client)
    	{
    		outputControlForce = replicatedControlForce;
    	}

    	super.tick(deltaSeconds);

    	// update landing gear state
    	if (gearUpAnimation != 'None')
    	{
    		traceStart = location;
    		traceEnd = traceStart + vect(0, 0, -1) * gearTraceLength;
    		LandingGearUp = Trace(dummy, dummy, traceEnd, traceStart) == None;
    	}

    	// coasting damping
    	if (positions[driverIndex].occupant == None)
    	{
    		dampingPlusEnabled = true;
    		dampingPlusXY = coastingDamping;
    		dampingPlusPositiveZ = coastingDamping;
    		dampingPlusNegativeZ = 0;
    	}
    	else
    	{
    		dampingPlusEnabled = false;
    	}

    	// not diving if no driver
    	if (clientPositions[driverIndex].occupant == None)
    		divingForceApplied = false;
    }

    defaultproperties
    {
    	AirSpeed = 5000

    	Health=800

    	strafeThrustForce = 50
    	strafeForce = 25
    	forwardThrustForce = 50
    	forwardForce = 25
    	upThrustForce = 50
    	reverseForce = 15
    	reverseThrustForce = 25
    	strafeCombinedReduction = 0.5
    	forwardCombinedReduction = 0.5
    	diveThrustForce = 50
    	diveCombinedReduction = 0.5
    	thrustCombinedReduction = 0.5

    	thrustingEffectState = false
    	accelerationEffectState = AES_NONE

    	divingForceApplied = false

    	downDiveForceScale=1.2
    	aheadDiveForceScale=0.2

    	navigationMaximumPitch = 7000
    	navigationMinimumPitch = -8000
    	navigationTurnRate = 4000
    	rotateMinimumPitch = -10000
    	rotateMaximumPitch = 10000
    	thrustThresholdPitch = 500

    	Physics = PHYS_Havok

    	forceScale = 250

    	clientControlJointStrength = 1
    	clientDriverControlJointStrength = 1.5
    	controlJointStrength = 2.5

    	counterGravityForceScale = 0.5
    	coastingCounterGravityForceScale = 0.2
    	diveCounterGravityForceScale = 0

    	flightControlDamping = 0.25

    	blendTime = 0.2

    	bPhysicsAnimUpdate = true

    	spawningBlendTime = 0.6

    	gearUpBlendTime = 1.2

    	angularBankScale = 0.35
    	linearBankScale = 0.4

    	gearTraceLength = 600

    	flightRotationEffectMagnitude = 650

    	coastingDamping = 0.4

    	throttleScale = 0.0005

    	hardConstrainAircraftPitch = true
    	hardAircraftPitchRange = 22500

    	currentDesiredHavokState=(ignoreRotation=true)
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:28.000 - Creation time: st 23.5.2018 00:10:44.816 - Created with UnCodeX