Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Gameplay.RocketPodProjectile

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238

    class RocketPodProjectile extends ExplosiveProjectile;

    var		Vector	xAxis, yAxis, zAxis;	// The player's view axes

    struct InitVec
    {
    	var float X, Y, Z;
    };

    var		InitVec	initialZAxis;

    var		Vector	rotationVec;			// The vector towards which the projectile velocity needs to be rotated
    var		Vector	prevRotationVec;

    var		float	offset;					// The offset from the players view vector
    var		float	offsetVecAngle;			// The angle of the offset vector (the offset vector is the z axis of the players view
    var()	float	spiralRate				"The rate, in degrees, at which the projectiles rotate around each other"; // Converted to radians at run time

    var		bool	armed;					// Set to true after the armingPeriod has expired
    var()	float	armingPeriod			"The period after which the projectile will become armed";

    var()	float	spreadRadius			"The radius to which the projectile will spread out to after launch";
    var()	float	spreadPeriod			"The amount of time it will take the projectile the reach the spreadRadius";

    var()	float	convergeRadius			"The radius to which the projectile will converge in to after spreadRadius is reached";
    var()	float	convergePeriod			"The amount of time it will take the projectile the reach the convergeRadius";

    var()	float	postSpreadVelocity		"The velocity the projectile will accelerate to after reaching the spreadRadius";
    var()	float	postSpreadAcceleration	"The rate at which the projectile will accelerate to postSpreadVelocity";

    var()	float	maxAnglePerSecond		"Rate of turn in degrees"; // Converted to radians at run time
    var()	float	rotationModifier		"Modifier applied to the angle before rotation";

    var		float	timeCounter;

    replication
    {
    	reliable if (Role == ROLE_Authority)
    		rotationVec, initialZAxis;
    }

    simulated function PostBeginPlay()
    {
    	super.PostBeginPlay();
    	SetTimer(armingPeriod, false);
    }

    simulated function Timer()
    {
    	armed = true;
    }

    simulated function endLife(Actor HitActor, vector TouchLocation, vector TouchNormal)
    {
    	if (armed)
    	{
    		Super.endLife(HitActor, TouchLocation, TouchNormal);
    	}
    	else
    	{
    		if (!bEndedLife)
    			TriggerEffectEvent('Dud', None, None, TouchLocation, Rotator(TouchNormal));

    		bEndedLife = true;

    		Destroy();
    	}
    }

    simulated function Destroyed()
    {
    	UntriggerEffectEvent('Jet');
    	super.Destroyed();
    }

    auto state Spread
    {
    	simulated function BeginState()
    	{
    		maxAnglePerSecond = (maxAnglePerSecond / 180.0) * Pi; // convert angle from degress to radians
    		spiralRate = (spiralRate / 180.0) * Pi; // convert angle from degress to radians
    		timeCounter = 0.0;
    	}

    	simulated function spreadAlongAxis(float Delta)
    	{
    		zAxis.X = initialZAxis.X;
    		zAxis.Y = initialZAxis.Y;
    		zAxis.Z = initialZAxis.Z;

    		Move(zAxis * (Delta / spreadPeriod) * spreadRadius);
    	}

    	simulated function Tick(float Delta)
    	{
    		if (timeCounter < spreadPeriod)
    		{
    			spreadAlongAxis(Delta);
    			timeCounter += Delta;
    		}
    		else
    		{
    			offset = spreadRadius;
    			GotoState('Converge');
    		}
    	}
    }

    state Converge
    {
    	simulated function BeginState()
    	{
    		TriggerEffectEvent('Jet');
    		timeCounter = 0.0;
    	}

    	simulated function Tick(float Delta)
    	{
    		accelerateProjectile(Delta);
    		controlProjectile(Delta);

    		if (Level.NetMode != NM_Client)
    			offset -= (Delta / convergePeriod) * convergeRadius;

    		timeCounter += Delta;

    		if (timeCounter > convergePeriod)
    		{
    			// If we haven't hit terminal velocity yet continue accelerating
    			if (VSize(Velocity) < postSpreadVelocity)
    				GotoState('Accelerate');
    			else
    				GotoState('Control');
    		}
    	}
    }

    simulated function accelerateProjectile(float Delta)
    {
    	Velocity += Normal(Velocity) * (postSpreadAcceleration * Delta);
    }

    state Accelerate
    {
    	simulated function Tick(float Delta)
    	{
    		accelerateProjectile(Delta);
    		controlProjectile(Delta);

    		if (VSize(Velocity) > postSpreadVelocity)
    			GotoState('Control');
    	}
    }

    simulated function controlProjectile(float Delta)
    {
    	local Character firer;
    	local Vector projectileVec;		// Vector from the players location to the projectiles location
    	local float angle;

    	if (Level.NetMode != NM_Client)
    	{
    		if (Instigator == None)
    			return;

    		firer = Character(Instigator);

    		if (RocketPod(firer.weapon) == None)
    			return;

    		GetAxes(firer.motor.getViewRotation(), xAxis, yAxis, zAxis);

    		projectileVec = Location - firer.weapon.rookMotor.getFirstPersonEquippableLocation(firer.weapon);

    		offsetVecAngle += spiralRate * Delta;

    		if (offsetVecAngle > 2 * Pi)
    			offsetVecAngle -= 2 * Pi;

    		// The projectileVec is projected onto the xAxis and extended by the magnitude of the projectile velocity.
    		// Then we add the offset vector (which is calculated with those quat operations and scaled by the offset value).
    		// Then we subtract the projectileVec from the value to get a vector from the projectiles location to its ideal location.
    		rotationVec = ((((projectileVec Dot xAxis) + VSize(Velocity)) * xAxis) +
    			QuatRotateVector(QuatFromAxisAndAngle(xAxis, offsetVecAngle), zAxis) * offset) - projectileVec;
    	}

    	angle = ACos(FClamp(Normal(Velocity) Dot Normal(rotationVec), -1.0, 1.0));

    	if (angle > maxAnglePerSecond)
    		angle = maxAnglePerSecond;

    	Velocity = QuatRotateVector(QuatFromAxisAndAngle(Velocity Cross rotationVec, angle * Delta * rotationModifier), Velocity);

    	prevRotationVec = rotationVec;

    	SetRotation(Rotator(Velocity));
    }

    state Control
    {
    	simulated function Tick(float Delta)
    	{
    		controlProjectile(Delta);
    	}
    }

    defaultproperties
    {
    	bDeflectable = false

    	bNetNotify = true
    	bNetTemporary = false

    	damageAmt = 0
    	radiusDamageAmt = 15
    	radiusDamageSize = 50
    	radiusDamageMomentum = 10000

    	spiralRate = 120.0

    	armed = false
    	armingPeriod = 0.5

    	spreadRadius = 75.0
    	spreadPeriod = 0.5
    	convergeRadius = 25.0
    	convergePeriod = 1.5

    	postSpreadVelocity = 2000
    	postSpreadAcceleration = 500

    	maxAnglePerSecond = 90.0
    	rotationModifier = 1.0

    	StaticMesh = StaticMesh'Weapons.Rocket'
    	DrawScale3D = (X=0.5,Y=0.5,Z=0.5)
    	deathMessage = '%s copped it off %s\'s RocketPod'
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:20.000 - Creation time: st 23.5.2018 00:10:46.788 - Created with UnCodeX