Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Tyrion.ActionWaitForGoal

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078

    class ActionWaitForGoal extends TyrionScriptAction implements IGoalNotification;

    var() editcombotype(enumTyrionTargets) Name target;
    var() String goalName;
    var() float timeout;
    var private float beginTime;
    var private int result;

    function OnGoalCompleted(bool bAchieved)
    {
    	if (bAchieved)
    		result = 0;
    	else
    		result = 1;
    }

    // execute
    latent function Variable execute()
    {
    	local Actor a;
    	local AI_Goal targetGoal;

    	Super.execute();

    	result = -1;

    	// todo: use the list of pawns and make a list of squadinfos to speed up search
    	targetGoal = None;
    	ForEach parentScript.actorLabel(class'Actor', a, target)
    	{
    		targetGoal = class'AI_Goal'.static.findGoalByName( a, goalName );

    		if (targetGoal != None && !targetGoal.hasCompleted())
    			break;
    	}

    	if (targetGoal != None)
    	{
    		targetGoal.addNotificationRecipient(self);

    		if (timeout > 0.0)
    		{
    			beginTime = parentScript.Level.TimeSeconds;

    			while (result == -1)
    			{
    				Sleep(0.0);

    				if (parentScript.Level.TimeSeconds - beginTime >= timeout)
    					result = 2;
    			}
    		}
    		else
    			while (result == -1)
    				Sleep(0.0);

    		return newTemporaryVariable(class'VariableFloat', String(result));
    	}

    	return newTemporaryVariable(class'VariableFloat', "0");
    }

    // editorDisplayString
    function editorDisplayString(out string s)
    {
    	s = "Wait for goal named " $ propertyDisplayString('goalName') $ " to finish";

    	if (timeout > 0.0)
    		s = s $ ", or timeout in " $ timeout $ " seconds";
    }

    defaultproperties
    {
    	returnType			= class'Variable'
    	actionDisplayName	= "Wait For Goal"
    	actionHelp			= "Waits for a goal to complete or fail, optional timeout period will stop the wait even if the goal has not completed. Returns 0 for success, 1 for failure and 2 for timedout"
    	category			= "AI"
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:54:28.000 - Creation time: st 23.5.2018 00:10:40.790 - Created with UnCodeX