Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Gameplay.MPCheckpoint

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376

    class MPCheckpoint extends MPArea;

    var() editcombotype(enumCheckpoints)
    	  Name			nextCheckpointLabel	"The next checkpoint";
    var() bool			bStartingPoint		"Is this checkpoint the start of a lap?";
    var() bool			bFinishingPoint		"Is this checkpoint the end of a lap?";
    var() int			numLapsToFinish		"If bFinishingLine is true, specify the number of laps here";
    var() int			teamPointsPerLap	"Number of points awarded to your team for each lap passed";
    var() Name			passAnimation		"The name of the animation to play when this checkpoint gets passed";
    var() bool			bDontResetAfterPass	"If true, the checkpoint won't reset itself after you pass it, so its effects will stay active";
    var() bool			bUsePersonalObjectives "If true, the player will automatically receive a personal objective for each checkpoint";

    // Effect events
    var(EffectEvents) Name	passedEffectEvent	"The name of an effect event that plays once on the checkpoint when passed";
    var(EffectEvents) Name	failedEffectEvent	"The name of an effect event that plays once on the checkpoint when failed";

    var bool bPassedEffect;
    var bool bLocalPassedEffect;

    var Array<PlayerCharacterController>		awaitingClientsList;
    var float					startingTime;
    var MPCheckpoint			nextCheckpoint;

    // Stats
    var(Stats)	class<Stat>		checkpointPassedStat;
    var(Stats)	class<Stat>		lapFinishedStat;
    var(Stats)	class<Stat>		raceFinishedStat;

    // Objectives
    var(Objectives) localized string	selfCheckpointObjectiveDesc		"A description that will show up as a personal objective for your next checkpoint.";

    var(LocalMessage) class<Engine.LocalMessage>	CheckpointMessageClass "The class used for displaying messages and playing effects related to carryables.";

    struct ClientCheckpointData
    {
    	var PlayerCharacterController client;
    	var int lap;
    	var float lastTimePassed;
    };

    var Array<ClientCheckpointData>		passedClientsList;

    replication
    {
    	reliable if (Role == ROLE_Authority)
    		bPassedEffect;
    }

    // PostBeginPlay
    function PostBeginPlay()
    {
    	Super.PostBeginPlay();

    	if (bStartingPoint)
    	{
    		startingTime = Level.TimeSeconds;
    		// Register interest in connect messages, but only if this is a starting point
    		registerMessage(class'MessageClientConnected', "All");
    	}

    	nextCheckpoint = MPCheckpoint(findByLabel(class'MPCheckpoint', nextCheckpointLabel));

    	// Register interest in disconnect and team change messages
    	// This is needed in order to tidy up client lists
    	registerMessage(class'MessageClientDisconnected', "All");
    	registerMessage(class'MessageClientChangedTeam', "All");
    }

    simulated function PostNetReceive()
    {
    	Super.PostNetReceive();

    	updateCheckpointEffects();
    }

    simulated function updateCheckpointEffects()
    {
    	if (bPassedEffect != bLocalPassedEffect)
    	{
    		bLocalPassedEffect = bPassedEffect;
    		if (bPassedEffect)
    		{
    			TriggerEffectEvent(passedEffectEvent);
    			PlayAnim(passAnimation);

    			if (!bDontResetAfterPass)
    				SetTimer(1, false);
    		}
    		else
    		{
    			// The passedEffectEvent wasn't intended to be looping but the artists have used it that way
    			// so UnTrigger it here
    			UnTriggerEffectEvent(passedEffectEvent);
    			PlayAnim('Deactive');
    		}
    	}
    }

    simulated event Timer()
    {
    	// Temporary:  restore checkpoint to its lowered location
    	bPassedEffect = false;
    	updateCheckpointEffects();
    }

    function onMessage(Message msg)
    {
    	if (MessageClientChangedTeam(msg) != None)
    	{
    		// Do cleanup here
    		//Log("Checkpoint:  Team change detected for "$MessageClientChangedTeam(msg).client);
    	}
    	else if (MessageClientConnected(msg) != None)
    	{
    		// If this message was received, we know this is a starting point, so
    		// automatically advance to the next checkpoint
    		advanceCheckpoint(MessageClientConnected(msg).client);
    	}
    	else if (MessageClientDisconnected(msg) != None)
    	{
    		// Ensure this client is removed from all client lists
    		removeAwaitingClient(MessageClientDisconnected(msg).client);
    	}
    }

    function OnAreaEntered(Character c)
    {
    	// Use Owner instead of Controller to handle case where player is in a vehicle
    	//Log(self$" entered by "$c$" with owner "$c.owner);
    	if (isAwaitingClient(PlayerCharacterController(c.Owner)))
    		passCheckpoint(PlayerCharacterController(c.Owner), c.team());
    	else if (team() == None || c.team() == team())
    	{
    		failCheckpoint(c);
    	}
    }

    function OnAreaExited(Character c)
    {
    	// Do nothing
    }

    // Old approach was to touch the checkpoint
    /*function Touch(Actor Other)
    {
    	local Character c;

    	c = Character(Other);
    	if (c == None)
    		return;

    	if (isAwaitingClient(PlayerCharacterController(c.Controller)))
    		passCheckpoint(PlayerCharacterController(c.Controller), c.team());
    	else
    	{
    		//c.ClientMessage("This isn't your current checkpoint");
    		dispatchMessage(new class'MessageCheckpointFailed'(label, c.label, getTeamLabel() ));
    	}
    }*/

    function failCheckpoint(Character c)
    {
    	//c.ClientMessage("This isn't your current checkpoint");
    	dispatchMessage(new class'MessageCheckpointFailed'(label, c.label, getTeamLabel() ));
    	Level.Game.BroadcastLocalized(self, CheckpointMessageClass, 0, c.tribesReplicationInfo, self);
    }

    function passCheckpoint(PlayerCharacterController c, TeamInfo t)
    {
    	local int p;

    	bPassedEffect = true;
    	updateCheckpointEffects();

    	//c.ClientMessage("Checkpoint passed!  Proceed to next checkpoint");
    	dispatchMessage(new class'MessageCheckpointPassed'(label, c.label, getTeamLabel() ));
    	Level.Game.BroadcastLocalized(self, CheckpointMessageClass, 1, c.playerReplicationInfo, self);
    	//Log("CHECKPOINT:  Checkpoint passed by "$c);

    	// Could display lap time difference here

    	p = getClientCheckpointDataIndex(c);
    	// If the player hasn't already passed here, create a new entry
    	if (p < 0)
    		p = addPassedClient(c);

    	// Advance the lap counter
    	passedClientsList[p].lap = passedClientsList[p].lap + 1;

    	// Set a timestamp
    	passedClientsList[p].lastTimePassed = Level.TimeSeconds;

    	// Advance the passed player's next checkpoint
    	advanceCheckpoint(c);

    	if (bFinishingPoint)
    	{
    		// Award a point for finishing the lap
    		scoreTeam(teamPointsPerLap, t);

    		// Check to see if this is the last lap
    		if (passedClientsList[p].lap >= numLapsToFinish)
    		{
    			lastLapPassed(passedClientsList[p]);
    		}
    		// If it's not the last lap, inform the player
    		else
    		{
    			//Log("CHECKPOINT:  Lap completed, rank = "$getClientRank(passedClientsList[p])$", plap = "$passedClientsList[p].lap$", finish = "$numLapsToFinish);
    			//c.ClientMessage("Lap completed!  "$ (numLapsToFinish - passedClientsList[p].lap) $" laps to go");
    			//c.ClientMessage("Your rank:  "$getClientRank(passedClientsList[p]));
    		}
    	}
    }

    function advanceCheckpoint(PlayerCharacterController c)
    {
    	// This checkpoint is no longer awaiting this player
    	removeAwaitingClient(c);

    	// The next checkpoint is now awaiting this player
    	if (nextCheckpoint != None)
    	{
    		nextCheckpoint.addAwaitingClient(c);
    		// Add waypoint here
    		if (bUsePersonalObjectives)
    			setPersonalObjective(c, selfCheckpointObjectiveDesc, nextCheckpoint);
    	}
    }

    function bool isAwaitingClient(PlayerCharacterController c)
    {
    	local int i;

    	for (i=0; i<awaitingClientsList.Length; i++)
    	{
    		if (awaitingClientsList[i] == c)
    			return true;
    	}

    	return false;
    }

    function removeAwaitingClient(PlayerCharacterController c)
    {
    	local int i;

    	for (i=0; i<awaitingClientsList.Length; i++)
    	{
    		if (awaitingClientsList[i] == c)
    			awaitingClientsList.Remove(i, 1);
    	}
    }

    function addAwaitingClient(PlayerCharacterController c)
    {
    	//Log("CHECKPOINT:  Checkpoint "$self$" is now awaiting client "$c);
    	awaitingClientsList[awaitingClientsList.Length] = c;
    }

    function int getClientCheckpointDataIndex(PlayerCharacterController c)
    {
    	local int i;

    	for (i=0; i<passedClientsList.Length; i++)
    	{
    		//Log("CHECKPOINT:  "$passedClientsList[i].client$" == "$c$"?");
    		if (passedClientsList[i].client == c)
    			return i;
    	}

    	return -1;
    }

    function int addPassedClient(PlayerCharacterController c)
    {
    	passedClientsList.Length = passedClientsList.Length + 1;
    	passedClientsList[passedClientsList.Length - 1].client = c;

    	//Log("CHECKPOINT:  Added passed client "$c);

    	return passedClientsList.Length - 1;
    }

    function lastLapPassed(ClientCheckpointData p)
    {
    	//p.client.ClientMessage("You finished the race!  Final rank:  "$getClientRank(p));
    	//Log("CHECKPOINT: FINISHED, rank = "$getClientRank(p));
    	if (bUsePersonalObjectives)
    		removePersonalObjective(p.client);

    	// Remove the client from the next checkpoint
    	nextCheckpoint.removeAwaitingClient(p.client);
    }

    function int getClientRank(ClientCheckpointData p)
    {
    	local int i;
    	local int rank;
    	local ClientCheckpointData compareClient;

    	rank = 1;

    	for (i=0; i<passedClientsList.Length; i++)
    	{
    		compareClient = passedClientsList[i];

    		if (compareClient == p)
    			continue;

    		if (compareClient.lap > p.lap)
    			rank++;
    		else if (compareClient.lap == p.lap)
    			if (compareClient.lastTimePassed < p.lastTimePassed)
    				rank++;
    	}

    	return rank;
    }

    function reset()
    {
    	awaitingClientsList.Length = 0;

    	if (bDontResetAfterPass)
    	{
    		bPassedEffect = false;
    		updateCheckpointEffects();
    	}

    	// Recurse along the list until the end of the race
    	if (nextCheckpoint != None && !bFinishingPoint)
    	{
    		nextCheckpoint.reset();
    	}
    }

    function restartPlayer(PlayerCharacterController pcc)
    {
    	advanceCheckpoint(pcc);
    }

    // enumCheckpoints
    function enumCheckpoints(Engine.LevelInfo l, out Array<Name> a)
    {
    	local MPCheckpoint c;

    	ForEach DynamicActors(class'MPCheckpoint', c)
    	{
    		// Valid next checkpoints need to be the same team, neutral team, or any team if this checkpoint
    		// is a neutral checkpoint.  Neutral checkpoints can be shared between teams.
    		if (c.isA(Class.Name) && c != self && (c.team() == team() || team() == None || c.team() == None ))
    			a[a.Length] = c.Label;
    	}
    }

    defaultProperties
    {
    	DrawType				= DT_Mesh
    	Mesh					= Mesh'MPGameObjects.MPCheckpoint'
    	bCollideActors			= true
    	bCollideWorld			= true
    	bMovable				= false
    	//bBlockPlayers			= false
    	bNetNotify				= true
    	NetUpdateFrequency		= 2

    	selfCheckpointObjectiveDesc	= "Proceed to the next Checkpoint."
    	CheckpointMessageClass	= class'MPCheckpointMessages'
    	passedEffectEvent		= Passed
    	failedEffectEvent		= Failed
    	passAnimation			= Activate
    	teamPointsPerLap		= 1
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:18.000 - Creation time: st 23.5.2018 00:10:45.874 - Created with UnCodeX