Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Scripting.ActionCinematicFadeView

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089

    class ActionCinematicFadeView extends Action;

    var() actionnoresolve color fadeStart;
    var() actionnoresolve color fadeEnd;
    var() actionnoresolve float fadeAlphaStart	"The start alpha value of the fade, between 0 and 1";
    var() actionnoresolve float fadeAlphaEnd	"The end alpha value of the fade, between 0 and 1";
    var() float duration						"Duration of fade in seconds. Set to zero for an instant adjustment";
    var() float holdDuration					"Time in seconds to hold the fade after the duration is over.";
    var() bool bRestoreFadeControl				"If false, then fade control is not restored to the game after the action is finished. When you are finished with this behaviour, you will need to trigger a 'zero duration' fade action with this variable set to false. If you do not do this, the screen may remain black and pain flashes will not work.";

    var float startTime;

    // execute
    latent function Variable execute()
    {
    	local PlayerController pc;
    	local Vector fadeDiff;
    	local float alpha;

    	Super.execute();

    	pc = parentScript.Level.GetLocalPlayerController();
    	pc.bManualFogUpdate = true;

    	if (duration != 0)
    	{
    		fadeDiff.X = fadeEnd.R - fadeStart.R;
    		fadeDiff.Y = fadeEnd.G - fadeStart.G;
    		fadeDiff.Z = fadeEnd.B - fadeStart.B;

    		startTime = parentScript.Level.TimeSeconds;
    		while (parentScript.Level.TimeSeconds - startTime < duration)
    		{
    			alpha = (parentScript.Level.TimeSeconds - startTime) / duration;

    			pc.FlashFog.X = (float(fadeStart.R) + fadeDiff.X * alpha) / 255;
    			pc.FlashFog.Y = (float(fadeStart.G) + fadeDiff.Y * alpha) / 255;
    			pc.FlashFog.Z = (float(fadeStart.B) + fadeDiff.Z * alpha) / 255;
    			pc.FlashScale.X = 1.0f - (fadeAlphaStart + (fadeAlphaEnd - fadeAlphaStart) * alpha); // for some reason, flashscale 0 means full alpha
    			pc.FlashScale.Y = pc.FlashScale.X;
    			pc.FlashScale.Z = pc.FlashScale.X;
    			Sleep(0);
    		}
    	}
    	else
    	{
    		pc.FlashFog.X = fadeEnd.R / 255;
    		pc.FlashFog.Y = fadeEnd.G / 255;
    		pc.FlashFog.Z = fadeEnd.B / 255;
    		pc.FlashScale.X = fadeAlphaEnd;
    		pc.FlashScale.Y = pc.FlashScale.X;
    		pc.FlashScale.Z = pc.FlashScale.X;
    	}

    	if (holdDuration > 0)
    		Sleep(holdDuration);

    	if (bRestoreFadeControl)
    	{
    		pc.bManualFogUpdate = false;

    		pc.FlashScale.X = 1;
    		pc.FlashScale.Y = 1;
    		pc.FlashScale.Z = 1;
    	}

    	return None;
    }

    // editorDisplayString
    function editorDisplayString(out string s)
    {
    	s = "Fade view";
    }

    defaultproperties
    {
    	returnType			= None
    	actionDisplayName	= "Fade View"
    	actionHelp			= "Fades the view. Does not finish until the fade is completed."
    	category			= "Cinematic"

    	duration			= 2
    	fadeStart			= (R=0,G=0,B=0)
    	fadeEnd				= (R=0,G=0,B=0)
    	fadeAlphaStart		= 0
    	fadeAlphaEnd		= 1
    	bRestoreFadeControl = true
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:42.000 - Creation time: st 23.5.2018 00:10:40.087 - Created with UnCodeX