Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Gameplay.VehicleSpawnPoint

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291

    class VehicleSpawnPoint extends BaseDevice
    	native;

    cppText
    {
    	virtual void PlayReplicatedAnim();
    }

    var () class<Vehicle> vehicleClass;
    var () float spawnDuration;
    var () float abandonmentDesturctionStartRadius;
    var () float abandonmentDesturctionPeriod;
    var () float spawnOffsetHeight;

    var () bool bAllowSpawnedVehicleStealing;

    var Vehicle spawnedVehicle;

    var float spawnStartTime;

    var int index;

    var vector direction;

    var float spawnAnimationLength;

    var name animationName;

    var float dummy;

    var vector spawnOffset;

    var name localAnimationName;

    var bool bTearOffAnimation;

    replication
    {
    	reliable if (Role == ROLE_Authority)
    		spawnedVehicle;
    }

    native function Vehicle spawnVehicle(vector spawnLocation, rotator spawnRotation);

    simulated function tick(float deltaSeconds)
    {
    	super.tick(deltaSeconds);

    	GetAnimParams(0, localAnimationName, dummy, dummy);
    }

    simulated function postBeginPlay()
    {
    	super.postBeginPlay();

    	spawnOffset.z = spawnOffsetHeight;
    }

    simulated function postNetBeginPlay()
    {
    	super.postNetBeginPlay();
    }

    simulated function postNetReceive()
    {
    	local name currentAnimationName;

    	super.postNetReceive();

    	// assuming between last tick and now replicated animation has been applied

    	GetAnimParams(0, currentAnimationName, dummy, dummy);

    	// check for spawn animation event
    	if (localAnimationName != currentAnimationName && currentAnimationName == 'SpawnEnd')
    		GotoState('Active', 'Spawn');

    	// check for bake animation event
    	if (localAnimationName != currentAnimationName && currentAnimationName == 'SpawnStart')
    		GotoState('Active', 'NewSpawn');
    }

    simulated event onTeamChange()
    {
    	super.onTeamChange();

    	// destroy spawned vehicle if it is not the same team and is yet to be driven
    	if (Role == ROLE_Authority && spawnedVehicle != None && !spawnedVehicle.bHasBeenOccupied && team() != spawnedVehicle.team())
    	{
    		spawnedVehicle.TakeDamage(spawnedVehicle.health + 10, self, spawnedVehicle.Location, vect(0,0,0), class'DamageType');
    	}
    }

    simulated state Active
    {

    	simulated function endState()
    	{
    		super.endState();

    		// handle case we are powering down while vehicle is spawning
    		GetAnimParams(0, animationName, dummy, dummy);
    		if (animationName == 'SpawnEnd' && IsAnimating())
    		{
    			bTearOffAnimation = false;

    			// snap to final spot
    			if (spawnedVehicle != None)
    				spawnedVehicle.move(getBoneCoords('VehicleSpawn', true).origin + spawnOffset - spawnedVehicle.Location);

    			postSpawnVehicle();
    		}
    	}

    Begin:

    	// case a client is recieving spawn point mid spawn
    	GetAnimParams(0, animationName, dummy, dummy);
    	if (animationName == 'SpawnEnd' && IsAnimating())
    		goto('Spawning');

    	// client waiting for new spawn
    	if (Role != ROLE_Authority)
    		goto('End');

    	// case of server waiting for new spawn
    	if (m_team == None || spawnedVehicle != None)
    		goto('WaitForNewSpawnEvent');

    Spawn:

    	// make sure channel 1 blending is off
    	AnimBlendParams(1, 0);

    	if (Role == ROLE_Authority)
    	{
    		PlayAnim('SpawnEnd');
    		preSpawnVehicle();
    	}

    Spawning:

    	// clients might get here even though the vehicle is not spawning
    	if (Role != ROLE_Authority && spawnedVehicle != None && !spawnedVehicle.spawning)
    		goto('End');

    	// wait for animation to finish
    	GetAnimParams(0, animationName, dummy, dummy);
    	if (animationName == 'SpawnEnd' && IsAnimating())
    	{
    		// on clients tear off this animation to avoid snapping at end
    		if (Role < ROLE_Authority)
    			bTearOffAnimation = true;

    		// manual move vehicle with vehicle bone - using a bone attachment was problematic
    		if (spawnedVehicle != None)
    			spawnedVehicle.move(getBoneCoords('Vehicle', true).origin + spawnOffset - spawnedVehicle.Location);

    		sleep(0);
    		Goto('Spawning');
    	}

    	// snap to final spot for sake of robustness
    	if (spawnedVehicle != None)
    		spawnedVehicle.move(getBoneCoords('VehicleSpawn', true).origin + spawnOffset - spawnedVehicle.Location);

    	if (Role < ROLE_Authority)
    		bTearOffAnimation = false;

    	postSpawnVehicle();

    	// clients stop now and wait for event from server in PostNetReceive
    	if (Role != ROLE_Authority)
    		goto('End');

    WaitForNewSpawnEvent:

    	// keep on waiting if we do not have a team
    	if (m_team == None)
    	{
    		sleep(0);
    		goto('WaitForNewSpawnEvent');
    	}

    	// wait for vehicle to die
    	if (spawnedVehicle == None || spawnedVehicle.health <= 0 || spawnedVehicle.bDeleteMe)
    		goto('NewSpawn');

    	// start abandonment destruction if necessary
    	if (!spawnedVehicle.abandonmentDestruction && VSize(Location - spawnedVehicle.Location) > abandonmentDesturctionStartRadius)
    		spawnedVehicle.enableAbandonmentDestruction(abandonmentDesturctionPeriod);

    	sleep(0);
    	goto('WaitForNewSpawnEvent');

    NewSpawn:

    	spawnedVehicle = None;

    	spawnStartTime = Level.TimeSeconds;

    	bTearOffAnimation = false;

    	if (Role == ROLE_Authority)
    		PlayAnim('SpawnStart');

    SpawnStarting:

    	// wait for animation to finish
    	GetAnimParams(0, animationName, dummy, dummy);
    	if (animationName == 'SpawnStart' && IsAnimating())
    	{
    		sleep(0);
    		goto('SpawnStarting');
    	}

    	// blend the posts going down
    	AnimBlendParams(1, 1);
    	PlayAnim('Spawning', GetAnimLength('Spawning') / spawnDuration, , 1);

    	while ((Level.TimeSeconds - spawnStartTime) < spawnDuration)
    		sleep(0);

    	if (Role == ROLE_Authority)
    		goto('Spawn');

    End:

    }

    // Spawns actual vehicle instance and puts vehicle in the spawn state.
    function preSpawnVehicle()
    {
    	if (vehicleClass == None)
    	{
    		warn("vehicle class is none");
    		return;
    	}

    	spawnedVehicle = spawnVehicle(getBoneCoords('Vehicle', true).origin + spawnOffset, getBoneRotation('Vehicle'));
    	spawnedVehicle.bCanBeStolen = bAllowSpawnedVehicleStealing;

    	spawnedVehicle.startedSpawnFromVehicleSpawnPoint();

    	if (spawnedVehicle == None)
    	{
    		warn("failed to spawn vehicle");
    		return;
    	}

    	if (team() == None)
    		warn("vehicle spawn point does not have a team");

    	spawnedVehicle.Label = Name(Label $ "Vehicle");
    	spawnedVehicle.setTeam(team());
    }

    // Puts spanwed vehicle in normal vehicle state.
    simulated function postSpawnVehicle()
    {
    	// getting crash in detachFromBone
    	if (spawnedVehicle != None)
    	{
    		spawnedVehicle.spawning = false;

    		spawnedVehicle.finishedSpawnFromVehicleSpawnPoint();
    	}
    }

    defaultProperties
    {
    	drawType = DT_Mesh
    	Mesh = SkeletalMesh'BaseObjects.VehicleSpawnPod'

    	spawnDuration = 10

    	abandonmentDesturctionStartRadius = 3000
    	abandonmentDesturctionPeriod = 5

    	spawnOffsetHeight = 40

    	bNetNotify = true

    	bWorldGeometry = true

    	bAllowSpawnedVehicleStealing = true

    	bReplicateAnimations = true

    	bAlwaysRelevant = true
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:24.000 - Creation time: st 23.5.2018 00:10:50.470 - Created with UnCodeX