Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Gameplay.GameInfo

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431
00432
00433
00434
00435
00436
00437
00438
00439
00440
00441
00442
00443
00444
00445
00446
00447
00448
00449
00450
00451
00452
00453
00454
00455
00456
00457
00458
00459
00460
00461
00462
00463
00464
00465
00466
00467
00468
00469
00470
00471
00472
00473
00474
00475
00476
00477
00478
00479
00480
00481
00482
00483
00484
00485
00486
00487
00488
00489
00490
00491
00492
00493
00494
00495
00496
00497
00498
00499
00500
00501
00502
00503
00504
00505
00506
00507
00508
00509
00510
00511
00512
00513
00514
00515
00516
00517
00518
00519
00520
00521
00522
00523
00524
00525
00526
00527
00528
00529
00530
00531
00532
00533
00534
00535
00536
00537
00538
00539
00540
00541
00542
00543
00544
00545
00546
00547
00548
00549
00550
00551
00552
00553
00554
00555
00556
00557
00558
00559
00560
00561
00562
00563
00564
00565
00566
00567
00568
00569
00570
00571
00572
00573
00574
00575
00576
00577
00578
00579
00580
00581
00582
00583
00584
00585
00586
00587
00588
00589
00590
00591
00592
00593
00594
00595
00596
00597
00598
00599
00600
00601
00602
00603
00604
00605
00606
00607
00608
00609
00610
00611
00612
00613
00614
00615
00616
00617
00618
00619
00620
00621
00622
00623
00624
00625
00626
00627
00628
00629
00630
00631
00632
00633
00634
00635
00636
00637
00638
00639
00640
00641
00642
00643
00644

    class GameInfo extends Engine.GameInfo;

    //-----------------------------------------------------------------------------
    // Variables.

    var class<CheatManager>		CheatClass;					// class of CheatManager for player controllers

    var transient private int	secondsPassed;				// TEMP fix for player start happening way before the first frame
    var transient private bool	msgSent;					// TEMP fix for player start happening way before the first frame

    // Variables that can be configured by the game operator
    var() globalconfig float playerTeamDamagePercentage					"Members of the same team can damage each other's health down to this percentage (0 to disable).  Server configurable.";
    var() globalconfig float baseDeviceTeamDamagePercentage				"Members of the same team can damage their base objects' health down to this percentage (0 to disable).  Server configurable.";

    var() class<InventoryStationAccess> inventoryStationAccessClass "Optional inventory station used by this game type for non-physical inventory selection.  Can be overriden in roundDatas.";

    var() float equipmentLifeTime;

    var	LatticeInfo	lattice;

    function PostBeginPlay()
    {
    	local Actor a;
    	local LatticeInfo l;
    	local TeamInfo t;
    	local BaseInfo b;
    	local BoundaryVolume bv;

    	Label = 'GameInfo';

    	Super.PostBeginPlay();

    	// filter objects that were loaded
    	ForEach DynamicActors(class'Actor', a)
    	{
    		// Don't delete BoundaryVolumes
    		if (!allowObjectAtLoad(a) && !a.isA('BoundaryVolume'))
    		{
    			//Log("Filtering "$a);
    			a.Destroy();
    		}
    	}

    	// instruct reamining TeamInfos to evaluate remaining playerStarts
    	ForEach AllActors(class'TeamInfo', t)
    	{
    		t.evaluatePlayerStarts();
    	}

    	// initialize baseInfos
    	ForEach AllActors(class'BaseInfo', b)
    	{
    		b.Initialize();
    	}

    	// load skin packages if required
    	if (allowSkinChanges())
    	{
    		class'SkinInfo'.static.loadAllSkins(Level);
    	}

    	// See if there's a lattice
    	ForEach AllActors(class'LatticeInfo', l)
    	{
    		// Assume there's only one
    		lattice = l;
    		break;
    	}

    	// send a message that the level has started
    	dispatchMessage(new class'MessageLevelStart');

    	// initialise the game boundary volume
    	ForEach AllActors(class'BoundaryVolume', bv)
    	{
    		// assume there's only one
    		if (bv.Active)
    		{
    			BoundaryVolume = bv;
    			break;
    		}
    	}
    }

    function PostLoadGame()
    {
    	super.PostLoadGame();
    	dispatchMessage(new class'MessageGameLoaded');
    }

    //
    // Log a player in.
    // Fails login if you set the Error string.
    // PreLogin is called before Login, but significant game time may pass before
    // Login is called, especially if content is downloaded.
    //
    event PlayerController Login
    (
    	string Portal,
    	string Options,
    	out string Error
    )
    {
    	local Actor						StartSpot;
    	local PlayerController			NewPlayer;
        local string					InName, InAdminName, InPassword, InChecksum, InClass, InCharacter;
    	local string					controllerName;
        local bool						bSpectator, bAdmin;
    	local class<PlayerController>	PlayerControllerClass;	// type of player controller to spawn for players logging in
    	local class<Security>			MySecurityClass;
    	local Vector					controllerStartLoc;
    	local Rotator					controllerStartRot;

    	InName     = Left(DecodeFromURL(ParseOption ( Options, "Name")), 20);

        bSpectator = ( ParseOption( Options, "SpectatorOnly" ) ~= "true" );

        bAdmin = AccessControl.CheckOptionsAdmin(Options);

        // Make sure there is capacity except for admins. (This might have changed since the PreLogin call).
        if ( !bAdmin && AtCapacity(bSpectator) )
    	{
    		Error=GameMessageClass.Default.MaxedOutMessage;
    		return None;
    	}

    	// If admin, force spectate mode if the server already full of reg. players
    	if ( bAdmin && AtCapacity(false))
    		bSpectator = true;

    	BaseMutator.ModifyLogin(Portal, Options);

    	// Get URL options.
        InAdminName= ParseOption ( Options, "AdminName");
    	InPassword = ParseOption ( Options, "Password" );
    	InChecksum = ParseOption ( Options, "Checksum" );

    	log( "Login:" @ InName );
    	if( InPassword != "" )
    		log( "Password"@InPassword );

    	// Find a start spot.
    	StartSpot = tribesFindPlayerStart( None, initialTeam());

    	if( StartSpot != None )
    	{
    		if ( SinglePlayerStart(StartSpot)!=None)
    			controllerName = SinglePlayerStart(StartSpot).PlayerControllerClassName;

    		controllerStartLoc = StartSpot.Location;
    		controllerStartRot = StartSpot.Rotation;
    	}
    	else
    	{
    		LOG("GameInfo::Login: Warning, no start spot could be found");
    	}

    	if ( controllerName == "" )
    		controllerName = PlayerControllerClassName;

    	if ( PlayerControllerClass == None )
    		PlayerControllerClass = class<PlayerController>(DynamicLoadObject(controllerName, class'Class'));

    	NewPlayer = spawn(PlayerControllerClass,,,controllerStartLoc,controllerStartRot);

    	// Handle controller spawn failure.
    	if( NewPlayer == None )
    	{
    		log("Couldn't spawn player controller of class "$PlayerControllerClass);
    		Error = GameMessageClass.Default.FailedSpawnMessage;
    		return None;
    	}

        // Init player's replication info
        NewPlayer.GameReplicationInfo = GameReplicationInfo;

    	// Apply security to this controller

    	MySecurityClass=class<Security>(DynamicLoadObject(SecurityClass,class'class'));
    	NewPlayer.PlayerSecurity = spawn(MySecurityClass, self);
    	if (NewPlayer.PlayerSecurity==None)
    	{
    		log("Could not spawn security for player "$NewPlayer,'Security');
    	}

    	//NewPlayer.GotoState('AttractMode');

    	// Init player's name
    	if( InName=="" )
    		InName=DefaultPlayerName;
    	if( Level.NetMode!=NM_Standalone || NewPlayer.PlayerReplicationInfo.PlayerName==DefaultPlayerName )
    		ChangeName( NewPlayer, InName, false );

    	// Init the players gender
    	NewPlayer.PlayerReplicationInfo.bIsFemale = (ParseOption(Options, "IsFemale") ~= "true");

    	// Init players voice set
    	if(TribesReplicationInfo(NewPlayer.PlayerReplicationInfo) != None)
    	{
    		TribesReplicationInfo(NewPlayer.PlayerReplicationInfo).VoiceSetPackageName = (ParseOption(Options, "VoiceSet"));
    		if(TribesReplicationInfo(NewPlayer.PlayerReplicationInfo).VoiceSetPackageName == "")
    			TribesReplicationInfo(NewPlayer.PlayerReplicationInfo).VoiceSetPackageName = "QuickChatAlbrecht";
    	}

        if ( bSpectator || NewPlayer.PlayerReplicationInfo.bOnlySpectator )
    	{
            NewPlayer.PlayerReplicationInfo.bOnlySpectator = true;
    		NewPlayer.PlayerReplicationInfo.bIsSpectator = true;
    		NumSpectators++;
    		return NewPlayer;
    	}

        // Init player's administrative privileges and log it
        if (AccessControl.AdminLogin(NewPlayer, InAdminName, InPassword))
        {
    		AccessControl.AdminEntered(NewPlayer, InAdminName);
        }

    	// Set the player's ID.
    	NewPlayer.PlayerReplicationInfo.PlayerID = CurrentID++;

    	// Get default pawn class from start point, if available
    	if ( PlayerStart(StartSpot)!=None)
    		InClass = PlayerStart(StartSpot).defaultPawnClassName();

    	// Else get default pawn class from command line
    	// Commented out, not needed for our game
    /*	if ( InClass == "" )
    	InClass = ParseOption( Options, "Class" );*/

    	// Else use DefaultPlayerClassName field
        if (InClass == "")
            InClass = DefaultPlayerClassName;
        InCharacter = ParseOption(Options, "Character");
        NewPlayer.SetPawnClass(InClass, InCharacter);

    	NumPlayers++;
        bWelcomePending = true;

    	// if delayed start, don't give a pawn to the player yet
    	// Normal for multiplayer games
    	if ( bDelayedStart )
    	{
    		NewPlayer.GotoState('PlayerWaiting');
    		return NewPlayer;
    	}

    	return NewPlayer;
    }

    // Called after a successful login. This is the first place
    // it is safe to call replicated functions on the PlayerPawn.
    //
    event PostLogin( PlayerController NewPlayer )
    {
    	Super.PostLogin(NewPlayer);

    	PlayerCharacterController(NewPlayer).clientSetCheats(cheatClass);

    	// tell client to load skin classes if it is allowed
    	if(allowSkinChanges())
    		PlayerCharacterController(NewPlayer).clientLoadSkinClasses();

    	// Dispatch a connect event
    	NewPlayer.dispatchMessage(new class'MessageClientConnected'(PlayerCharacterController(NewPlayer)) );
    }

    function Logout( Controller Exiting )
    {
    	local PlayerCharacterController pcc;

    	pcc = PlayerCharacterController(Exiting);

    	if (pcc != None)
    	{
    		// Dispatch a disconnect event
    		Exiting.dispatchMessage(new class'MessageClientDisconnected'(pcc));

    		pcc.playerDisconnected();
    	}

    	Super.Logout(Exiting);
    }

    // Moved functionality from RestartPlayer to here, to allow parameterised modification of respawn behaviour
    private function respawn( Controller aPlayer, bool bCreateNewPawn )
    {
    	local PlayerStart startSpot;
    	local int spawnTries;
    	local Character playerChar;
    	local TribesReplicationInfo TRI;
    	local Vector teleportLoc;

    	if( bRestartLevel && Level.NetMode!=NM_DedicatedServer && Level.NetMode!=NM_ListenServer || aPlayer==None)
    		return;

    	if (aPlayer.Pawn!=None && bCreateNewPawn)
    	{
    	    //log("destroy pawn: "$aPlayer.Pawn);

    	    // destroy pawn
    		aPlayer.Pawn.Destroy();
    		aPlayer.Pawn = None;
        }

        if (aPlayer.PawnClass!=None)
        {
    		if (aPlayer.PlayerReplicationInfo != None)
    			TRI = TribesReplicationInfo(aPlayer.PlayerReplicationInfo);

    	    while (spawnTries<5)
    	    {
    			// If the player has a team already, start him on that team
    			if (TRI != None)
    			    startSpot = tribesFindPlayerStart(aPlayer, TRI.team);
    			else
    			// Otherwise try to start him without a team (needed for single player)
    				startSpot = tribesFindPlayerStart(aPlayer, None);

    		    aPlayer.StartSpot = StartSpot;

    		    if (startSpot != None)
    		    {
    			    if (aPlayer.PreviousPawnClass!=None && aPlayer.PawnClass != aPlayer.PreviousPawnClass)
    				    BaseMutator.PlayerChangedClass(aPlayer);

    				// bCreateNewPawn support
    				if (aPlayer.Pawn == None)
    				{
    					aPlayer.Pawn = Spawn(aPlayer.PawnClass,,,StartSpot.Location,StartSpot.Rotation);

    					if (aPlayer.Pawn != None)
    						break;
    				}
    				else
    				{
    					teleportLoc = StartSpot.Location;
    					teleportLoc.Z += aPlayer.Pawn.CollisionHeight;
    					if (Character(aPlayer.Pawn) == None)
    					{
    						aPlayer.Pawn.unifiedSetPosition(teleportLoc);
    						aPlayer.Pawn.SetRotation(StartSpot.Rotation);
    					}
    					else
    						Character(aPlayer.Pawn).teleportTo(teleportLoc, StartSpot.Rotation);

    					if (aPlayer.Pawn.Location != teleportLoc)
    						LOG("Couldn't move player to start spot"@teleportLoc);
    					else
    						break;
    				}
    		    }

    		    spawnTries++;
    	    }

    	    if (startSpot == None || aPlayer.Pawn == None)
    	    {
    		    log("Tried 5 times, couldn't spawn player of type "$aPlayer.PawnClass);
    		    //log("why you ask? because... startSpot="$startSpot$", aPlayer.Pawn="$aPlayer.Pawn);
    		    return;
    	    }
    	}
    	else
    		Log("Warning:  respawn() called on a player that has no pawnClass");

        if (aPlayer.Pawn!=None)
        {
    	    aPlayer.Pawn.label = 'Player';

    	    if (Level.NetMode != NM_Standalone)
    		    aPlayer.Pawn.label = aPlayer.Pawn.Name;

    	    aPlayer.Pawn.LastStartSpot = startSpot;
    	    aPlayer.Pawn.LastStartTime = Level.TimeSeconds;
    	    aPlayer.PreviousPawnClass = aPlayer.Pawn.Class;

    	    aPlayer.Possess(aPlayer.Pawn);
    	    aPlayer.PawnClass = aPlayer.Pawn.Class;

    		// Need to assign the player's team based on TRI
    		playerChar = Character(aPlayer.Pawn);
    		if (TRI.team != None)
    		{
    		    playerChar.setTeam(TRI.team);
    		}

            aPlayer.Pawn.PlayTeleportEffect(true, true);
    	    aPlayer.ClientSetRotation(aPlayer.Pawn.Rotation);
    	    AddDefaultInventory(aPlayer.Pawn);
    	    TriggerEvent( StartSpot.Event, StartSpot, aPlayer.Pawn);

    	    if (startSpot != None && startSpot.invincibleDelay > 0.0 && Character(aPlayer.Pawn) != None)
    	    {
    			aPlayer.Pawn.TriggerEffectEvent('Invincible');
    		    Character(aPlayer.Pawn).bTempInvincible = true;
    		    aPlayer.Pawn.SetTimer(startSpot.invincibleDelay, false);
    	    }

    	    // send a message that the player has started
    	    dispatchMessage(new class'MessagePlayerStart');
    	}
    }

    // Restarts the player while keeping his pawn
    function respawnKeepPawn( Controller aPlayer )
    {
    	respawn(aPlayer, false);
    }

    //
    // Restart a player, call this when you want the player to respawn or start the game
    //
    function RestartPlayer( Controller aPlayer )
    {
    	respawn(aPlayer, true);
    }

    event Timer()  // TEMP fix for player start happening way before the first frame
    {
    	Super.Timer();

    	if (secondsPassed < 10)
    	{
    		++secondsPassed;
    	}
    	else
    	{
    		if (!msgSent)
    		{
    			dispatchMessage(new class'MessagePlayerStartDelayed');
    			msgSent = true;
    		}
    	}
    }

    // initialTeam
    function TeamInfo initialTeam()
    {
    	local TeamInfo t;

    	ForEach DynamicActors(class'TeamInfo', t)
    		return t;

    	return None;
    }

    function int numTeams()
    {
    	local int teamCount;
    	local TeamInfo ti;

    	teamCount = 0;
    	foreach DynamicActors(class'TeamInfo', ti)
    		teamCount += 1;

    	return teamCount;
    }

    function TeamInfo GetTeamFromIndex(int index)
    {
    	local int i;
    	local TeamInfo ti;

    	i = 0;
    	foreach DynamicActors(class'TeamInfo', ti)
    	{
    		if (i == index)
    			return ti;

    		++i;
    	}

    	return None;

    }

    function String GetPlayerNamesList()
    {
    	local String playerNamesList;
    	local TribesReplicationInfo tri;

    	foreach DynamicActors(class'TribesReplicationInfo', tri)
    		playerNamesList $= tri.getTeamAffiliatedName();

    	return playerNamesList;

    }

    function String GetGameSpyGameMode()
    {
    	return "exiting";
    }

    // tryRespawn
    // called when a player requests to be respawned
    function bool tryRespawn(PlayerCharacterController c)
    {
    	RestartPlayer(c);
    	return true;
    }

    // onDeath
    // called when character that a controller is viewing dies
    function onDeath(PlayerCharacterController c)
    {
    }

    // allowObjectAtLoad
    function bool allowObjectAtLoad(Actor a)
    {
    	local int i;

    	// Check for inclusion list first, which overrides any exclusions
    	for (i=0; i<a.gameInfoInclusions.Length; i++)
    	{
    		if (IsA(a.gameInfoInclusions[i].name))
    			return true;
    	}

    	// Check for strict exclusivity
    	if (a.exclusiveToGameInfo != None)
    		return IsA(a.exclusiveToGameInfo.name);

    	// Check for exclusion list
    	for (i=0; i<a.gameInfoExclusions.Length; i++)
    	{
    		if (a.gameInfoExclusions[i] == None)
    			continue;

    		if (IsA(a.gameInfoExclusions[i].name))
    			return false;
    	}

    	return true;
    }

    function bool allowSkinChanges()
    {
    	return true;
    }

    // return false to disable manual respawn with the 'b' key, base implementation returns true
    function bool allowManualRespawn()
    {
    	return Mutator(BaseMutator).MutateManualRespawn();
    }

    // tribesRatePlayerStart
    function float tribesRatePlayerStart(PlayerStart P, TeamInfo Team, Controller Player)
    {
    	return 1;
    }

    // tribesFindPlayerStart
    function PlayerStart tribesFindPlayerStart( Controller Player, TeamInfo InTeam )
    {
    	local PlayerStart N, BestStart;
    	local float NewRating, BestRating;

    	BestRating = 0;

    	foreach AllActors( class 'PlayerStart', N )
    	{
    		NewRating = tribesRatePlayerStart(N, InTeam, Player);

    		if ( NewRating > BestRating )
    		{
    			BestRating = NewRating;
    			BestStart = N;
    		}
    	}

    	// Log("Best start found to be "$BestStart$" for team "$InTeam);
    	return BestStart;
    }

    // playerPawnDestroyedState
    function Name playerPawnDestroyedState()
    {
    	return 'Dead';
    }

    function Name playerPawnNoRespawnState()
    {
    	return 'Dead';
    }

    // onSpectate
    function onSpectate(PlayerCharacterController c)
    {
    }

    function onUnspectate(PlayerCharacterController c)
    {
    }

    function class<InventoryStationAccess> getInventoryStationAccessClass()
    {
    	return inventoryStationAccessClass;
    }

    function addDroppedEquipment(Equipment e);

    function removeDroppedEquipment(Equipment e);

    function preLevelChange()
    {
    	// Perform any necessary cleanup here
    }

    function float modifyRepairRate(Rook who, float rate)
    {
    	return rate;
    }

    static function bool showChatWindow()
    {
    	return true;
    }

    function modifyAI(BaseAICharacter c);
    function modifyPlayer(SingleplayerCharacter c);
    function float modifyHealthKitRate(Rook who, float rate)
    {
    	return rate;
    }

    defaultproperties
    {
        bDelayedStart			= false
        bRestartLevel			= False
    	AccessControlClass		= "Gameplay.AccessControl"
    	CheatClass				= class'ConsoleCommandManager'
    	MutatorClass			= "Gameplay.Mutator"
    	DefaultPlayerClassName	= "Gameplay.Character"
    	playerTeamDamagePercentage		= 0.0
    	baseDeviceTeamDamagePercentage	= 0.5
    	inventoryStationAccessClass = class'InventoryStationStandaloneAccess'
    	GameReplicationInfoClass	= class'Gameplay.TribesGameReplicationInfo'
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:12.000 - Creation time: st 23.5.2018 00:10:43.497 - Created with UnCodeX