Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Tyrion.NS_Turn

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121

    //=====================================================================
    // NS_Turn
    //
    // Turns to a specified facing
    //=====================================================================

    class NS_Turn extends NS_Action;

    //=====================================================================
    // Constants

    const TURN_INCREMENT = 4096;

    enum TurnDirections
    {
    	TD_DONT_CARE,		// turns in direction that takes less time
    	TD_CLOCKWISE,
    	TD_COUNTERCLOCKWISE
    };

    //=====================================================================
    // Variables

    var Rotator facing;
    var TurnDirections turnDirection;

    var Character character;
    var Rotator r;

    //=====================================================================
    // Functions

    //---------------------------------------------------------------------

    static function NS_Turn startAction(AI_Controller c, ActionBase parent, Rotator facing,
    									optional TurnDirections turnDirection)
    {
    	local NS_Turn action;

    	// create new object
    	// (in the future, we may want to allow for actions that don't create a
    	// new action, and pay for that by having their child not be interruptable)
    	action = new(c.level.Outer) class'NS_Turn'( c, parent );

    	// set action parameters
    	action.facing = facing;
    	action.turnDirection = turnDirection;

    	action.runAction();
    	return action;
    }

    //---------------------------------------------------------------------
    // Turn the character to "r" and wait for the turn to complete

    latent function turn( Rotator r )
    {
    	character.motor.setViewRotation( r );
    	character.motor.setAIMoveRotation( r );

    	// wait for turn to complete
    	while ( Abs(character.motor.getMoveYawDelta()) > 100 && class'Pawn'.static.checkAlive( character ) )
    		yield();
    }

    //---------------------------------------------------------------------
    // determine the yaw increment for this character if it should turn in
    // a specific direction, limited by TURN_INCREMENT

    function int getIncrement()
    {
    	local int delta;

    	delta = facing.Yaw - r.Yaw;

    	if ( delta < 0 )
    		delta += 65536;

    	if ( turnDirection == TD_CLOCKWISE )
    		delta = min(delta,TURN_INCREMENT);
    	else
    		delta = max(delta-65536,-TURN_INCREMENT);

    	return delta;
    }

    //=====================================================================
    // States

    state Running
    {
    Begin:
    	character = Character(controller.Pawn);

    	if ( character.logNavigationSystem )
    		log( name @ "(" @ controller.Pawn.name @ ") started turning" );

    	if ( turnDirection != TD_DONT_CARE )
    	{
    		r = character.motor.getMoveRotation();

    		if ( character.logNavigationSystem )
    			log( name @ "turning from" @ r.Yaw @ "to" @ facing.Yaw );

    		while ( facing.Yaw != r.Yaw && class'Pawn'.static.checkAlive( character ) )
    		{
    			//log( "Increment:" @ getIncrement() @ facing.Yaw @ r.Yaw );
    			r.Yaw = ( r.Yaw + getIncrement() ) & 65535;
    			turn( r );
    		}
    	}
    	else
    	{
    		turn( facing );
    	}

    	if ( class'Pawn'.static.checkDead( character ) )
    		fail( ACT_ALL_RESOURCES_DIED );
    	else
    		succeed();
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:54:28.000 - Creation time: st 23.5.2018 00:10:46.202 - Created with UnCodeX