Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Gameplay.Deployable

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431
00432
00433
00434
00435
00436
00437
00438
00439
00440
00441
00442
00443
00444
00445
00446
00447
00448
00449
00450
00451
00452
00453
00454
00455
00456
00457
00458
00459
00460
00461
00462
00463
00464
00465
00466
00467
00468
00469
00470
00471
00472

    // Deployable
    // Base class for deployables. The deployable object represents a piece of equipment that can be carried
    // by the player and then deployed somewhere. Once deployed, the object cannot be picked up again.
    //
    // Generally this class has no need to be used, instead used the derived BaseDeviceDeployable class. Objects
    // that can be deployed themselves should be a type of BaseDevice, but this class remains in case the deployable
    // system needs to be extended in another direction.
    class Deployable extends Equippable
    	native
    	abstract;

    var() float			deployRange				"The maximum range from the player at which the object can be deployed";
    var() bool			bCanDeployOnWall		"If true, the object can be spawned on a wall, else the object must be spawned on the floor";
    var() float			exclusiveRange			"The minimum distance that deployables of the same type can be deployed from each other. 0 to disable.";
    var() bool			bCanBeStolen			"If false, the enemy cannot take the deployable until it has been previously held by a member of the friendly team.";

    var bool			bDeployed;
    var bool			bIsInStation;
    var TeamInfo		team;
    var bool			bDeploying;

    var() Material		hudReticuleOk			"Reticule shown when deployable can be placed successfully";
    var() float			hudReticuleOkWidth		"Width of the reticule texture";
    var() float			hudReticuleOkHeight		"Height of the reticule texture";
    var() float			hudReticuleOkCenterX	"X co-ord on the texture of the hud center";
    var() float			hudReticuleOkCenterY	"Y co-ord on the texture of the hud center";

    var() Material		hudReticuleBad			"Reticule shown when deployable cannot be placed successfully";
    var() float			hudReticuleBadWidth		"Width of the reticule texture";
    var() float			hudReticuleBadHeight	"Height of the reticule texture";
    var() float			hudReticuleBadCenterX	"X co-ord on the texture of the hud center";
    var() float			hudReticuleBadCenterY	"Y co-ord on the texture of the hud center";

    var() Rotator		deployRotOffset			"Rotation applied to the deployable after it is deployed";

    var() Name			thirdPersonInventoryAttachmentBone		"Attachment bone used when the deployable is not selected, but held in the inventory";
    var() Vector		thirdPersonInventoryAttachmentOffset	"Offset from attachment point for 3rd person mesh, while the deployable is not selected";
    var Name			originalAttachmentBone;

    var() Name			deployedQuickChatTag					"Quick chat tag to announce when deployed";

    enum eDeployableInfo
    {
    	DeployableInfo_Ok,
    	DeployableInfo_TooFar,
    	DeployableInfo_NoSurface,
    	DeployableInfo_Blocked,
    	DeployableInfo_SameTypeTooNear,
    	DeployableInfo_InvalidTargetObject,
    	DeployableInfo_BadState
    };

    var eDeployableInfo lastTestResult;

    replication
    {
    	reliable if (Role == ROLE_Authority)
    		bDeployed, bIsInStation;

    	reliable if (Role == ROLE_Authority && bNetOwner)
    		lastTestResult;
    }

    simulated function PostNetReceive()
    {
    	if (bIsInStation)
    		GotoState('DeployableStation');
    	else
    		super.PostNetReceive();
    }

    // PostNetBeginPlay
    simulated function PostNetBeginPlay()
    {
    	Super.PostNetBeginPlay();

    	if (Mesh != None)
    		PlayAnim('Closed');
    }

    simulated function bool armsFirstPersonStatus(bool bNewIsFirstPerson)
    {
    	return false;
    }

    // canPickup
    function bool canPickup(Character potentialOwner)
    {
    	local Deployable existing;

    	if (!bCanBeStolen && team != None && potentialOwner.team() != None && potentialOwner.team() != team)
    		return false;

    	if (!potentialOwner.armorClass.static.isDeployableAllowed(class))
    	{
    //		potentialOwner.ClientMessage("Your armor does not allow you to pick up this deployable.");
    		return false;
    	}

    	existing = Deployable(potentialOwner.nextEquipment(None, class'Deployable'));
    	if (existing != None)
    	{
    //		potentialOwner.ClientMessage("You can only carry one deployable at a time.");
    		return false;
    	}

    	return true;
    }

    function eDeployableInfo testDeploy()
    {
    	lastTestResult = doDeploy(true);
    	return lastTestResult;
    }

    simulated function bool EncroachingOn(Actor Other)
    {
    	return bDeploying;
    }

    simulated private function eDeployableInfo doDeploy(optional bool bTest)
    {
    	local bool bOldColActors;
    	local bool bOldColWorld;
    	local bool bOldBlockActors;
    	local bool bOldBlockPlayers;
    	local bool bOldUseCylinderCollision;
    	local vector startTrace, hitNormal, endTrace;
    	local vector loc;
    	local rotator newRotation;
    	local Actor a;
    	local eDeployableInfo result;
    	local Character charOwner;
    	local Actor allD;

    	bDeploying = true;

    	bOldColWorld = bCollideWorld;
    	bOldColActors = bCollideActors;
    	bOldBlockActors = bBlockActors;
    	bOldBlockPlayers = bOldBlockPlayers;
    	bOldUseCylinderCollision = bUseCylinderCollision;

    	charOwner = Character(Owner);

    	startTrace = charOwner.Location + charOwner.EyePosition();
    	endTrace = startTrace + Vector(charOwner.motor.getViewRotation()) * deployRange;

    	bCollideWorld = false;
    	SetCollision(false, false, false);

    	result = DeployableInfo_Ok;

    	// test for deployment range
    	a = charOwner.Trace(loc, hitNormal, endTrace, startTrace, true, Vect(0.1,0.1,0.1));
    	loc += hitNormal * (CollisionHeight * 0.5);
    	if (a == None || VSize(loc - startTrace) > deployRange)
    	{
    		result = DeployableInfo_TooFar;
    	}

    	// make sure we don't deploy onto vehicles or havok objects
    	if (DynamicObject(a) != None || Vehicle(a) != None || VehicleSpawnPoint(a) != None ||
    		BaseDevice(a) != None || MPActor(a) != None)
    		result = DeployableInfo_InvalidTargetObject;

    	bUseCylinderCollision = true;
    	bCollideWorld = true;
    	SetCollision(true, true, true);

    	// check if we can deploy onto a wall
    	if (result == DeployableInfo_Ok && !bCanDeployOnWall)
    	{
    		if (Vect(0, 0, 1) Dot hitNormal < 0.5)
    		{
    			result = DeployableInfo_NoSurface;
    		}
    	}

    	// check if we can deploy near other deployables
    	if (result == DeployableInfo_Ok && exclusiveRange > 0)
    	{
    		ForEach DynamicActors(class, allD)
    		{
    			if (allD != self && VSize(allD.Location - loc) < exclusiveRange && Deployable(allD).bDeployed)
    			{
    				result = DeployableInfo_SameTypeTooNear;
    				break;
    			}
    		}
    	}

    	if (result == DeployableInfo_Ok)
    	{
    		newRotation.Yaw = charOwner.Rotation.Yaw;
    		newRotation += deployRotOffset;

    		if (bTest)
    		{
    			if (!TestMove(loc, newRotation))
    			{
    				result = DeployableInfo_Blocked;
    			}
    		}
    		else
    		{
    			if (!SetLocation(loc))
    			{
    				result = DeployableInfo_Blocked;
    			}
    			else
    			{
    				if (!SetRotation(newRotation))
    				{
    					result = DeployableInfo_Blocked;
    				}
    				else
    				{
    					team = charOwner.team();
    				}
    			}
    		}
    	}

    	bCollideWorld = bOldColWorld;
    	bUseCylinderCollision = bOldUseCylinderCollision;
    	SetCollision(bOldColActors, bOldBlockActors, bOldBlockPlayers);

    	bDeploying = false;

    	return result;
    }

    // FireReleased state
    state FireReleased
    {
    	function eDeployableInfo deploy()
    	{
    		local Character charOwner;
    		local eDeployableInfo testResult;

    		if (bDeployed)
    			return DeployableInfo_BadState;

    		charOwner = Character(Owner);
    		if (charOwner == None)
    		{
    			log("Deployable used without owner");
    			return DeployableInfo_BadState;
    		}

    		if (charOwner.motor == None)
    		{
    			log("Deployable character owner has no motor");
    			return DeployableInfo_BadState;
    		}

    		testResult = doDeploy();
    		return testResult;
    	}

    	simulated function BeginState()
    	{
    		Super.BeginState();

    		if (Level.NetMode != NM_Client)
    		{
    			if (deploy() == DeployableInfo_Ok)
    			{
    				bDeployed = true;

    				// trigger a quickchat to tell the team its deployed
    				if(	deployedQuickChatTag != '' && Character(Owner) != None &&
    					PlayerCharacterController(Character(Owner).Controller) != None &&
    					! PlayerCharacterController(Character(Owner).Controller).IsSinglePlayer())
    						PlayerCharacterController(Character(Owner).Controller).TeamQuickChat("", String(deployedQuickChatTag));
    			}
    			else
    				GotoState('Idle');
    		}
    	}
    }

    // needPrompt
    function bool needPrompt(Character potentialOwner)
    {
    	return false;
    }

    // Tick
    simulated function Tick(float Delta)
    {
    	if (bDeployed && !IsInState('Deployed'))
    	{
    		GotoState('Deployed');
    	}
    	else
    		Super.Tick(Delta);
    }

    simulated function updateAttachmentStatus(optional bool bForce)
    {
    	if (!firstPersonStatus())
    	{
    		bHidden = false;
    		selectMesh(bForce);
    		SetRelativeLocation(thirdPersonInventoryAttachmentOffset);
    	}
    	else
    	{
    		bHidden = true;
    	}
    }

    function simulated bool fire(optional bool _fireOnce)
    {
    	local Character charOwner;

    	// client-side scripting specific code
    	charOwner = Character(Owner);
    	if (charOwner != None)
    	{
    		if (PlayerCharacterController(charOwner.controller) != None)
    		{
    			PlayerCharacterController(charOwner.controller).clientSideChar.deployableUseTime = Level.TimeSeconds;
    		}
    	}

    	return super.fire(_fireOnce);
    }

    // State Idle
    simulated state Idle
    {
    	simulated function BeginState()
    	{
    		Super.BeginState();
    		Instigator = None;
    		SetRelativeRotation(Rot(0,0,0));
    	}

    	simulated function Tick(float Delta)
    	{
    		Super.Tick(Delta);

    		testDeploy();
    	}
    }

    // State Held
    // Overridden to show the deployable on the character's back
    simulated state Held
    {
    	simulated function BeginState()
    	{
    		super.BeginState();
    		bMeshChangeOk = false;
    		Instigator = None;
    		originalAttachmentBone = thirdPersonAttachmentBone;
    		thirdPersonAttachmentBone = thirdPersonInventoryAttachmentBone;

    		updateAttachmentStatus(true);

    		SetRelativeRotation(Rot(0,0,0));
    	}

    	simulated function Tick(float DeltaTime)
    	{
    		super.Tick(DeltaTime);

    		updateAttachmentStatus();
    	}

    	simulated function EndState()
    	{
    		super.EndState();
    		thirdPersonAttachmentBone = originalAttachmentBone;
    	}
    }

    // State Dropped
    simulated state Dropped
    {
    	simulated function BeginState()
    	{
    		Super.BeginState();
    		bCanBeStolen = true;
    	}
    }

    // State Deployed
    simulated state Deployed extends Dropped
    {
    	function setupDropped()
    	{
    		Character(rookOwner).removeEquipment(self);
    		Character(rookOwner).deployable = None;
    		Super.setupDropped();
    		bDropped = false;
    	}

    	simulated function BeginState()
    	{
    		setupDropped();
    	}

    	// called to see if the object can expire due to timeout, max dropped equipment etc.
    	simulated function bool canExpire()
    	{
    		return false;
    	}

    Begin:
    	if (Mesh != None)
    	{
    		PlayAnim('Deploy');
    		FinishAnim();
    		LoopAnim('Deployed');
    	}
    }

    simulated state DeployableStation extends AwaitingPickup
    {
    	simulated function setup()
    	{
    		bCanPickup = false;
    		SetCollision(false, false, false);
    		bCollideWorld = false;
    		bHidden = false;
    	}

    	simulated function BeginState()
    	{
    		super.BeginState();
    		bIsInStation = true;
    	}

    	simulated function EndState()
    	{
    		super.EndState();
    		bIsInStation = false;
    	}

    Begin:
    	bPlayPickupSound = true;
    	setup();
    }

    defaultproperties
    {
    	bCanDrop				= true
    	bCanBeStolen			= false
    	animClass				= class'CharacterEquippableAnimator'
    	deployRange				= 1000
    	exclusiveRange			= 1000

    	hudReticuleOk			= texture'HUD.ReticuleScatter'
    	hudReticuleOkWidth		= 128
    	hudReticuleOkHeight		= 128
    	hudReticuleOkCenterX	= 64
    	hudReticuleOkCenterY	= 64

    	hudReticuleBad			= texture'HUD.ReticuleDirect'
    	hudReticuleBadWidth		= 128
    	hudReticuleBadHeight	= 128
    	hudReticuleBadCenterX	= 64
    	hudReticuleBadCenterY	= 64

    	thirdPersonInventoryAttachmentBone = "deployable"
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:10.000 - Creation time: st 23.5.2018 00:10:43.099 - Created with UnCodeX