Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Tyrion.AI_SquadAttack

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213

    //=====================================================================
    // AI_SquadAttack
    // Has a squad attacks another squad
    // High level attack - moves to a target and engages it
    //=====================================================================

    class AI_SquadAttack extends AI_SquadAction
    	editinlinenew;

    //=====================================================================
    // Constants

    const DEFAULT_PROXIMITY = 1000;	// how close to get to target (by default)

    //=====================================================================
    // Variables

    var(Parameters) editinline Name targetName "Label of target pawn or squad";

    var(InternalParameters) editconst SquadInfo targetSquad;
    var(InternalParameters) editconst Pawn target;

    var int i;
    var Actor targetActor;
    var Pawn attacker;
    var bool bAttackGoalPosted;

    //=====================================================================
    // Functions

    //---------------------------------------------------------------------
    // child action callbacks

    function goalAchievedCB( AI_Goal goal, AI_Action child )
    {
    	super.goalAchievedCB( goal, child );

    	// assign new target
    	if ( assignNewTarget( goal.resource.pawn() ) == None )
    		runAction();			// no targets left -> action continues running
    }

    //---------------------------------------------------------------------
    // child action callbacks

    function goalNotAchievedCB( AI_Goal goal, AI_Action child, ACT_ErrorCodes errorCode )
    {
    	super.goalNotAchievedCB( goal, child, errorCode );

    	//log( name $ ":" @ goal.name @ "not achieved" @ "with errorcode" @ errorcode );

    	if ( errorCode == ACT_ALL_RESOURCES_DIED || errorCode == ACT_RESOURCE_INACTIVE )
    	{
    		if ( !resource.isActive() )
    			instantFail( ACT_RESOURCE_INACTIVE );
    	}
    	else
    	{
    		if ( assignNewTarget( goal.resource.pawn() ) == None )
    			runAction();			// no targets left -> action continues running

    		goal.unPostGoal( self );				// unpost old goal (deletes goal!)
    	}
    }

    //---------------------------------------------------------------------
    // finds a new target and posts an attack goal
    // returns the target found

    private function Pawn assignNewTarget( Pawn attacker )
    {
    	local Pawn target;

    	target = bestTarget( attacker );

    	if ( target != None )
    		(new class'AI_AttackGoal'( AI_Resource(attacker.characterAI), achievingGoal.priority, target )).postGoal( self );

    	return target;
    }

    //---------------------------------------------------------------------
    // finds best target in targetSquad
    // return None if all target pawns are dead

    private function Pawn bestTarget( Pawn attacker )
    {
    	local int i, j;
    	local Pawn enemy;
    	local Pawn closestEnemy;				// closest living enemy
    	local AI_AttackGoal goal;
    	local bool bEnemyBeingAttacked;
    	local array<Pawn> sortedTargets;		// targets sorted by distance
    	local array<float> distancesSquared;

    	if ( target != None || targetSquad == None )
    		return target;						// attacking a single target

    	// sort targets by distance (stupid n-squared insertion sort)
    	for ( i = 0; i < targetSquad.pawns.length; i++ )
    	{
    		enemy = targetSquad.pawns[i];
    		if ( enemy == None )
    			distancesSquared[i] = 99999999999999.9f;
    		else
    			distancesSquared[i] = VDistSquared( enemy.Location, attacker.Location );

    		// maintain sorted list of distances
    		for( j = 0; j < i; ++j )
    		{
    			if ( distancesSquared[j] < distancesSquared[i] )
    				break;
    		}
    		sortedTargets.insert(j, 1);
    		sortedTargets[j] = enemy;
    	}

    	// find enemy member that isn't being attacked and is visible
    	for ( i = 0; i < sortedTargets.length; i++ )
    	{
    		enemy = targetSquad.pawns[i];

    		if ( class'Pawn'.static.checkAlive( enemy ) && Rook(attacker).vision.isVisible( enemy ) )
    		{
    			for ( j = 0; j < resource.goals.length; j++ )
    			{
    				goal = AI_AttackGoal(resource.goals[j]);
    				if ( goal != None && goal.target == enemy )
    				{
    					bEnemyBeingAttacked = true;
    					break;
    				}
    			}

    			if ( !bEnemyBeingAttacked )
    				return enemy;

    			if ( closestEnemy == None )
    				closestEnemy = enemy;
    		}
    	}

    	// all enemies being attacked - just return closest one (or None)
    	return closestEnemy;
    }

    //=====================================================================
    // State code

    state Running
    {
    Begin:
    	if ( target == None && targetSquad == None && targetName == '' )
    	{
    		log( "AI WARNING:" @ name @ "(" @ squad().name @ ") has no target" );
    		fail( ACT_INVALID_PARAMETERS, true );
    	}

    	if ( target == None && targetSquad == None )
    	{
    		targetActor = squad().findStaticByLabel( class'Actor', targetName, true );
    		targetSquad = SquadInfo(targetActor);
    		target = Pawn(targetActor);
    	}

    	if ( squad().logTyrion )
    		if ( target != None )
    			log( name @ "started." @ squad().name @ "is attacking" @ target.name );
    		else
    			log( name @ "started." @ squad().name @ "is attacking" @ targetSquad.name );

    	if ( target == None && targetSquad == None )
    	{
    		log( "AI WARNING:" @ name @ "(" @ squad().name @ ") can't find specified target" );
    		fail( ACT_INVALID_PARAMETERS, true );
    	}

    	// find targets for all squad members
    	for ( i = 0; i < squad().pawns.length; i++ )
    	{
    		attacker = squad().pawns[i];
    		if ( class'Pawn'.static.checkAlive( attacker ) && assignNewTarget( attacker ) != None )
    			bAttackGoalPosted = true;
    	}

    	// pauses until all targets have died (all attackers dying handled in callback)
    	if ( bAttackGoalPosted )
    		pause();		// at least one AttackGoal posted

    	if ( squad().logTyrion )
    	{
    		if ( !targetSquad.squadAI.isActive() )
    			log( name @ "(" @ squad().name @ ")succeeded!" );
    		else
    			log( name @ "(" @ squad().name @ ")failed." );
    	}

    	if ( !targetSquad.squadAI.isActive() )
    		succeed();
    	else
    	{
    		// (Tyrion won't rematch this goal since it doesn't use leaf resources - but it should try again if it fails)
    		resource.bMatchGoals = true;
    		fail( ACT_GENERAL_FAILURE );
    	}
    }

    //=====================================================================

    defaultproperties
    {
    	satisfiesGoal = class'AI_SquadAttackGoal'
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:54:00.000 - Creation time: st 23.5.2018 00:10:41.732 - Created with UnCodeX