Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Gameplay.DeployedRepairer

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155

    class DeployedRepairer extends BaseDevice implements IRepairClient;

    var RepairRadius rr;
    var() float radius;
    var() float repairRate;
    var() float accumulationScale;
    var() float selfRepairRate;
    var() string socketFrontLeft;
    var() string socketFrontRight;
    var() string socketBackLeft;
    var() string socketBackRight;

    // local port positions
    var Vector frontPortLeft;
    var Vector frontPortRight;
    var Vector backPortLeft;
    var Vector backPortRight;

    simulated function PostBeginPlay()
    {
    	local Rotator rot;
    	local Vector s;

    	super.PostBeginPlay();

    	initRepairRadius();
    	getSocket(socketFrontLeft, frontPortLeft, rot, s, SOCKET_Local);
    	getSocket(socketFrontRight, frontPortRight, rot, s, SOCKET_Local);
    	getSocket(socketBackLeft, backPortLeft, rot, s, SOCKET_Local);
    	getSocket(socketBackRight, backPortRight, rot, s, SOCKET_Local);
    }

    simulated function Tick(float Delta)
    {
    	super.Tick(Delta);
    	IncreaseHealth(selfRepairRate * Delta);
    }

    simulated function initRepairRadius()
    {
    	rr = new class'RepairRadius'(self, , Location);
    }

    simulated function Destroyed()
    {
    	super.Destroyed();

    	if (rr != None)
    		rr.Destroy();
    }

    // IRepairClient
    simulated function bool canRepair(Rook r)
    {
    	local BaseDevice b;

    	if (Character(r) != None && !r.isAlive())
    		return false;

    	b = BaseDevice(r);
    	if (b != None && b.bWasDeployed && b.isDisabled())
    		return false;

    	return r != self && r.canBeRepairedBy(self) && r.health < r.healthMaximum;
    }

    simulated function float getRepairRadius()
    {
    	return radius;
    }

    simulated function beginRepair(Rook r)
    {
    	if (!r.IsHumanControlled())
    		level.speechManager.PlayDynamicSpeech( r, 'UseHealth' );

    	r.addRepairFromDeployable(repairRate, accumulationScale);
    }

    simulated function endRepair(Rook r)
    {
    	r.removeRepairFromDeployable(accumulationScale);
    }

    simulated function Pawn getFXOriginActor()
    {
    	return self;
    }

    simulated function Vector getFXTendrilOrigin(Vector targetPos)
    {
    	local Vector forwardVec;
    	local Vector leftVec;
    	local Vector originatorToTarget;
    	local bool bForward;
    	local bool bLeft;

    	originatorToTarget = targetPos - Location;
    	originatorToTarget.z = 0;
    	originatorToTarget = Normal(originatorToTarget);

    	forwardVec = Vector(Rotation);
    	forwardVec.z = 0;
    	forwardVec = Normal(forwardVec);

    	leftVec.x = forwardVec.y;
    	leftVec.y = -forwardVec.x;

    	bForward = originatorToTarget dot forwardVec > 0;
    	bLeft = originatorToTarget dot leftVec > 0;

    	if (bLeft)
    	{
    		if (bForward)
    			return Location + (frontPortLeft >> Rotation);
    		else
    			return Location + (backPortLeft >> Rotation);
    	}
    	else
    	{
    		if (bForward)
    			return Location + (frontPortRight >> Rotation);
    		else
    			return Location + (backPortRight >> Rotation);
    	}

    	return Location;
    }

    simulated function Vector getFXTendrilTarget(Actor target)
    {
    	return target.unifiedGetPosition();
    }

    simulated function onTendrilCreate(RepairTendril t) {}

    // End IRepairClient

    defaultproperties
    {
    	bWasDeployed = true
    	bIgnoreEncroachers = true

    	radius = 400
    	repairRate = 10
    	accumulationScale = 1.0
    	selfRepairRate = 5

    	socketFrontLeft = "CHILD00"
    	socketFrontRight = "CHILD01"
    	socketBackLeft = "CHILD02"
    	socketBackRight = "CHILD03"

    	Mesh = SkeletalMesh'Deployables.DepRepairStation'
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:20.000 - Creation time: st 23.5.2018 00:10:43.118 - Created with UnCodeX