Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Gameplay.Pod

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255

    // Pod

    class Pod extends JointControlledAircraft
    	native;

    cppText
    {
    	void CleanupDestroyed();
    }

    var array<name> muzzleSockets;

    var int currentMuzzleIndex;

    var int engineDustEffectIndex;
    var vector engineDustEffectLocation;

    var (Pod) float engineDustTraceLength;
    var (Pod) float engineDustGroundOffset;

    var VehicleEffectObserver muzzleFlashObserver;

    replication
    {
    	reliable if (Role == ROLE_Authority && bNetInitial)
    		currentMuzzleIndex;
    }

    simulated function Material getTeamSkin()
    {
    	if (m_team != None)
    		return m_team.podSkin;

    	return None;
    }

    simulated event postNetBeginPlay()
    {
    	super.postNetBeginPlay();

    	// set team skin
    	if (m_team != None)
    	{
    		skins[0] = m_team.podSkin;
    		if (Level.NetMode != NM_Client)
    			RepSkin = m_team.podSkin;
    	}

    	muzzleFlashObserver = new class'VehicleEffectObserver'();

    	TriggerEffectEvent('Spawn');
    }

    function vector getProjectileSpawnLocation()
    {
    	return getBoneCoords(muzzleSockets[currentMuzzleIndex], true).origin;
    }

    function onShotFiredNotification()
    {
    	// cycle location
    	++currentMuzzleIndex;
    	if (currentMuzzleIndex == muzzleSockets.length)
    		currentMuzzleIndex = 0;
    }

    simulated function vector getFirstPersonEquippableLocation(Equippable subject)
    {
    	warn("not implemented");
    	return location;
    }

    simulated function rotator getFirstPersonEquippableRotation(Equippable subject)
    {
    	warn("not implemented");
    	return rotation;
    }

    simulated function vector getControlJointAttachLocation()
    {
    	return getBoneCoords('Pod').origin;
    }

    simulated function Actor getEffectsBaseActor()
    {
    	return self;
    }

    simulated function initialiseEffects()
    {
    	super.initialiseEffects();

    	addEffect('engineDust', true, engineDustEffectIndex);
    }

    simulated function bool isEffectCauserActive(int effectCauserIndex)
    {
    	local vector traceStart;
    	local vector traceEnd;

    	local vector dummy;

    	switch (effectCauserIndex)
    	{
    	case engineDustEffectIndex:

    		// trace from engine to ground
    		if (positions[driverIndex].occupant == None)
    			return false;
    		traceStart = location;
    		traceEnd = traceStart + (vect(0, 0, -1) >> Rotation) * engineDustTraceLength;

    		// The Trace simply ignores all Actors. Ideally it would only ignore Actors to do with the Pod like the occupant and the Pod
    		// itself.

    		return Trace(engineDustEffectLocation, dummy, traceEnd, traceStart, false) != None;
    	}

    	return super.isEffectCauserActive(effectCauserIndex);
    }

    simulated function updateDynamicEffectStates()
    {
    	local vector groundOffset;

    	super.updateDynamicEffectStates();

    	groundOffset.Z = engineDustGroundOffset;

    	// move engine dust effect

    	// I am assuming that the location is valid if the effect is playing.

    	if (effects[engineDustEffectIndex].observer.emitter != None && effects[engineDustEffectIndex].flag)
    		effects[engineDustEffectIndex].observer.emitter.setLocation(engineDustEffectLocation + groundOffset);
    }

    function bool aimAdjustViewRotation()
    {
    	return true;
    }

    simulated function getAlternateAimAdjustStart(rotator cameraRotation, out vector newAimAdjustStart)
    {
    	newAimAdjustStart = getCameraLookAt(cameraRotation, driverIndex);
    }

    simulated function bool customFiredEffectProcessing()
    {
    	return true;
    }

    simulated function doCustomFiredEffectProcessing()
    {
    	local int previousMuzzleIndex;
    	if (Level.NetMode != NM_DedicatedServer && muzzleFlashObserver != None)
    	{
    		TriggerEffectEvent('Fired', , , , , , , muzzleFlashObserver);

    		// update current muzzle index if we are client
    		if (Level.NetMode == NM_Client)
    		{
    			++currentMuzzleIndex;
    			if (currentMuzzleIndex == 4)
    				currentMuzzleIndex = 0;
    		}

    		previousMuzzleIndex = currentMuzzleIndex - 1;
    		if (previousMuzzleIndex == -1)
    			previousMuzzleIndex = 3;
    		if (muzzleFlashObserver.emitter != None)
    		{
    			muzzleFlashObserver.emitter.setLocation(getBoneCoords(muzzleSockets[previousMuzzleIndex], true).origin);
    			muzzleFlashObserver.emitter.bHardAttach = true;
    			muzzleFlashObserver.emitter.setBase(self);
    		}
    	}
    }

    simulated function destroyed()
    {
    	muzzleFlashObserver.cleanup();
    	muzzleFlashObserver.delete();
    	muzzleFlashObserver = None;

    	super.destroyed();
    }

    defaultproperties
    {
    	DrawType=DT_Mesh
    	Mesh=SkeletalMesh'Vehicles.Pod'

    	Health=800

    	TPCameraDistance=800

    	strafeThrustForce = 500
    	strafeForce = 250
    	forwardThrustForce = 500
    	forwardForce = 250
    	upThrustForce = 500
    	reverseForce = 150
    	reverseThrustForce = 250
    	diveThrustForce = 500

    	bDrawDriverInTP = true

    	HavokDataClass=class'PodHavokData'

    	rootBone="Pod"

    	positions(0)=(type=VP_DRIVER,hideOccupant=false,occupantControllerState=TribesPlayerDriving,thirdPersonCamera=true,lookAtInheritPitch=true,occupantAnimation=Pod_Stand,occupantConnection=character)

    	driverWeaponClass=class'PodWeapon'

    	muzzleSockets(0)=muzzle1
    	muzzleSockets(1)=muzzle2
    	muzzleSockets(2)=muzzle3
    	muzzleSockets(3)=muzzle4

    	motorClass = class'PodMotor'

    	idleAnimation = idle
    	leftAnimation = strafeLeft
    	rightAnimation = strafeRight
    	forwardAnimation = throttleForward
    	backAnimation = throttleBack
    	upAnimation = thrust
    	downAnimation = dive

    	blendTime = 0.2

    	engineDustTraceLength = 750
    	engineDustGroundOffset = 100

    	angularBankScale = 0.3
    	linearBankScale = 0.05

    	waterDamagePerSecond = 0

    	navigationTurnRate = 10000
    	throttleScale = 0.002

    	thrustThresholdPitch = 12000

    	driveYawCoefficient = 25
    	drivePitchCoefficient = 25

    	navigationMaximumPitch = 12000

    	cornerSlowDownSpeedCoefficient = 10

    	localizedName = "fighter"
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:28.000 - Creation time: st 23.5.2018 00:10:46.542 - Created with UnCodeX