Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Gameplay.VehicleMountedTurret

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431
00432
00433
00434
00435
00436
00437
00438
00439
00440
00441
00442
00443
00444
00445
00446
00447
00448
00449
00450
00451
00452
00453
00454
00455
00456
00457
00458
00459
00460
00461
00462
00463
00464
00465
00466
00467
00468
00469
00470
00471
00472
00473
00474
00475
00476
00477
00478
00479
00480
00481
00482
00483
00484
00485
00486
00487
00488
00489
00490
00491
00492
00493
00494
00495
00496
00497
00498
00499
00500
00501
00502
00503
00504
00505
00506

    // VehicleMountedTurret
    //
    // The gameplay aspect of a turret mounted on a vehicle. Visual aspect is handled by actual weapon.
    // Has an initialise function that must be called after spawning. The
    // rationale for the existence of this behaviour is that specific sub classes of this class are not created
    // therefore specific data must be pushed down into instances of this class.

    class VehicleMountedTurret extends Rook implements IFiringMotor
    	dependsOn(PlayerCharacterController)
    	native;

    cpptext
    {
    	virtual UBOOL Tick(FLOAT deltaSeconds, ELevelTick TickType);
    	virtual void tickAI( FLOAT DeltaSeconds );
    	virtual FVector GetViewPoint();
    	virtual UBOOL shouldLookForPawns();
    	virtual UBOOL IsNetRelevantFor(APlayerController* RealViewer, AActor* Viewer, FVector SrcLocation);
    	virtual UBOOL canBeSeenBy(APawn* pawn) {return Controller && Controller->bIsPlayer;};	// AI's only see player controlled turrets
    }

    var name pivotBone;
    var name pitchPivotBone;

    var protected Vehicle.VehiclePositionType positionType;
    var private Vehicle.VehiclePositionType localPositionType;

    // initialise in PostBeginPlay
    var int positionIndex;

    var vehicle ownerVehicle;

    var Weapon weapon;

    var float maximumPitch;
    var float minimumPitch;

    var float yawStart;
    var float yawRange;
    var bool yawConstrained;
    var bool yawPositiveDirection;

    var rotator worldSpaceNoRollRotation;
    var rotator vehicleSpaceRotation;
    var rotator vehicleSpaceClientDisplayRotation;

    var rotator turretOffsetRotation;
    var name turretBone;

    var float maximumClientDisplayTurnRate;

    var rotator vehicleSpaceRotationAI;
    var float maximumAITurnRate;

    // The specific way turrets rotate in third person is slightly different dependent on bone rotations. This property specified which
    // specific method to use. This is rather nasty. Perhaps it would be better to standardise bone rotations.
    var int thirdPersonRotationType;

    var Vector cachedCameraLocation;

    replication
    {
    	// This could be optimised by having the appropriate values for each vehicle mounted turret type stored in a class that is simply
    	// passed down. The VehicleMountedTurret can then simply access the default values.

    	reliable if (Role == ROLE_Authority)
    		ownerVehicle, clientOccupantEnter, maximumPitch, minimumPitch, weapon, positionType, yawConstrained, yawStart, yawRange,
    				yawPositiveDirection, turretOffsetRotation, turretBone, maximumClientDisplayTurnRate;

    	reliable if (Role == ROLE_Authority && !bNetOwner)
    		vehicleSpaceRotation;
    }

    simulated function setPositionType(Vehicle.VehiclePositionType newPositionType)
    {
    	positionType = newPositionType;
    	positionIndex = ownerVehicle.getPositionIndex(positionType);
    }

    simulated function IFiringMotor firingMotor()
    {
    	return self;
    }

    // Returns the character (if it exists) that is controlling this rook (i.e. turret or vehicle)
    simulated function Character getControllingCharacter()
    {
    	if (positionIndex < 0)
    		return None;
    	else
    		return ownerVehicle.positions[positionIndex].occupant;
    }

    simulated function Character getDriver()
    {
    	if (positionIndex < 0)
    		return None;
    	else
    		return ownerVehicle.positions[positionIndex].occupant;
    }

    simulated function faceRotation(rotator newRotation, float deltaTime)
    {
    	// ignored
    }

    simulated function clientOccupantEnter(PlayerController pc, Character newDriver, int positionIndex)
    {
    	local Vehicle.ClientOccupantEnterData data;

    	// forward to vehicle
    	data.controller = pc;
    	data.positionIndex = positionIndex;
    	data.occupant = newDriver;
    	ownerVehicle.clientOccupantEnter(data);
    }

    simulated function postNetBeginPlay()
    {
    	super.postNetBeginPlay();

    	localPositionType = positionType;

    	if (Vehicle(owner) != None)
    	{
    		ownerVehicle = Vehicle(owner);
    		if (positionType != VP_NULL)
    			positionIndex = ownerVehicle.getPositionIndex(positionType);
    	}
    }

    simulated function postNetReceive()
    {
    	super.postNetReceive();

    	// update owner vehicle
    	if (Vehicle(owner) != None)
    	{
    		ownerVehicle = Vehicle(owner);
    		if (positionType != VP_NULL)
    			positionIndex = ownerVehicle.getPositionIndex(positionType);
    	}

    	// handle position type updates
    	if (ownerVehicle != None && localPositionType != positionType)
    	{
    		if (positionType != VP_NULL)
    			positionIndex = ownerVehicle.getPositionIndex(positionType);
    		localPositionType = positionType;
    	}
    }

    function updateParams(float inMaximumPitch, float inMinimumPitch, float inYawStart, float inYawRange)
    {
    	maximumPitch = inMaximumPitch;
    	minimumPitch = inMinimumPitch;

    	yawStart = inYawStart;
    	if (yawStart < 0)
    		yawStart += 65536;
    	yawRange = inYawRange;
    }

    function initialise(class<Weapon> turretWeaponClass, name inTurretBone, float inMaximumPitch, float inMinimumPitch, bool inYawConstrained,
    		float inYawStart, float inYawRange, bool inYawPositiveDirection, float inMaximumClientDisplayTurnRate, float inMaximumAITurnRate)
    {
    	local coords turretOffsetCoords;

    	turretBone = inTurretBone;

    	maximumPitch = inMaximumPitch;
    	minimumPitch = inMinimumPitch;

    	yawConstrained = inYawConstrained;
    	yawStart = inYawStart;
    	if (yawStart < 0)
    		yawStart += 65536;
    	yawRange = inYawRange;
    	yawPositiveDirection = inYawPositiveDirection;

    	// initialise weapon
    	weapon = spawn(turretWeaponClass, self, , location);
    	weapon.setOwner(self);
    	weapon.equip();

    	turretOffsetCoords = ownerVehicle.getBoneCoords(turretBone, true);
    	turretOffsetRotation = orthoRotation(turretOffsetCoords.XAxis, turretOffsetCoords.YAxis, turretOffsetCoords.ZAxis);
    	turretOffsetRotation = turretOffsetRotation - ownerVehicle.Rotation;

    	vehicleSpaceRotation = turretOffsetRotation;

    	maximumClientDisplayTurnRate = inMaximumClientDisplayTurnRate;

    	maximumAITurnRate = inMaximumAITurnRate;
    }

    simulated function tick(float deltaSeconds)
    {
    	super.tick(deltaSeconds);

    	// update vehicle display rotation
    	if (Level.NetMode == NM_Client)
    	{
    		vehicleSpaceClientDisplayRotation = class'Vehicle'.static.interpolateRotation(vehicleSpaceClientDisplayRotation,
    				vehicleSpaceRotation, maximumClientDisplayTurnRate, deltaSeconds);
    	}

    	// update AI rotation
    	if (controller != None && !controller.bIsPlayer)
    	{
    		vehicleSpaceRotationAI = class'Vehicle'.static.interpolateRotation(vehicleSpaceRotationAI, vehicleSpaceRotation, maximumAITurnRate,
    				deltaSeconds);
    	}

    	// stop firing if no occupant
    	if (weapon != None && weapon.IsInState('FirePressed') && Controller == None)
    		weapon.releaseFire();

    	// make sure owner vehicle is up to date
    	if (ownerVehicle == None && Vehicle(owner) != None)
    		ownerVehicle = Vehicle(owner);

    	// make sure position index is up to date
    	if (positionIndex < 0 && positionType != VP_NULL && ownerVehicle != None)
    		positionIndex = ownerVehicle.getPositionIndex(positionType);
    }

    function useEnergy(float amount)
    {

    }

    function float getEnergy()
    {
    	return 1000;
    }

    function processMove(rotator worldSpaceNoRollRotation_, rotator vehicleSpaceRotation_)
    {
    	worldSpaceNoRollRotation = worldSpaceNoRollRotation_;
    	vehicleSpaceRotation = vehicleSpaceRotation_;
    }

    // Forwards call to owner vehicle.
    function getOut()
    {
    	if (ownerVehicle == None)
    	{
    		warn("owner vehicle is none");
    		return;
    	}

    	ownerVehicle.getOut(positionType);
    }

    // Forwards call to owner vehicle.
    simulated function bool specialCalcView(out actor ViewActor, out vector CameraLocation, out rotator CameraRotation )
    {
    	// for sake of robustness set a reasonable camera location
    	CameraLocation = Location;

    	if (ownerVehicle == None)
    		return false;

    	if (positionIndex < 0)
    		return false;

    	if (controller == None)
    		return false;

    	ViewActor = controller;

    	// camera position is locked to vehicle
    	CameraLocation = ownerVehicle.getBoneCoords(turretBone, true).origin +
    			(ownerVehicle.positions[positionIndex].firstPersonCameraLocation >> worldSpaceNoRollRotation);

    	// puts each element between +/- 32767
    	Normalize(CameraRotation);

    	// don't draw the driver
    	ownerVehicle.positions[positionIndex].occupant.bOwnerNoSee = true;

    	cachedCameraLocation = CameraLocation;

    	return true;
    }

    simulated function vector EyePosition()
    {
    	return cachedCameraLocation - Location;
    }

    function turretFire()
    {
    	if (weapon == None)
    		return;

    	fire(false);
    }

    function turretCeaseFire()
    {
    	if (weapon == None)
    		return;

    	releaseFire();
    }

    function fire(optional bool fireOnce)
    {
    	weapon.fire(fireOnce);
    }

    function altFire(optional bool fireOnce)
    {

    }

    function releaseFire()
    {
    	weapon.releaseFire();
    }

    function releaseAltFire()
    {

    }

    function bool shouldFire(Equippable e)
    {
    	return false;
    }

    function setFirePressed(Equippable e, bool pressed)
    {
    }

    function vector getProjectileSpawnLocation()
    {
    	return ownerVehicle.getBoneCoords(turretBone, true).origin + (ownerVehicle.positions[positionIndex].firstPersonWeaponLocation >>
    			worldSpaceNoRollRotation) + (weapon.projectileSpawnOffset >> worldSpaceNoRollRotation);
    }

    function setViewRotation(Rotator r)
    {
    	local PlayerCharacterController.DynamicTurretRotationProcessingOutput output;
    	output = class'PlayerCharacterController'.static.dynamicTurretRotationProcessing(r, ownerVehicle.Rotation, minimumPitch,
    			maximumPitch, yawConstrained, yawPositiveDirection, yawStart, yawRange);

    	worldSpaceNoRollRotation = output.worldSpaceNoRollRotation;
    	vehicleSpaceRotation = output.vehicleSpaceRotation;
    }

    simulated function Rotator getDefaultOccupantRotation()
    {
    	return QuatToRotator(QuatProduct(QuatFromRotator(vehicleSpaceRotation), QuatFromRotator(ownerVehicle.rotation)));
    }

    function Rotator getViewRotation()
    {
    	// AI case
    	if (controller != None && !controller.bIsPlayer)
    		return QuatToRotator(QuatProduct(QuatFromRotator(vehicleSpaceRotationAI), QuatFromRotator(ownerVehicle.rotation)));

    	return worldSpaceNoRollRotation;
    }

    function onShotFiredNotification()
    {
    	// ignore
    }

    simulated function vector getFirstPersonEquippableLocation(Equippable subject)
    {
    	return ownerVehicle.getBoneCoords(turretBone, true).origin + (ownerVehicle.positions[positionIndex].firstPersonWeaponLocation >>
    			worldSpaceNoRollRotation);
    }

    simulated function rotator getFirstPersonEquippableRotation(Equippable subject)
    {
    	return worldSpaceNoRollRotation;
    }

    simulated function getThirdPersonEquippableAttachment(Equippable subject, out Rook attachTo, out name boneName)
    {
    	attachTo = ownerVehicle;
    	boneName = 'turret';
    }

    function bool aimAdjustViewRotation()
    {
    	return true;
    }

    function Rook getPhysicalAttachment()
    {
    	return ownerVehicle;
    }

    function Weapon getWeapon()
    {
    	return weapon;
    }

    // returns true if the turret can sight the location given its view constraints
    function bool canTargetPoint(Vector targetLoc)
    {
    	return true;
    }

    function destroyed()
    {
    	super.destroyed();

    	weapon.destroy();
    }

    simulated function Actor getEffectsBaseActor()
    {
    	return None;
    }

    simulated function bool customFiredEffectProcessing()
    {
    	return false;
    }

    simulated function doCustomFiredEffectProcessing()
    {
    	assert(false);
    }

    simulated function Name getKillerLabel()
    {
    	if (ownerVehicle != None)
    		return ownerVehicle.label;

    	return super.getKillerLabel();
    }

    simulated function getAlternateAimAdjustStart(rotator cameraRotation, out vector newAimAdjustStart);

    simulated function DisplayDebug(Canvas Canvas, out float YL, out float YPos)
    {
    	Super.DisplayDebug(Canvas, YL, YPos);

    	Canvas.SetDrawColor(0,255,0);

    	Canvas.SetPos(4,YPos);

    	// owner vehicle
    	Canvas.DrawText("Owner Vehicle:" @ ownerVehicle);
    	YPos += YL;
    	Canvas.SetPos(4,YPos);

    	// position type and index
    	Canvas.DrawText("Position Type:" @ positionType $ ", Position Index:" @ positionIndex);
    	YPos += YL;
    	Canvas.SetPos(4,YPos);
    }

    defaultProperties
    {
    	DrawType = DT_None
    	RemoteRole = ROLE_SimulatedProxy
    	bHardAttach = true
    	bHidden = false
    	bCollideActors = false
    	bStatic = false
    	CollisionRadius = +0080.000000
    	CollisionHeight = +0400.000000
    	bCollideWhenPlacing = false
    	bOnlyAffectPawns = true
    	Physics = PHYS_None
    	bShouldBaseAtStartup = false
    	bNetInitialRotation = true
    	bSpecialCalcView = true
    	bBlockPlayers = false
    	bBlockActors = false
    	bCollideWorld = false
    	bRotateToDesired = false
    	bNetNotify = true
    	positionIndex = -1
    	bStasis = false

    	bAlwaysRelevant = false

    	bReplicateMovement = true

    	playerControllerState = "PlayerVehicleTurreting"

    	AI_LOD_Level = AILOD_MINIMAL
    	peripheralVision = -1				// 360 degree vision
    	peripheralVisionZAngle = 3.14159	// 180 degrees up/down

    	maximumClientDisplayTurnRate = 8000

    	maximumAITurnRate = 12000

    	bBlockHavok = false

    	bCanBeSensed = false

    	positionType = VP_NULL
    	localPositionType = VP_NULL
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:28.000 - Creation time: st 23.5.2018 00:10:50.452 - Created with UnCodeX