Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Tyrion.AI_SquadFollow

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388

    //=====================================================================
    // AI_SquadFollow
    // Has a squad follow a pawn
    //=====================================================================

    class AI_SquadFollow extends AI_SquadAction implements IFollowFunction
    	editinlinenew;

    //=====================================================================
    // Constants

    const MAX_SQUAD_SIZE = 9;			// maximum number of pawns in a squad
    const MIN_LEADER_SPEED = 3;			// (km/h) min speed of leader for followers to update position

    //=====================================================================
    // Variables

    var(Parameters) editinline Name targetName "A pawn to follow";
    var(Parameters) float proximity "How close to get to one's desired position while following";
    var(Parameters) float formationDiameter "What's the approximate diameter of the formation?";
    var(Parameters) float energyUsage;
    var(Parameters) float terminalVelocity;
    var(Parameters) float terminalHeight;
    var(Parameters) Character.GroundMovementLevels preferredGroundMovement;

    var(InternalParameters) editconst Pawn target;

    var int i;
    var Pawn pawn;
    var int aliveFollowers;	// number of alive pawns in the squad who are following (doesn't include followee or player)

    var AI_Goal followGoals[MAX_SQUAD_SIZE];	// followers' goals
    var int positionMap[MAX_SQUAD_SIZE];		// maps followers positionIndex to the index used by the offset function
    var int lastUpdateOffset[MAX_SQUAD_SIZE];	// what was the result of the last positionIndex pawn's call to updateOffset?

    //=====================================================================
    // Functions

    //---------------------------------------------------------------------
    // number of alive pawns currently following

    function int nFollowers()
    {
    	return aliveFollowers;
    }

    //---------------------------------------------------------------------
    // number of alive and dead pawns

    function int nPossibleFollowers()
    {
    	return squad().pawns.length;
    }

    //---------------------------------------------------------------------
    // IFollowFunction interface: is a given location a valid place to follow to?

    function bool validDestination( Vector point )
    {
    	return true;
    }

    //---------------------------------------------------------------------
    // IFollowFunction interface: how close do you want to get to the target?

    function float proximityFunction()
    {
    	return proximity;
    }

    //---------------------------------------------------------------------
    // Inform an action that a particular pawn died

    function pawnDied( Pawn member )
    {
    	local int i;

    	if ( squad().logTyrion )
    		log( name $ ": (" @ squad().name @ ")" @ member.name @ "died!" );

    	assert( member != None );

    	// remove followGoal of dead pawn (pawns list is not changed so positionIndexes still make sense)
    	for ( i = 0; i < squad().pawns.length; i++ )
    	{
    		if ( squad().pawns[i] == member && followGoals[i] != None )
    		{
    			followGoals[i].unPostGoal( self );
    			followGoals[i].Release();
    			followGoals[i] = None;
    			// this may give the wrong number if pawnDied is called before statecode is called, but that's ok,
    			// because aliveFollowers will be recomputed in state anyways
    			aliveFollowers--;
    			break;
    		}
    	}
    }

    //---------------------------------------------------------------------
    // Sanity check for "aliveFollowers"

    function bool verifyAliveFollowers()
    {
    	local int i;
    	local int actualFollowers;

    	for ( i = 0; i < squad().pawns.length; i++ )
    		if ( class'Pawn'.static.checkAlive( squad().pawns[i] ) && squad().pawns[i] != target )
    		{
    			//log( squad().name @ "contains:" @ squad().pawns[i].name );
    			actualFollowers++;
    		}

    	if ( actualFollowers != aliveFollowers )
    	{
    		log( "AI ERROR:" @ name $ ": aliveFollowers is" @ aliveFollowers @ "; should be" @ actualFollowers );
    		return false;
    	}
    	else
    		return true;
    }

    //---------------------------------------------------------------------
    // IFollowFunction interface: should offset be updated?

    function bool updateOffset( Pawn follower, Pawn leader, int positionIndex )
    {
    	local float distanceSquared;
    	local int i, sumUpdateOffsets;

    	//log( "updateOffset called by" @ follower.name @ "("$ positionIndex $ ")" );

    	distanceSquared = VDistSquared( leader.Location, follower.Location );

    	if ( ( VSize( leader.Velocity ) / 80 * 3.6f > MIN_LEADER_SPEED && distanceSquared > formationDiameter * formationDiameter )
    			|| distanceSquared > 4 * formationDiameter * formationDiameter )
    	{
    		// if all pawns are waiting for a new offset, remap positions before sending this one off
    		for ( i = 0; i < nPossibleFollowers(); i++ )
    			sumUpdateOffsets += lastUpdateOffset[i];

    		if ( sumUpdateOffsets == 0 )
    			assignPawnsToPositions();

    		lastUpdateOffset[positionIndex] = 1;
    		return true;
    	}
    	else
    	{
    		lastUpdateOffset[positionIndex] = 0;
    		return false;
    	}
    }

    //---------------------------------------------------------------------
    // IFollowFunction interface: offset for follow function

    function Vector offset( Pawn leader, int positionIndex )
    {
    	return offsetInternal( leader, positionMap[positionIndex] );
    }

    function Vector offsetInternal( Pawn leader, int positionIndex )
    {
    	local Vector result;
    	local int row;

    	// hard code positions for now; x is back(-)/front(+); y is left(-)/right(+)
    	switch ( nFollowers() )
    	{
    	case 1:
    		result.X = -100;
    		result.Y = -5/6 * formationDiameter;
    		break;
    	case 2:
    		switch( positionIndex )
    		{
    		case 0:
    			result.X = -100;
    			result.Y = -2/3 * formationDiameter;
    			break;
    		case 1:
    			result.X = -100;
    			result.Y = +2/3 * formationDiameter;
    			break;
    		}
    		break;
    	case 3:
    		switch( positionIndex )
    		{
    		case 0:
    			result.X = -100;
    			result.Y = -5/6 * formationDiameter;
    			break;
    		case 1:
    			result.X = -2/3 * formationDiameter;
    			result.Y = 0;
    			break;
    		case 2:
    			result.X = -100;
    			result.Y = +5/6 * formationDiameter;
    			break;
    		}
    		break;
    	default:
    		switch( positionIndex )
    		{
    		case 0:
    			result.X = -100;
    			result.Y = -formationDiameter;
    			break;
    		case 1:
    			result.X = -4/6 * formationDiameter;
    			result.Y = -200;
    			break;
    		case 2:
    			result.X = -4/6 * formationDiameter;
    			result.Y = +200;
    			break;
    		case 3:
    			result.X = -100;
    			result.Y = formationDiameter;
    			break;
    		default:
    			row = (nFollowers() - 3) / 2;	// assuming this rounds down
    			result.X = -300 * row;
    			result.Y = ((positionIndex % 2) * 2 - 1) * 1/2 * formationDiameter;
    			break;
    		}
    		break;
    	}

    	if ( positionIndex < 0 || positionIndex > nFollowers()-1 )
    		log( "AI WARNING:" @ name @ "offsetInternal referencing illegal positionIndex (" $ positionIndex $ "). Squad only has" @ nFollowers() @ "followers" );

    	//log( positionIndex $ " ("$ nFollowers() $") picked offset " $ result );

    	return result >> rotator(leader.Velocity);
    	//return result >> Character(leader).motor.getMoveRotation();
    }

    //---------------------------------------------------------------------
    // assign pawns to squad positions

    function assignPawnsToPositions()
    {
    	local int positionIndex, pawnIndex, bestPositionIndex;
    	local int bPositionUsed[MAX_SQUAD_SIZE];	// (boolean arrays not allowed)
    	local float bestDistSquared, distSquared;
    	local Pawn pawn;

    	for ( pawnIndex = 0; pawnIndex < nPossibleFollowers(); pawnIndex++ )
    	{
    		pawn = squad().pawns[pawnIndex];

    		if ( class'Pawn'.static.checkAlive( pawn ) && pawn != target )
    		{
    			bestDistSquared = 99999999999999.9f;

    			// find positionIndex closest to this position
    			for ( positionIndex = 0; positionIndex < nFollowers(); positionIndex++ )
    			{
    				// distance of pawn from this position
    				distSquared = VDistSquared( pawn.Location, offsetInternal( target, positionIndex ) + target.Location );

    				if ( bPositionUsed[positionIndex] == 0 && distSquared < bestDistSquared )
    				{
    					bestDistSquared = distSquared;
    					bestPositionIndex = positionIndex;
    				}
    			}

    			bPositionUsed[bestPositionIndex] = 1;
    			positionMap[pawnIndex] = bestPositionIndex;

    			if ( Rook(pawn).bShowSquadDebug )
    				log( "Assigning" @ pawn.name @ "to position" @ bestPositionIndex );
    		}
    		else
    			positionMap[pawnIndex] = -1;
    	}
    }

    //---------------------------------------------------------------------

    function cleanup()
    {
    	local int i;
    	local Controller c;

    	super.cleanup();

    	// stop all the followers
    	for ( i = 0; i < squad().pawns.length; i++ )
    	{
    		if ( followGoals[i] != None )
    		{
    			c = followGoals[i].resource.pawn().controller;
    			if ( c != None )
    				AI_Controller(c).stopMove();
    			followGoals[i].Release();
    			followGoals[i] = None;
    		}
    	}
    }

    //=====================================================================
    // State code

    state Running
    {
    Begin:
    	if ( target == None && targetName == '' )
    	{
    		log( "AI WARNING:" @ name @ "has no target" );
    		fail( ACT_INVALID_PARAMETERS, true );
    	}

    	if ( target == None )
    		target = Pawn(squad().findByLabel( class'Engine.Pawn', targetName, true ));

    	if ( target == None )
    	{
    		log( "AI WARNING:" @ name @ "can't find specified pawn" );
    		fail( ACT_INVALID_PARAMETERS, true );
    	}

    	if ( squad().pawns.length > MAX_SQUAD_SIZE )
    	{
    		log( "AI ERROR:" @ name @ "contains more than" @ MAX_SQUAD_SIZE @ "pawns" );
    		assert( squad().pawns.length > MAX_SQUAD_SIZE );
    	}

    	if ( squad().logTyrion )
    		log( name @ "started." @ squad().name @ "is following" @ target.name );

    	// create follow goals for pawns that are alive
    	aliveFollowers = 0;
    	for ( i = 0; i < MAX_SQUAD_SIZE; ++i )
    	{
    		if ( i < squad().pawns.length )
    			pawn = squad().pawns[i];
    		else
    			pawn = None;

    		if ( class'Pawn'.static.checkAlive( pawn ) && pawn != target )
    		{
    			followGoals[i] = (new class'AI_FollowGoal'( AI_MovementResource(pawn.movementAI),
    								achievingGoal.priority, target, proximity, self, i,,,, preferredGroundMovement )).postGoal( self ).myAddRef();
    			aliveFollowers++;
    		}
    		else
    			followGoals[i] = None;
    	}

    	while ( class'Pawn'.static.checkAlive( target ) && nFollowers() > 0 )
    	{
    		if ( Rook(target).bShowSquadDebug )
    			log( name $ ": Assigning new positions (" $ nFollowers() @ "guys left)" ) ;

    		assignPawnsToPositions();

    		// a goal only succeeds when the target dies (in which case all will succeed)
    		// a goal only fails when the resource dies - that goal is removed in the callback
    		waitForAllGoals( followGoals[0], followGoals[1], followGoals[2], followGoals[3],
    						followGoals[4], followGoals[5], followGoals[6], followGoals[7], followGoals[8]);
    	}

    	if ( squad().logTyrion )
    		log( name @ "stopped." );

    	if ( nFollowers() > 0 )
    		succeed();
    	else
    		fail( ACT_ALL_RESOURCES_DIED );
    }

    //=====================================================================

    function classConstruct()
    {
    	resourceUsage = class'AI_Resource'.const.RU_LEGS;
    }

    defaultproperties
    {
    	satisfiesGoal = class'AI_SquadFollowGoal'
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:54:02.000 - Creation time: st 23.5.2018 00:10:41.745 - Created with UnCodeX