Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# MojoActions.TsActionPlayAnim

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100

    class TsActionPlayAnim extends TsAction;

    var(Action) MojoAnimation BaseAnim;
    var(Action) float BlendInTime;
    // var(Action) float BlendOutTime;
    var(Action) float AnimRate;
    var(Action) int Iterations;
    var(Action) int PlayChannel;
    var(Action) bool DisablePhysics;

    var transient int currItrtn;
    var transient Actor.EPhysics org_physics;

    function bool OnStart()
    {
    	local MeshAnimation mesh_anim;

    	if ( (BaseAnim.name == 'None') || (BaseAnim.name == '') || (Iterations == 0) )
    		return false;

    	// load a new animation set if specified
    	if (BaseAnim.animation_set != '')
    	{
    		mesh_anim = MeshAnimation(DynamicLoadObject(string(Actor.Mesh.Outer.Name) $ "." $ string(BaseAnim.animation_set), class'MeshAnimation', true));
    		if (mesh_anim == None)
    		{
    			Log("ActionPlayAnim: Couldn't load animation set "$BaseAnim.animation_set);
    			return false;
    		}

    		Actor.LinkSkelAnim(mesh_anim);
    	}

    	if (!Actor.HasAnim(BaseAnim.name))
    	{
    		Log("bad animation name");
    		return false;
    	}

    	currItrtn = 0;

    	if (DisablePhysics)
    	{
    		org_physics = Actor.Physics;
    		Actor.SetPhysics(PHYS_None);
    	}

    	Actor.PlayAnim(BaseAnim.name,AnimRate,BlendInTime, PlayChannel);

    	return true;
    }

    function bool OnTick(float delta)
    {
    	local name currAnim;
    	local float dummyFloat;
    	local bool still_animating;

    	still_animating = Actor.IsAnimating(PlayChannel);
    	// even if we are still animating on play channel , we may have switched to a different anim. ie we are no
    	// longer playing our desired anim
    	if (still_animating)
    	{
    		Actor.GetAnimParams(PlayChannel, currAnim, dummyFloat, dummyFloat);
    		still_animating = (currAnim == BaseAnim.name);
    	}

    	// if not animating, end, or loop again
    	if (!still_animating)
    	{
    		currItrtn++;
    		if (currItrtn >= Iterations)
    		{
    			return false;
    		}
    		else
    		{
    			Actor.PlayAnim(BaseAnim.name,AnimRate,BlendInTime, PlayChannel);
    		}
    	}

    	return true;
    }

    function OnFinish()
    {
    	if (DisablePhysics)
    		Actor.SetPhysics(org_physics);
    }

    defaultproperties
    {
    	DName			="Play Animation"
    	Track			="Animation"
    	Help			="Run a particular skeletal animation"
        BlendInTime		=0.000000
     //   BlendOutTime	=0.200000
    	AnimRate		=1.000000
    	Iterations		=1
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:36.000 - Creation time: st 23.5.2018 00:10:49.344 - Created with UnCodeX