Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Gameplay.ObjectSpawnPoint

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346

    class ObjectSpawnPoint extends BaseDevice;

    var() class<Actor>	objectType				"The type of object spawned at this spawn point";
    var() float			respawnDelay			"How long before a new object is made available after the old object is destroyed";
    var() Vector		spawnOffset				"Offset from the origin that the object appears at, possibly temporary, will have to be tuned depending on the type of object being spawned";
    var() bool			bCanSpawnMultiples		"If false, the spawn point must wait until the previous object taken from it is used up or destroyed before it can spawn a new object. Otherwise, a new object is spawned once the existing object is taken by a character and the respawn delay elapses";
    var() Rotator		spawnRotationOffset		"Rotation offset to be applied to the object when spawned";
    var() Name			objectAttachBone		"Bone on SpawnPoint that the object is attached to when spawned";
    var() float			useableObjectCollisionHeight;
    var() float			useableObjectCollisionRadius;
    var() Vector		useableObjectOffset;

    var Actor						spawnedObject; // use with care on client. prefer signal events.
    var ObjectSpawnUseableObject	useableObject;
    var float						respawnAnimTime;
    var bool						bHoldingObject;
    var bool						bWatchingObject;
    var bool						bFirstSpawn;
    var bool						bWaitingForObject;
    var bool						bFinishedDeployEnd;
    var bool						bFinishedClosing;

    replication
    {
    	reliable if (Role == ROLE_Authority)
    		spawnedObject, respawnAnimTime, bHoldingObject, bWatchingObject,
    		bFirstSpawn, bWaitingForObject, bFinishedDeployEnd, bFinishedClosing;
    }

    function PostBeginPlay()
    {
    	local vector useableOffset;

    	super.PostBeginPlay();

    	useableOffset = useableObjectOffset >> rotation;
    	useableOffset += Location;

    	useableObject = spawn(class'ObjectSpawnUseableObject',self,,useableOffset,Rotation);
    	useableObject.SetCollisionSize(useableObjectCollisionRadius, useableObjectCollisionHeight);

    	UseablePoints[0] = useableObject.GetUseablePoint();
    	UseablePointsValid[0] = UP_Valid;
    }

    simulated function Destroyed()
    {
    	if (useableObject != None)
    		useableObject.Destroy();

    	Super.Destroyed();
    }

    // spawnObject
    function spawnObject()
    {
    	local Vector spawnLocation;
    	local Rotator spawnRotation;

    	if (objectType == None)
    		return;

    	spawnLocation = spawnOffset >> rotation;
    	spawnLocation += Location;

    	spawnRotation = spawnRotationOffset + rotation;

    	spawnedObject = spawn(objectType, , , spawnLocation, spawnRotation);
    	if (spawnedObject != None)
    	{
    		spawnedObject.SetPhysics(PHYS_None);
    		spawnedObject.Instigator = self;
    		if (objectAttachBone != '')
    		{
    			AttachToBone(spawnedObject, objectAttachBone);
    			spawnedObject.bReplicateMovement = true;
    		}
    		TriggerEffectEvent('SpawnObject');

    		if (Rook(spawnedObject) != None)
    			Rook(spawnedObject).setTeam(team());
    		else if (Deployable(spawnedObject) != None)
    		{
    			Deployable(spawnedObject).team = team();
    			spawnedObject.GotoState('DeployableStation');
    		}

    		bHoldingObject = true;
    	}
    	else
    	{
    		log("ObjectSpawnPoint "$label$" couldn't spawn its object");

    		bHoldingObject = false;
    	}
    }

    simulated function bool CanBeUsedBy(Character CharacterUser)
    {
    	return super.CanBeUsedBy(CharacterUser);
    }

    // OnPlayerUsed
    function OnPlayerUsed(Pawn Other)
    {
    	local Character c;
    	local Deployable d;

    	c = Character(Other);

    	d = Deployable(spawnedObject);

    	if (d != None && c != None)
    	{
    		if (d.canPickup(c))
    		{
    			d.team = team();
    			d.pickup(c);

    			// no longer a valid useable point
    			UseablePointsValid[0] = UP_NotValid;

    			bHoldingObject = false;
    		}
    	}
    }

    simulated function bool isOpenedAnimPlaying(Name animName)
    {
    	return animName == 'Open' || animName == 'DeployStart' || animName == 'DeployEnd';
    }

    simulated latent function latentExecuteActive()
    {
    	local float lastTime;

    	if (respawnAnimTime != 0)
    		Goto RespawnAnimClosing;

    	if (bHoldingObject)
    		Goto HoldingObject;
    	else if (bWatchingObject)
    		Goto WatchingObject;
    	else if (bWaitingForObject)
    		Goto WaitingForRespawn;
    	else if (bFinishedDeployEnd)
    		Goto FinishedDeployEnd;
    	else if (bFinishedClosing)
    		Goto FinishedClosing;
    	else
    	{
    		if (!bFirstSpawn)
    			Goto WaitingForRespawn;
    		else
    			bFirstSpawn = false;
    	}

    SpawnObject:
    	PlayBDAnim('DeployStart');
    	TriggerEffectEvent('DeployableSpawned');

    	bWaitingForObject = false;

    	spawnObject(); // server-only call
    	while (spawnedObject == None)
    		Sleep(0.1);	// may have to wait on client for object reference to replicate
    	UseablePointsValid[0] = UP_Valid;

    HoldingObject:
    	// check if object was collected
    	if (!bHoldingObject)
    	{
    		if (bCanSpawnMultiples)
    		{
    			bWatchingObject = false;
    			StopAnimating();
    			goto WaitingForRespawn;	// we don't care about the object's death if we can spawn multiples
    		}
    		else
    		{
    			bWatchingObject = true;
    			goto WatchingObject;
    		}
    	}
    	Sleep(0.5);
    	goto HoldingObject;

    WatchingObject: // waiting for the spawned object to die
    	if (!bWatchingObject)
    	{
    		StopAnimating();
    		goto WaitingForRespawn;
    	}

    	if (Role == ROLE_Authority)
    	{
    		if (spawnedObject == None || spawnedObject.bDeleteMe)
    		{
    			bWatchingObject = false;
    		}
    	}

    	Sleep(0.5);
    	goto WatchingObject;

    WaitingForRespawn:
    	bFinishedDeployEnd = false;
    	bWaitingForObject = true;

    	if (!IsAnimating())
    	{
    		PlayBDAnim('DeployEnd');
    	}

    	FinishAnim(0);

    FinishedDeployEnd:
    	bWaitingForObject = false;
    	bFinishedDeployEnd = true;

    	while (Role != ROLE_Authority && (respawnAnimTime == 0 && HasAnim('Closing')))
    	{
    		if (spawnedObject != None)
    			goto SpawnObject;

    		Sleep(0);
    	}

    RespawnAnimClosing:

    	// respawnAnimTime is used to sync anim on client only
    	if (Role == ROLE_Authority)
    		respawnAnimTime = GetAnimLength('Closing') * respawnDelay;

    	PlayAnim('Closing', 1.0 / respawnAnimTime,, 0);
    	savedAnim = 'Closing';

    	lastTime = Level.TimeSeconds;
    	while (true)
    	{
    		Sleep(0);
    		respawnAnimTime -= Level.TimeSeconds - lastTime;

    		// stop deployable poking through station on client
    		if (Level.NetMode == NM_Client && spawnedObject != None)
    			spawnedObject.bHidden = true;

    		if (!IsAnimating())
    			break;
    	}

    	StopAnimating();

    	respawnAnimTime = 0;

    FinishedClosing:
    	if (spawnedObject != None)
    		spawnedObject.bHidden = false;

    	bFinishedDeployEnd = false;
    	bFinishedClosing = true;

    	if (!IsAnimating())
    	{
    		PlayBDAnim('Opening');
    	}
    	FinishAnim(0);

    	while (Role != ROLE_Authority && spawnedObject == None)
    	{
    		Sleep(0);
    	}

    	bFinishedClosing = false;
    	goto SpawnObject;
    }

    // State Unpowered
    simulated state Unpowered
    {
    	simulated function BeginState()
    	{
    		super.BeginState();
    		destroyHeldObject();
    		UseablePointsValid[0] = UP_NotValid;
    	}

    Begin:
    	if (!bInitialization)
    	{
    		PlayBDAnim('Closing');
    		FinishAnim();
    	}
    	LoopBDAnim('Closed');
    }

    // State Destructed
    simulated state Destructed
    {
    	simulated function BeginState()
    	{
    		super.BeginState();
    		destroyHeldObject();
    		UseablePointsValid[0] = UP_NotValid;
    	}
    }

    function destroyHeldObject()
    {
    	if (bHoldingObject)
    	{
    		if (spawnedObject != None)
    		{
    			spawnedObject.Destroy();
    			spawnedObject = None;
    		}

    		bHoldingObject = false;
    		bWatchingObject = false;
    		bWaitingForObject = false;
    		bFinishedDeployEnd = false;
    		bFinishedClosing = false;
    	}
    }

    function onTeamChange()
    {
    	super.onTeamChange();

    	destroyHeldObject();
    }

    defaultproperties
    {
    	bReplicateAnimations = false

    	bWorldGeometry = false
    	objectAttachBone = "deployable"

    	useableObjectCollisionHeight = 80
    	useableObjectCollisionRadius = 60
    	useableObjectOffset = (X=0,Y=40,Z=0)

    	bFirstSpawn = true;
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:20.000 - Creation time: st 23.5.2018 00:10:46.260 - Created with UnCodeX