Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Tyrion.AI_TargetSensor

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155

    //=====================================================================
    // AI_TargetSensor
    // Keeps track of a particular pawn
    // Value (object): pointer to the target or None
    //=====================================================================

    class AI_TargetSensor extends AI_Sensor implements IVisionNotification;

    //=====================================================================
    // Variables

    // Parameters
    var Pawn target;					// the pawn this sensor is interested in
    var float canStillSeePeriod;		// seconds after which a target is lost during which the AI still knows where the target is

    // Output
    var Vector lastPlaceSeen;			// last known location of target
    var float lastTimeSeen;				// time at which target was last seen

    var AI_Sensor timerSensor;

    //=====================================================================
    // Functions

    //---------------------------------------------------------------------
    // vision callbacks

    function OnViewerSawPawn(Pawn Viewer, Pawn Seen)
    {
    	if ( target == Seen )
    	{
    		if ( sensorAction.resource.localRook().logTyrion )
    			log( sensorAction.resource.localRook().name $ ":" @ target.name @ "acquired" );

    		// discontinue countdown to "not seen" if timer present
    		if ( timerSensor != None )
    		{
    			timerSensor.deactivateSensor( self );
    			timerSensor = None;
    		}

    		setObjectValue( Seen );
    	}
    }

    function OnViewerLostPawn(Pawn Viewer, Pawn Seen)
    {
    	local int timerValue;

    	if ( target == Seen )
    	{
    		lastPlaceSeen = Seen.Location;
    		lastTimeSeen = target.level.TimeSeconds;

    		if ( canStillSeePeriod <= 0 || class'Pawn'.static.checkDead( target ) )
    		{
    			if ( sensorAction.resource.localRook().logTyrion )
    				log( sensorAction.resource.localRook().name $ ":" @ target.name @ "lost (" @ canStillSeePeriod @ ")" );
    			setObjectValue( None );
    		}
    		else
    		{
    			timerValue = canStillSeePeriod +
    				AI_SensorResource( class'Setup'.static.GetStaticSensorResource() ).globalSensorAction.timer.queryIntegerValue();

    			if ( timerSensor != None )
    			{
    				timerSensor.deactivateSensor( self );
    				timerSensor = None;
    			}
    			timerSensor = class'AI_Sensor'.static.activateSensor( self, class'AI_TimerSensor', None, timerValue, timerValue );
    		}
    	}
    }

    //---------------------------------------------------------------------
    // Sensor callback (from timerSensor)

    function onSensorMessage( AI_Sensor sensor, AI_SensorData value, Object userData )
    {
    	//log( name @ "sensorMessage called by" @ sensor.name @ "with value" @ value.integerData );

    	timerSensor.deactivateSensor( self );
    	timerSensor = None;

    	if ( class'Pawn'.static.checkDead( target ) ||
    		( !sensorAction.resource.localRook().vision.isVisible( target ) ))
    	{
    		if ( sensorAction.resource.localRook().logTyrion )
    			log( sensorAction.resource.localRook().name $ ":" @ target @ "not seen for" @ canStillSeePeriod @ "seconds (lastTimeSeen:" @ lastTimeSeen $ ")" );
    		setObjectValue( None );
    	}
    }

    //---------------------------------------------------------------------
    // perform sensor-specific startup initializations when sensor is activated

    function begin()
    {
    	sensorAction.resource.localRook().RegisterVisionNotification( self );
    }

    //---------------------------------------------------------------------
    // perform sensor-specific cleanup when sensor is deactivated

    function cleanup()
    {
    	//log( name @ sensorAction.resource.localRook().name @ "UNREGISTERING VISION" );
    	sensorAction.resource.localRook().UnregisterVisionNotification( self );
    	target = None;

    	if ( timerSensor != None )
    	{
    		timerSensor.deactivateSensor( self );
    		timerSensor = None;
    	}
    }

    //---------------------------------------------------------------------
    // Initialize set the sensor's parameters
    // 'target': the pawn this sensor is interested in
    // 'canStillSeePeriod': seconds after which a target is lost during which the AI still knows where the target is

    function setParameters( Pawn _target, optional float _canStillSeePeriod )
    {
    	if ( sensorAction.resource.localRook().logTyrion &&
    		( (target != None && target != _target) ||
    		( (canStillSeePeriod != 0 && canStillSeePeriod != _canStillSeePeriod)) ))
    		log( name @ "is redefining its target value from" @ target @ canStillSeePeriod @ "to" @ _target @ _canStillSeePeriod );

    	target = _target;
    	canStillSeePeriod = _canStillSeePeriod;

    	if ( sensorAction.resource.localRook().vision.isVisible( target ) ||
    		(lastTimeSeen >= 0 && lastTimeSeen >= target.level.TimeSeconds - canStillSeePeriod ))
    	{
    		//log( name @ "TargetSensor ACTIVATED!" @ target.Level.TimeSeconds - lastTimeSeen @ "(lastTimeSeen:" @ lastTimeSeen $ ")" );
    		setObjectValue( target );	// so sensor message is sent when sensor is first activated
    	}
    	else
    	{
    		//log( name @ "target not visible" @ target.Level.TimeSeconds @ lastTimeSeen );
    		setObjectValue( None );
    	}
    }

    //=====================================================================

    defaultproperties
    {
    	lastTimeSeen = -9999999

    	bNotifyOnValueChange = true
    	bNotifyIfResourceInactive = true	// vision based sensors have to pass through pawn lost messages when vision shuts down
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:54:30.000 - Creation time: st 23.5.2018 00:10:41.836 - Created with UnCodeX