Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Engine.Projector

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158

    class Projector extends Actor
    	placeable
    	hidecategories(Collision, Force, Karma, LightColor, Lighting, Object, Sound)
    	native;

    // Projector blending operation.

    enum EProjectorBlending
    {
    	PB_None,
    	PB_Modulate,
    	PB_AlphaBlend,
    	PB_Add,
    	PB_AlphaModulate,
    };

    var() EProjectorBlending	MaterialBlendingOp,		// The blending operation between the material being projected onto and ProjTexture.
    							FrameBufferBlendingOp;	// The blending operation between the framebuffer and the result of the base material blend.

    // Projector properties.

    var() Material	ProjTexture;
    var() int		FOV;
    var() int		MaxTraceDistance;
    var() bool		bProjectBSP;
    var() bool		bProjectTerrain;
    var() bool		bProjectStaticMesh;
    var() bool		bProjectParticles;
    var() bool		bProjectActor;
    var() bool		bLevelStatic;
    var() bool		bClipBSP;
    var() bool		bClipStaticMesh;
    var() bool		bProjectOnUnlit;
    var() bool		bGradient;
    var() bool		bProjectOnBackfaces;
    var() bool		bProjectOnAlpha;
    var bool		bProjectOnParallelBSP;

    var() name		ProjectTag;
    var() bool		bDynamicAttach;
    var() bool		bNoProjectOnOwner "If true, this projector will not project on an actor that owns it. Only applicable to DynamicProjectors";
    var() float		FadeInTime "Projector will fade in over this amount of time, in seconds. A value of 0 means 'appear instantly'";

    // Internal state.

    var const transient plane FrustumPlanes[6];
    var const transient vector FrustumVertices[8];
    var const transient Box Box;
    var const transient ProjectorRenderInfoPtr RenderInfo;
    var Texture GradientTexture;
    var transient Matrix GradientMatrix;
    var transient Matrix Matrix;
    var transient Vector OldLocation;

    // Native interface.

    native function AttachProjector(optional float FadeInTime);
    native function DetachProjector(optional bool Force);
    native function AbandonProjector(optional float Lifetime);

    native function AttachActor( Actor A );
    native function DetachActor( Actor A );

    simulated event PostBeginPlay()
    {
    	if ( Level.NetMode == NM_DedicatedServer )
    	{
    		GotoState('NoProjection');
    		return;
    	}

    	Initialise();
    	if( bProjectActor )
    		SetCollision(True, False, False);
    }

    #if IG_TRIBES3	// rowan: savegame support
    simulated event PostLoadGame()
    {
    	Initialise();
    }

    simulated function Initialise()
    {
    	AttachProjector( FadeInTime );
    	if( bLevelStatic )
    	{
    #if IG_SHARED // ckline: projectors cannot be both bLevelStatic and bDynamicAttach!
            assertWithDescription(!bDynamicAttach, "Projector "$Name$" is both bLevelStatic=true and bDynamicAttach=true -- this is not allowed and will probably cause the game to crash soon");
    #endif
    		AbandonProjector();
    		Destroy();
    	}
    }
    #endif

    simulated event Touch( Actor Other )
    {
    	if(Other==None)
    		return;

    	if( Other.bAcceptsProjectors
    	    && (ProjectTag=='' || Other.Tag==ProjectTag)
    	    && (bProjectStaticMesh || Other.StaticMesh==None)
    	    && !(Other.bStatic && bStatic && Other.StaticMesh!=None) )
    	{
    	    AttachActor(Other);
            }
    }

    simulated event Untouch( Actor Other )
    {
    	DetachActor(Other);
    }

    #if IG_SHARED	// rowan: call back before dynamic projectors are rendererd
    native final function UpdateMatrix();
    simulated event PreRenderCallback() {}
    #endif

    state NoProjection
    {
    	function BeginState()
    	{
    		Disable('Tick');
    	}
    }

    defaultproperties
    {
    	MaterialBlendingOp=PB_None
    	FrameBufferBlendingOp=PB_Modulate
    	FOV=0
    	bDirectional=True
    	Texture=Texture'Engine_res.Proj_Icon'
    	MaxTraceDistance=1000
    	bProjectBSP=True
    	bProjectTerrain=True
    	bProjectStaticMesh=True
    	bProjectParticles=True
    	bProjectActor=True
    	bProjectOnAlpha=True
    	bClipBSP=False
    	bClipStaticMesh=False
    	bLevelStatic=False
    	bProjectOnUnlit=False
    	bHidden=True
    	bStatic=True
    	GradientTexture=Texture'Engine_res.GRADIENT_Fade'
    	bProjectOnBackfaces=False
    	bDynamicAttach=False
    	RemoteRole=ROLE_None
    	CullDistance=0
    // #if IG_SHARED
        bOnlyAffectCurrentZone=false
    // #endif
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 16:01:26.000 - Creation time: st 23.5.2018 00:10:46.636 - Created with UnCodeX