Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Tyrion.AI_GoalSpecificSensorAction

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144

    //=====================================================================
    // AI_GoalSpecificSensorAction
    // Updates one-time use sensors needed to activate specific goals
    //=====================================================================

    class AI_GoalSpecificSensorAction extends AI_SensorCharacterAction;

    //=====================================================================
    // Constants

    const HEALTH_SCALE = 40.0f;		// health weighting (vs. distance squared) for repair priority

    //=====================================================================
    // Variables

    var AI_RepairSensor repairSensor;				// is updated by this sensor action
    var AI_EnterVehicleSensor enterVehicleSensor;	// is updated by this sensor action

    var BaseAICharacter ai;
    var Rook target;					// target of repair
    var int i;

    //=====================================================================
    // Functions

    //---------------------------------------------------------------------
    // set up the sensors this action may update

    function setupSensors( AI_Resource resource )
    {
    	// construct all sensors, add them to resource's sensor list
    	repairSensor = AI_RepairSensor(addSensorClass( class'AI_RepairSensor' ));
    	enterVehicleSensor = AI_EnterVehicleSensor(addSensorClass( class'AI_EnterVehicleSensor' ));

    	// repeat if there are more sensors this sensorAction updates
    }

    //---------------------------------------------------------------------
    // find the squad mate most in need of repair

    private final function Rook findDamagedSquadMate()
    {
    	local int i;
    	local Rook squaddie;
    	local Rook hurtSquaddie;		// return value
    	local float leastHealth;

    	if ( ai.squad() == None )
    		return None;

    	leastHealth = 9999999999.9f;

    	for ( i = 0; i < ai.squad().pawns.length; ++i )
    	{
    		squaddie = Rook(ai.squad().pawns[i]);
    		if ( class'Pawn'.static.checkAlive( squaddie ) && squaddie.health < squaddie.healthMaximum )
    		{
    			if ( squaddie.health < leastHealth )
    			{
    				leastHealth = squaddie.health;
    				hurtSquaddie = squaddie;
    			}
    		}
    	}

    	//if ( hurtSquaddie != None )
    	//	log( "REPAIR:" @ ai.name @ "found" @ hurtSquaddie.name @ "in squad" );

    	return hurtSquaddie;
    }

    //---------------------------------------------------------------------
    // find nearby pawns in need of repair

    private final function Rook findDamagedNearbyPawn()
    {
    	local int i;
    	local Rook rook;
    	local Rook hurtRook;		// return value
    	local float bestScore;
    	local float score;			// health + distance
    	local array<Rook> seenList;

    	bestScore = 9999999999.9f;
    	seenList = ai.vision.getSeenList();

    	for ( i = 0; i < seenList.length; ++i )
    	{
    		rook = seenList[i];
    		if ( class'Pawn'.static.checkAlive( rook ) && rook.health < rook.healthMaximum && ai.isFriendly( rook ) )
    		{
    			score = HEALTH_SCALE * rook.health + VDist( ai.Location, rook.Location );
    			if ( score < bestScore )
    			{
    				bestScore = score;
    				hurtRook = rook;
    			}
    		}
    	}

    	//if ( hurtRook != None )
    	//	log( "REPAIR:" @ ai.name @ "found" @ hurtRook.name @ "in seenlist" );

    	return hurtRook;
    }

    //=====================================================================
    // State Code

    state Running
    {
    Begin:
    	repairSensor.setObjectValue( None );
    	enterVehicleSensor.setObjectValue( None );
    	ai = baseAICharacter();

    	while ( true )
    	{
    		if ( repairSensor.queryUsage() > 0 && ai.pack.IsInState( 'Charged' ) )
    		{
    			// check squad mates damage
    			target = findDamagedSquadmate();

    			// check seen pawns damage
    			if ( target == None )
    				target = findDamagedNearbyPawn();

    			repairSensor.setObjectValue( target );
    		}

    		if ( enterVehicleSensor.queryUsage() > 0 )
    		{
    			if ( class'AI_EnterVehicleSensor'.static.isEnterable( enterVehicleSensor.vehicleOrTurret, enterVehicleSensor.vehiclePosition ) )
    				enterVehicleSensor.setObjectValue( enterVehicleSensor.vehicleOrTurret );
    			else
    				enterVehicleSensor.setObjectValue( None );
    		}

    		Sleep(1.0f);
    	}
    }

    //=====================================================================

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:54:28.000 - Creation time: st 23.5.2018 00:10:41.236 - Created with UnCodeX