Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Engine.GameInfo

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431
00432
00433
00434
00435
00436
00437
00438
00439
00440
00441
00442
00443
00444
00445
00446
00447
00448
00449
00450
00451
00452
00453
00454
00455
00456
00457
00458
00459
00460
00461
00462
00463
00464
00465
00466
00467
00468
00469
00470
00471
00472
00473
00474
00475
00476
00477
00478
00479
00480
00481
00482
00483
00484
00485
00486
00487
00488
00489
00490
00491
00492
00493
00494
00495
00496
00497
00498
00499
00500
00501
00502
00503
00504
00505
00506
00507
00508
00509
00510
00511
00512
00513
00514
00515
00516
00517
00518
00519
00520
00521
00522
00523
00524
00525
00526
00527
00528
00529
00530
00531
00532
00533
00534
00535
00536
00537
00538
00539
00540
00541
00542
00543
00544
00545
00546
00547
00548
00549
00550
00551
00552
00553
00554
00555
00556
00557
00558
00559
00560
00561
00562
00563
00564
00565
00566
00567
00568
00569
00570
00571
00572
00573
00574
00575
00576
00577
00578
00579
00580
00581
00582
00583
00584
00585
00586
00587
00588
00589
00590
00591
00592
00593
00594
00595
00596
00597
00598
00599
00600
00601
00602
00603
00604
00605
00606
00607
00608
00609
00610
00611
00612
00613
00614
00615
00616
00617
00618
00619
00620
00621
00622
00623
00624
00625
00626
00627
00628
00629
00630
00631
00632
00633
00634
00635
00636
00637
00638
00639
00640
00641
00642
00643
00644
00645
00646
00647
00648
00649
00650
00651
00652
00653
00654
00655
00656
00657
00658
00659
00660
00661
00662
00663
00664
00665
00666
00667
00668
00669
00670
00671
00672
00673
00674
00675
00676
00677
00678
00679
00680
00681
00682
00683
00684
00685
00686
00687
00688
00689
00690
00691
00692
00693
00694
00695
00696
00697
00698
00699
00700
00701
00702
00703
00704
00705
00706
00707
00708
00709
00710
00711
00712
00713
00714
00715
00716
00717
00718
00719
00720
00721
00722
00723
00724
00725
00726
00727
00728
00729
00730
00731
00732
00733
00734
00735
00736
00737
00738
00739
00740
00741
00742
00743
00744
00745
00746
00747
00748
00749
00750
00751
00752
00753
00754
00755
00756
00757
00758
00759
00760
00761
00762
00763
00764
00765
00766
00767
00768
00769
00770
00771
00772
00773
00774
00775
00776
00777
00778
00779
00780
00781
00782
00783
00784
00785
00786
00787
00788
00789
00790
00791
00792
00793
00794
00795
00796
00797
00798
00799
00800
00801
00802
00803
00804
00805
00806
00807
00808
00809
00810
00811
00812
00813
00814
00815
00816
00817
00818
00819
00820
00821
00822
00823
00824
00825
00826
00827
00828
00829
00830
00831
00832
00833
00834
00835
00836
00837
00838
00839
00840
00841
00842
00843
00844
00845
00846
00847
00848
00849
00850
00851
00852
00853
00854
00855
00856
00857
00858
00859
00860
00861
00862
00863
00864
00865
00866
00867
00868
00869
00870
00871
00872
00873
00874
00875
00876
00877
00878
00879
00880
00881
00882
00883
00884
00885
00886
00887
00888
00889
00890
00891
00892
00893
00894
00895
00896
00897
00898
00899
00900
00901
00902
00903
00904
00905
00906
00907
00908
00909
00910
00911
00912
00913
00914
00915
00916
00917
00918
00919
00920
00921
00922
00923
00924
00925
00926
00927
00928
00929
00930
00931
00932
00933
00934
00935
00936
00937
00938
00939
00940
00941
00942
00943
00944
00945
00946
00947
00948
00949
00950
00951
00952
00953
00954
00955
00956
00957
00958
00959
00960
00961
00962
00963
00964
00965
00966
00967
00968
00969
00970
00971
00972
00973
00974
00975
00976
00977
00978
00979
00980
00981
00982
00983
00984
00985
00986
00987
00988
00989
00990
00991
00992
00993
00994
00995
00996
00997
00998
00999
01000
01001
01002
01003
01004
01005
01006
01007
01008
01009
01010
01011
01012
01013
01014
01015
01016
01017
01018
01019
01020
01021
01022
01023
01024
01025
01026
01027
01028
01029
01030
01031
01032
01033
01034
01035
01036
01037
01038
01039
01040
01041
01042
01043
01044
01045
01046
01047
01048
01049
01050
01051
01052
01053
01054
01055
01056
01057
01058
01059
01060
01061
01062
01063
01064
01065
01066
01067
01068
01069
01070
01071
01072
01073
01074
01075
01076
01077
01078
01079
01080
01081
01082
01083
01084
01085
01086
01087
01088
01089
01090
01091
01092
01093
01094
01095
01096
01097
01098
01099
01100
01101
01102
01103
01104
01105
01106
01107
01108
01109
01110
01111
01112
01113
01114
01115
01116
01117
01118
01119
01120
01121
01122
01123
01124
01125
01126
01127
01128
01129
01130
01131
01132
01133
01134
01135
01136
01137
01138
01139
01140
01141
01142
01143
01144
01145
01146
01147
01148
01149
01150
01151
01152
01153
01154
01155
01156
01157
01158
01159
01160
01161
01162
01163
01164
01165
01166
01167
01168
01169
01170
01171
01172
01173
01174
01175
01176
01177
01178
01179
01180
01181
01182
01183
01184
01185
01186
01187
01188
01189
01190
01191
01192
01193
01194
01195
01196
01197
01198
01199
01200
01201
01202
01203
01204
01205
01206
01207
01208
01209
01210
01211
01212
01213
01214
01215
01216
01217
01218
01219
01220
01221
01222
01223
01224
01225
01226
01227
01228
01229
01230
01231
01232
01233
01234
01235
01236
01237
01238
01239
01240
01241
01242
01243
01244
01245
01246
01247
01248
01249
01250
01251
01252
01253
01254
01255
01256
01257
01258
01259
01260
01261
01262
01263
01264
01265
01266
01267
01268
01269
01270
01271
01272
01273
01274
01275
01276
01277
01278
01279
01280
01281
01282
01283
01284
01285
01286
01287
01288
01289
01290
01291
01292
01293
01294
01295
01296
01297
01298
01299
01300
01301
01302
01303
01304
01305
01306
01307
01308
01309
01310
01311
01312
01313
01314
01315
01316
01317
01318
01319
01320
01321
01322
01323
01324
01325
01326
01327
01328
01329
01330
01331
01332
01333
01334
01335
01336
01337
01338
01339
01340
01341
01342
01343
01344
01345
01346
01347
01348
01349
01350
01351
01352
01353
01354
01355
01356
01357
01358
01359
01360
01361
01362
01363
01364
01365
01366
01367
01368
01369
01370
01371
01372
01373
01374
01375
01376
01377
01378
01379
01380
01381
01382
01383
01384
01385
01386
01387
01388
01389
01390
01391
01392
01393
01394
01395
01396
01397
01398
01399
01400
01401
01402
01403
01404
01405
01406
01407
01408
01409
01410
01411
01412
01413
01414
01415
01416
01417
01418
01419
01420
01421
01422
01423
01424
01425
01426
01427
01428
01429
01430
01431
01432
01433
01434
01435
01436
01437
01438
01439
01440
01441
01442
01443
01444
01445
01446
01447
01448
01449
01450
01451
01452
01453
01454
01455
01456
01457
01458
01459
01460
01461
01462
01463
01464
01465
01466
01467
01468
01469
01470
01471
01472
01473
01474
01475
01476
01477
01478
01479
01480
01481
01482
01483
01484
01485
01486
01487
01488
01489
01490
01491
01492
01493
01494
01495
01496
01497
01498
01499
01500
01501
01502
01503
01504
01505
01506
01507
01508
01509
01510
01511
01512
01513
01514
01515
01516
01517
01518
01519
01520
01521
01522
01523
01524
01525
01526
01527
01528
01529
01530
01531
01532
01533
01534
01535
01536
01537
01538
01539
01540
01541
01542
01543
01544
01545
01546
01547
01548
01549
01550
01551
01552
01553
01554
01555
01556
01557
01558
01559
01560
01561
01562
01563
01564
01565
01566
01567
01568
01569
01570
01571
01572
01573
01574
01575
01576
01577
01578
01579
01580
01581
01582
01583
01584
01585
01586
01587
01588
01589
01590
01591
01592
01593
01594
01595
01596
01597
01598
01599
01600
01601
01602
01603
01604
01605
01606
01607
01608
01609
01610
01611
01612
01613
01614
01615
01616
01617
01618
01619
01620
01621
01622
01623
01624
01625
01626
01627
01628
01629
01630
01631
01632
01633
01634
01635
01636
01637
01638
01639
01640
01641
01642
01643
01644
01645
01646
01647
01648
01649
01650
01651
01652
01653
01654
01655
01656
01657
01658
01659
01660
01661
01662
01663
01664
01665
01666
01667
01668
01669
01670
01671
01672
01673
01674
01675
01676
01677
01678
01679
01680
01681
01682
01683
01684
01685
01686
01687
01688
01689
01690
01691
01692
01693
01694
01695
01696
01697
01698
01699
01700
01701
01702
01703
01704
01705
01706
01707
01708
01709
01710
01711
01712
01713
01714
01715
01716
01717
01718
01719
01720
01721
01722
01723
01724
01725
01726
01727
01728
01729
01730
01731
01732
01733
01734
01735
01736
01737
01738
01739
01740
01741
01742
01743
01744
01745
01746
01747
01748
01749
01750
01751
01752
01753
01754
01755
01756
01757
01758
01759
01760
01761
01762
01763
01764
01765
01766
01767
01768
01769
01770
01771
01772
01773
01774
01775
01776
01777
01778
01779
01780
01781
01782
01783
01784
01785
01786
01787
01788
01789
01790
01791
01792
01793
01794
01795
01796
01797
01798
01799
01800
01801
01802
01803
01804
01805
01806
01807
01808
01809
01810
01811
01812
01813
01814
01815
01816
01817
01818
01819
01820
01821
01822
01823
01824
01825
01826
01827
01828
01829
01830
01831
01832
01833
01834
01835
01836
01837
01838
01839
01840
01841
01842
01843
01844
01845
01846
01847
01848
01849
01850
01851
01852
01853
01854
01855
01856
01857
01858
01859
01860
01861
01862
01863
01864
01865
01866
01867
01868
01869
01870
01871
01872
01873
01874
01875
01876
01877
01878
01879
01880
01881
01882
01883
01884
01885
01886
01887
01888
01889
01890
01891
01892
01893
01894
01895
01896
01897
01898
01899
01900
01901
01902
01903
01904
01905
01906
01907
01908
01909
01910
01911
01912
01913
01914
01915
01916
01917
01918
01919
01920
01921
01922
01923
01924
01925
01926
01927
01928
01929
01930
01931
01932
01933
01934
01935
01936
01937
01938
01939
01940
01941
01942
01943
01944
01945
01946
01947
01948
01949
01950
01951
01952
01953
01954
01955
01956
01957
01958
01959
01960
01961
01962
01963
01964
01965
01966
01967
01968
01969
01970
01971
01972
01973
01974
01975
01976
01977
01978
01979
01980
01981
01982
01983
01984
01985
01986
01987
01988
01989
01990
01991
01992
01993
01994
01995
01996
01997
01998
01999
02000
02001
02002
02003
02004
02005
02006
02007
02008
02009
02010
02011
02012
02013
02014
02015
02016
02017
02018
02019
02020
02021
02022
02023
02024
02025

    //=============================================================================
    // GameInfo.
    //
    // The GameInfo defines the game being played: the game rules, scoring, what actors
    // are allowed to exist in this game type, and who may enter the game.  While the
    // GameInfo class is the public interface, much of this functionality is delegated
    // to several classes to allow easy modification of specific game components.  These
    // classes include GameInfo, AccessControl, Mutator, BroadcastHandler, and GameRules.
    // A GameInfo actor is instantiated when the level is initialized for gameplay (in
    // C++ UGameEngine::LoadMap() ).  The class of this GameInfo actor is determined by
    // (in order) either the DefaultGameType if specified in the LevelInfo, or the
    // DefaultGame entry in the game's .ini file (in the Engine.Engine section), unless
    // its a network game in which case the DefaultServerGame entry is used.
    //
    //=============================================================================
    class GameInfo extends Info
    	native;

    //-----------------------------------------------------------------------------
    // Variables.

    var bool				      bRestartLevel;			// Level should be restarted when player dies
    var bool				      bPauseable;				// Whether the game is pauseable.
    var config bool					bWeaponStay;              // Whether or not weapons stay when picked up.
    var	bool				      bCanChangeSkin;			// Allow player to change skins in game.
    var bool				      bTeamGame;				// This is a team game.
    var	bool					  bGameEnded;				// set when game ends
    var	bool					  bOverTime;
    var localized bool			  bAlternateMode;
    var	bool					  bCanViewOthers;
    var bool					  bDelayedStart;
    var bool					  bWaitingToStartMatch;
    var globalconfig bool		  bChangeLevels;
    var		bool				  bAlreadyChanged;
    var bool						bLoggingGame;           // Does this gametype log?
    var globalconfig bool			bEnableStatLogging;		// If True, games will log
    var config bool					bAllowWeaponThrowing;
    var config bool					bAllowBehindView;
    var globalconfig bool			bAdminCanPause;
    var bool						bGameRestarted;
    var bool						bKeepSamePlayerStart;	// used in post login

    var globalconfig float        GameDifficulty;
    var	  globalconfig int		  GoreLevel;				// 0=Normal, increasing values=less gore
    var   globalconfig float	  AutoAim;					// How much autoaiming to do (1 = none, 0 = always).
    														// (cosine of max error to correct)
    var   globalconfig float	  GameSpeed;				// Scale applied to game rate.
    var   float                   StartTime;

    var   string				  DefaultPlayerClassName;

    // user interface
    var   string                  ScoreBoardType;           // Type of class<Menu> to use for scoreboards. (gam)
    var   string			      BotMenuType;				// Type of bot menu to display.
    var   string			      RulesMenuType;			// Type of rules menu to display.
    var   string				  SettingsMenuType;			// Type of settings menu to display.
    var   string				  GameUMenuType;			// Type of Game dropdown to display.
    var   string				  MultiplayerUMenuType;		// Type of Multiplayer dropdown to display.
    var   string				  GameOptionsMenuType;		// Type of options dropdown to display.
    var	  string				  HUDType;					// HUD class this game uses.
    var   string				  MapListType;				// Maplist this game uses.
    var   string			      MapPrefix;				// Prefix characters for names of maps for this game type.
    var   string			      BeaconName;				// Identifying string used for finding LAN servers.

    var   globalconfig int	      MaxSpectators;			// Maximum number of spectators.
    var	  int					  NumSpectators;			// Current number of spectators.
    var   globalconfig int		  MaxPlayers;
    var   int					  NumPlayers;				// number of human players
    var	  int					  NumBots;					// number of non-human players (AI controlled but participating as a player)
    var   int					  CurrentID;
    var localized string	      DefaultPlayerName;
    #if IG_TRIBES3 // dbeswick
    var() localized string	      GameName;
    var() localized string	      GameDescription;
    #else
    var localized string	      GameName;
    #endif
    var float					  FearCostFallOff;			// how fast the FearCost in NavigationPoints falls off

    var config int                GoalScore;                // what score is needed to end the match
    var config int                MaxLives;	                // max number of lives for match, unless overruled by level's GameDetails
    var config int                TimeLimit;                // time limit in minutes

    // Message classes.
    var class<LocalMessage>		  DeathMessageClass;
    var class<GameMessage>		  GameMessageClass;
    var	name					  OtherMesgGroup;

    //-------------------------------------
    // GameInfo components
    var string MutatorClass;
    var Mutator BaseMutator;				// linked list of Mutators (for modifying actors as they enter the game)
    var globalconfig string AccessControlClass;
    var AccessControl AccessControl;		// AccessControl controls whether players can enter and/or become admins
    var GameRules GameRulesModifiers;		// linked list of modifier classes which affect game rules
    var string BroadcastHandlerClass;
    var BroadcastHandler BroadcastHandler;	// handles message (text and localized) broadcasts

    var class<PlayerController> PlayerControllerClass;	// type of player controller to spawn for players logging in
    var string PlayerControllerClassName;

    // ReplicationInfo
    var() class<GameReplicationInfo> GameReplicationInfoClass;
    var GameReplicationInfo GameReplicationInfo;
    var bool bWelcomePending;

    // Stats - jmw
    var GameStats                   GameStats;				// Holds the GameStats actor
    var globalconfig string				GameStatsClass;			// Type of GameStats actor to spawn

    // Voice chat
    struct VoiceChatterInfo
    {
    	var controller			Controller;
    	var int					IpAddr;
    	var int					Handle;
    };
    var array<VoiceChatterInfo>		VoiceChatters;

    // Cheat Protection
    var globalconfig string			SecurityClass;

    var() String ScreenShotName;
    var() String DecoTextName;

    #if IG_TRIBES3	// michaelj:  Localized
    var() localized String Acronym;
    #else
    var() String Acronym;
    #endif

    // localized PlayInfo descriptions & extra info
    var private localized string GIPropsDisplayText[11];
    var private localized string GIPropsExtras[2];

    #if IG_TRIBES3	// michaelj:  Added difficulty enums for filtering purposes in Actor
    var int difficulty;
    #endif

    #if IG_TRIBES3_VOTING   // glenn: voting support
    // voting handler
    var globalconfig string VotingHandlerType;
    var class<VotingHandler> VotingHandlerClass;
    var VotingHandler VotingHandler;
    #endif

    #if IG_TRIBES3 // dbeswick: catch travel failures
    var bool bMapRotationTraveling;
    #endif

    #if IG_TRIBES3 // Alex: level boundary volume - ideally would be in Gameplay.GameInfo, where it is set, but needs to be accessed natively
    var Volume BoundaryVolume;
    #endif

    #if IG_TRIBES3_ADMIN    // glenn: admin support
    native final static function	LoadMapList(string MapPrefix, out array<string> Maps);
    #endif

    //------------------------------------------------------------------------------
    // Engine notifications.

    function PreBeginPlay()
    {
    	StartTime = 0;
    	SetGameSpeed(GameSpeed);
    	GameReplicationInfo = Spawn(GameReplicationInfoClass);
    	InitGameReplicationInfo();
    	// Create stat logging actor.
        InitLogging();
    }

    #if IG_TRIBES3 // Ryan: notification of level change
    event LevelChange();
    #endif

    #if IG_SHARED
    //return true in your subclass if you want GameInfo to Tick
    function bool GameInfoShouldTick();
    #endif

    #if IG_EFFECTS
    function Tick(float DeltaTime)
    {
        if (!GameInfoShouldTick())
            Disable('Tick');
    }
    #endif

    simulated function UpdatePrecacheRenderData()
    {
    	PrecacheGameRenderData(Level);
    }

    static simulated function PrecacheGameRenderData(LevelInfo myLevel);

    function string FindPlayerByID( int PlayerID )
    {
        local int i;

        for( i=0; i<GameReplicationInfo.PRIArray.Length; i++ )
        {
            if( GameReplicationInfo.PRIArray[i].PlayerID == PlayerID )
                return GameReplicationInfo.PRIArray[i].PlayerName;
        }
        return "";
    }

    static function bool UseLowGore()
    {
    	return ( Default.bAlternateMode || (Default.GoreLevel > 0) );
    }

    function PostBeginPlay()
    {
    	if (GameStats!=None)
    	{
    		GameStats.NewGame();
    		GameStats.ServerInfo();
    	}
    }

    /* Reset()
    reset actor to initial state - used when restarting level without reloading.
    */
    function Reset()
    {
    	Super.Reset();
    	bGameEnded = false;
    	bOverTime = false;
    	bWaitingToStartMatch = true;
    	InitGameReplicationInfo();
    }

    /* InitLogging()
    Set up statistics logging
    */
    function InitLogging()
    {
    	local class <GameStats> MyGameStatsClass;

        if ( !bEnableStatLogging || !bLoggingGame || (Level.NetMode == NM_Standalone) || (Level.NetMode == NM_ListenServer) )
    		return;

    	MyGameStatsClass=class<GameStats>(DynamicLoadObject(GameStatsClass,class'class'));
        if (MyGameStatsClass!=None)
        {
    		GameStats = spawn(MyGameStatsClass);
            if (GameStats==None)
            	log("Could to create Stats Object");
        }
        else
        	log("Error loading GameStats ["$GameStatsClass$"]");
    }

    function Timer()
    {
    	local NavigationPoint N;
    	local int i;

        // If we are a server, broadcast a welcome message.
        if( bWelcomePending )
        {
    		bWelcomePending = false;
    		if ( Level.NetMode != NM_Standalone )
    		{
    			for ( i=0; i<GameReplicationInfo.PRIArray.Length; i++ )
    				if ( (GameReplicationInfo.PRIArray[i] != None)
    					&& !GameReplicationInfo.PRIArray[i].bWelcomed )
    				{
    					GameReplicationInfo.PRIArray[i].bWelcomed = true;
    					if ( !GameReplicationInfo.PRIArray[i].bOnlySpectator )
    						BroadcastLocalizedMessage(GameMessageClass, 1, GameReplicationInfo.PRIArray[i]);
    				}
    		}
    	}

    	BroadcastHandler.UpdateSentText();
        for ( N=Level.NavigationPointList; N!=None; N=N.NextNavigationPoint )
    		N.FearCost *= FearCostFallOff;
    }

    // Called when game shutsdown.
    event GameEnding()
    {
    	EndLogging("serverquit");
    }

    //------------------------------------------------------------------------------
    // Replication

    function InitGameReplicationInfo()
    {
    	GameReplicationInfo.bTeamGame = bTeamGame;
    	GameReplicationInfo.GameName = GameName;
    	GameReplicationInfo.GameClass = string(Class);
        GameReplicationInfo.MaxLives = MaxLives;
    }

    native function string GetNetworkNumber();

    #if IG_TRIBES3_VOTING   // glenn: voting support
    function InitMaplistHandler();
    #endif

    // VOTING TODO - integrate InitMaplistHandler implementation

    //------------------------------------------------------------------------------
    // Server/Game Querying.

    function GetServerInfo( out ServerResponseLine ServerState )
    {
    	ServerState.ServerName		= GameReplicationInfo.ServerName;
    	ServerState.MapName			= Left(string(Level), InStr(string(Level), "."));
    	ServerState.GameType		= Mid( string(Class), InStr(string(Class), ".")+1);
    	ServerState.CurrentPlayers	= GetNumPlayers();
    	ServerState.MaxPlayers		= MaxPlayers;
    	ServerState.IP				= ""; // filled in at the other end.
    	ServerState.Port			= GetServerPort();

    	ServerState.ServerInfo.Length = 0;
    	ServerState.PlayerInfo.Length = 0;
    }

    function int GetNumPlayers()
    {
    	return NumPlayers;
    }

    function GetServerDetails( out ServerResponseLine ServerState )
    {
    	local int i;
    	local Mutator M;
    	local GameRules G;

    	i = ServerState.ServerInfo.Length;

    	// servermode
    	ServerState.ServerInfo.Length = i+1;
    	ServerState.ServerInfo[i].Key = "servermode";
    	if( Level.NetMode==NM_ListenServer )
    		ServerState.ServerInfo[i++].Value = "non-dedicated";
        else
    		ServerState.ServerInfo[i++].Value = "dedicated";

    	// adminname
    	ServerState.ServerInfo.Length = i+1;
    	ServerState.ServerInfo[i].Key = "adminname";
    	ServerState.ServerInfo[i++].Value = GameReplicationInfo.AdminName;

    	// adminemail
    	ServerState.ServerInfo.Length = i+1;
    	ServerState.ServerInfo[i].Key = "adminemail";
    	ServerState.ServerInfo[i++].Value = GameReplicationInfo.AdminEmail;

    	// adminemail
    	ServerState.ServerInfo.Length = i+1;
    	ServerState.ServerInfo[i].Key = "ServerVersion";
    	ServerState.ServerInfo[i++].Value = level.EngineVersion;

    	// has password
    	if( AccessControl.RequiresPassword() )
    		{
    		ServerState.ServerInfo.Length = i+1;
    		ServerState.ServerInfo[i].Key = "password";
    		ServerState.ServerInfo[i++].Value = "true";
    	}

    	// has stats enabled
    	ServerState.ServerInfo.Length = i+1;
    	ServerState.ServerInfo[i].Key = "gamestats";
    	if( GameStats!=None )
    		ServerState.ServerInfo[i++].Value = "true";
    	else
    		ServerState.ServerInfo[i++].Value = "false";

    	// game speed
    	if( GameSpeed != 1.0 )
    			{
    		ServerState.ServerInfo.Length = i+1;
    		ServerState.ServerInfo[i].Key = "gamespeed";
    		ServerState.ServerInfo[i++].Value = string( int(GameSpeed*100)/100.0 );
    	}

    #if IG_TRIBES3_VOTING   // glenn: voting support
    	// voting
    	if( VotingHandler != None )
    		VotingHandler.GetServerDetails(ServerState);
    #endif

    	// Ask the mutators if they have anything to add.
    	for (M = BaseMutator.NextMutator; M != None; M = M.NextMutator)
    		M.GetServerDetails(ServerState);

    	// Ask the gamerules if they have anything to add.
    	for ( G=GameRulesModifiers; G!=None; G=G.NextGameRules )
    		G.GetServerDetails(ServerState);
    }

    function GetServerPlayers( out ServerResponseLine ServerState )
    {
        local Mutator M;
    	local Controller C;
    	local PlayerReplicationInfo PRI;
    	local int i;

    	i = ServerState.PlayerInfo.Length;

    	for( C=Level.ControllerList;C!=None;C=C.NextController )
            {
    			PRI = C.PlayerReplicationInfo;
    			if( (PRI != None) && !PRI.bBot && MessagingSpectator(C) == None )
                {
    			ServerState.PlayerInfo.Length = i+1;
    			ServerState.PlayerInfo[i].PlayerNum  = C.PlayerNum;
    			ServerState.PlayerInfo[i].PlayerName = PRI.PlayerName;
    			ServerState.PlayerInfo[i].Score		 = PRI.Score;
    			ServerState.PlayerInfo[i].Ping		 = PRI.Ping;
    			i++;
    		}
    	}

    	// Ask the mutators if they have anything to add.
    	for (M = BaseMutator.NextMutator; M != None; M = M.NextMutator)
    		M.GetServerPlayers(ServerState);
    }

    //------------------------------------------------------------------------------
    // Misc.

    // Return the server's port number.
    function int GetServerPort()
    {
    	local string S;
    	local int i;

    	// Figure out the server's port.
    	S = Level.GetAddressURL();
    	i = InStr( S, ":" );
    	assert(i>=0);
    	return int(Mid(S,i+1));
    }

    function bool SetPause( BOOL bPause, PlayerController P )
    {
        if( bPauseable || (bAdminCanPause && (P.IsA('Admin') || P.PlayerReplicationInfo.bAdmin)) || Level.Netmode==NM_Standalone )
    	{
    		if( bPause )
            {
    			Level.Pauser=P.PlayerReplicationInfo;
    #if IG_EFFECTS
                ConsoleCommand("PauseSounds");
    #endif
            }
    		else
            {
    			Level.Pauser=None;
    #if IG_EFFECTS
                ConsoleCommand("UnPauseSounds");
    #endif
            }
    		return True;
    	}
    	else return False;
    }

    //------------------------------------------------------------------------------
    // Voice chat.
    function ChangeVoiceChatter( Controller Client, int IpAddr, int Handle, bool Add )
    {
    	local int Index;
    	local PlayerController P;

    	if( Add )
    	{
    		Index = VoiceChatters.length;
    		VoiceChatters.Insert(Index,1);
    		VoiceChatters[Index].Controller	= Client;
    		VoiceChatters[Index].IpAddr		= IpAddr;
    		VoiceChatters[Index].Handle		= Handle;
    	}
    	else
    	{
    		for( Index=0; Index<VoiceChatters.Length; Index++ )
    		{
    			if( (VoiceChatters[Index].IpAddr == IpAddr) && (VoiceChatters[Index].Handle == Handle) )
    				VoiceChatters.Remove(Index,1);
    		}
    	}

    	foreach DynamicActors( class'PlayerController', P )
    	{
    		if( P != Client )
    		{
    			P.ClientChangeVoiceChatter( IpAddr, Handle, Add );
    		}
    	}
    }

    //------------------------------------------------------------------------------
    // Game parameters.

    //
    // Set gameplay speed.
    //
    function SetGameSpeed( Float T )
    {
    	local float OldSpeed;

    	OldSpeed = GameSpeed;
    	GameSpeed = FMax(T, 0.1);
    	Level.TimeDilation = GameSpeed;
    	if ( GameSpeed != OldSpeed )
        {
    		Default.GameSpeed = GameSpeed;
    		class'GameInfo'.static.StaticSaveConfig();
    	}
    	SetTimer(Level.TimeDilation, true);
    }

    //
    // Called after setting low or high detail mode.
    //
    event DetailChange()
    {
    	local actor A;
    	local zoneinfo Z;

        if( Level.DetailMode == DM_Low )
    	{
    		foreach DynamicActors(class'Actor', A)
    		{
                if( (A.bHighDetail || A.bSuperHighDetail) && !A.bGameRelevant )
                    A.Destroy();
            }
        }
        else if( Level.DetailMode == DM_High )
        {
            foreach DynamicActors(class'Actor', A)
            {
                if( A.bSuperHighDetail && !A.bGameRelevant )
    				A.Destroy();
    		}
    	}
    	foreach AllActors(class'ZoneInfo', Z)
    		Z.LinkToSkybox();
    }

    //------------------------------------------------------------------------------
    // Player start functions

    //
    // Grab the next option from a string.
    //
    function bool GrabOption( out string Options, out string Result )
    {
    	if( Left(Options,1)=="?" )
    	{
    		// Get result.
    		Result = Mid(Options,1);
    		if( InStr(Result,"?")>=0 )
    			Result = Left( Result, InStr(Result,"?") );

    		// Update options.
    		Options = Mid(Options,1);
    		if( InStr(Options,"?")>=0 )
    			Options = Mid( Options, InStr(Options,"?") );
    		else
    			Options = "";

    		return true;
    	}
    	else return false;
    }

    //
    // Break up a key=value pair into its key and value.
    //
    function GetKeyValue( string Pair, out string Key, out string Value )
    {
    	if( InStr(Pair,"=")>=0 )
    	{
    		Key   = Left(Pair,InStr(Pair,"="));
    		Value = Mid(Pair,InStr(Pair,"=")+1);
    	}
    	else
    	{
    		Key   = Pair;
    		Value = "";
    	}
    }

    /* ParseOption()
     Find an option in the options string and return it.
    */
    function string ParseOption( string Options, string InKey )
    {
    	local string Pair, Key, Value;
    	while( GrabOption( Options, Pair ) )
    	{
    		GetKeyValue( Pair, Key, Value );
    		if( Key ~= InKey )
    			return Value;
    	}
    	return "";
    }

    //
    // HasOption - return true if the option is specified on the command line.
    //
    function bool HasOption( string Options, string InKey )
    {
        local string Pair, Key, Value;
        while( GrabOption( Options, Pair ) )
        {
            GetKeyValue( Pair, Key, Value );
            if( Key ~= InKey )
                return true;
        }
        return false;
    }

    /* Initialize the game.
     The GameInfo's InitGame() function is called before any other scripts (including
     PreBeginPlay() ), and is used by the GameInfo to initialize parameters and spawn
     its helper classes.
     Warning: this is called before actors' PreBeginPlay.
    */
    event InitGame( string Options, out string Error )
    {
    	local string InOpt, LeftOpt;
    	local int pos;
    	local class<AccessControl> ACClass;
    	local class<GameRules> GRClass;
    	local class<BroadcastHandler> BHClass;

    	log( "InitGame:" @ Options );

        MaxPlayers = Clamp(GetIntOption( Options, "MaxPlayers", MaxPlayers ),0,32);
        MaxSpectators = Clamp(GetIntOption( Options, "MaxSpectators", MaxSpectators ),0,32);
        GameDifficulty = FMax(0,GetIntOption(Options, "Difficulty", GameDifficulty));

    	InOpt = ParseOption( Options, "GameSpeed");
    	if( InOpt != "" )
    	{
    		log("GameSpeed"@InOpt);
    		SetGameSpeed(float(InOpt));
    	}

        AddMutator(MutatorClass);

    	BHClass = class<BroadcastHandler>(DynamicLoadObject(BroadcastHandlerClass,Class'Class'));
    	BroadcastHandler = spawn(BHClass);

    	InOpt = ParseOption( Options, "AccessControl");
    	if( InOpt != "" )
    		ACClass = class<AccessControl>(DynamicLoadObject(InOpt, class'Class'));
        if ( ACClass == None )
    	{
    		ACClass = class<AccessControl>(DynamicLoadObject(AccessControlClass, class'Class'));
    		if (ACClass == None)
    			ACClass = class'Engine.AccessControl';
    	}

    	LeftOpt = ParseOption( Options, "AdminName" );
    	InOpt = ParseOption( Options, "AdminPassword");
    	if( LeftOpt!="" && InOpt!="" )
    		ACClass.default.bDontAddDefaultAdmin = true;

    	AccessControl = Spawn(ACClass);
    	if (AccessControl != None && LeftOpt!="" && InOpt!="" )
            AccessControl.SetAdminFromURL(LeftOpt, InOpt);

    	InOpt = ParseOption( Options, "GameRules");
    	if ( InOpt != "" )
    	{
    		log("Game Rules"@InOpt);
    		while ( InOpt != "" )
    		{
    			pos = InStr(InOpt,",");
    			if ( pos > 0 )
    			{
    				LeftOpt = Left(InOpt, pos);
    				InOpt = Right(InOpt, Len(InOpt) - pos - 1);
    			}
    			else
    			{
    				LeftOpt = InOpt;
    				InOpt = "";
    			}
    			log("Add game rules "$LeftOpt);
    			GRClass = class<GameRules>(DynamicLoadObject(LeftOpt, class'Class'));
    			if ( GRClass != None )
    			{
    				if ( GameRulesModifiers == None )
    					GameRulesModifiers = Spawn(GRClass);
    				else
    					GameRulesModifiers.AddGameRules(Spawn(GRClass));
    			}
    		}
    	}

    	log("Base Mutator is "$BaseMutator);

    	InOpt = ParseOption( Options, "Mutator");
    	if ( InOpt != "" )
    	{
    		log("Mutators"@InOpt);
    		while ( InOpt != "" )
    		{
    			pos = InStr(InOpt,",");
    			if ( pos > 0 )
    			{
    				LeftOpt = Left(InOpt, pos);
    				InOpt = Right(InOpt, Len(InOpt) - pos - 1);
    			}
    			else
    			{
    				LeftOpt = InOpt;
    				InOpt = "";
    			}
    			log("Add mutator "$LeftOpt);
                AddMutator(LeftOpt, true);
    		}
    	}

    	InOpt = ParseOption( Options, "GamePassword");
    	if( InOpt != "" )
    	{
    		AccessControl.SetGamePassWord(InOpt);
    		log( "GamePassword" @ InOpt );
    	}

        InOpt = ParseOption( Options,"AllowThrowing");
        if ( InOpt != "" )
        	bAllowWeaponThrowing = bool (InOpt);

    	InOpt = ParseOption( Options,"AllowBehindview");
        if ( InOpt != "" )
        	bAllowBehindview = bool ( InOpt);

    	InOpt = ParseOption(Options, "GameStats");
    	if ( InOpt != "")
    		bEnableStatLogging = bool(InOpt);
    	else
    		bEnableStatLogging = false;

    	log("GameInfo::InitGame : bEnableStatLogging"@bEnableStatLogging);

    	if( HasOption(Options, "DemoRec") )
    		Log( Level.ConsoleCommand("demorec"@ParseOption(Options, "DemoRec")) );

    #if IG_TRIBES3_VOTING   // glenn: voting support

        //log("**** voting initialization ****", 'voting');

    	// Voting handler requires maplist manager to be configured

        InitMaplistHandler();

    	InOpt = ParseOption( Options, "VotingHandler");
        if( InOpt != "" )
        {
            VotingHandlerClass = class<VotingHandler>(DynamicLoadObject(InOpt, class'Class'));
            //log("setting voting handler class from options: "$VotingHandlerClass, 'voting');
        }

    	if( VotingHandlerClass == None )
    	{
       		if( VotingHandlerType != "" )
       		{
       		    //log("setting voting handler class to type: "$VotingHandlerType, 'voting');

       			VotingHandlerClass = class<VotingHandler>(DynamicLoadObject(VotingHandlerType, class'Class'));
       	    }
       		else
       		{
       		    //log("dropping back to Engine.VotingHandler", 'voting');

    			VotingHandlerClass = class<VotingHandler>(DynamicLoadObject("Engine.VotingHandler", class'Class'));
    		}
        }

    	class'Engine.GameInfo'.default.VotingHandlerClass = VotingHandlerClass;

    	if( Level.NetMode != NM_StandAlone )
    	{
    		VotingHandler = Spawn(VotingHandlerClass);

    		//log("spawned voting handler: "$VotingHandler);

    		if(VotingHandler == none)
    			log("WARNING: Failed to spawn VotingHandler");
    	}
    	else
    	{
    	    log("standalone server: not spawning voting stuff", 'voting');
    	}

    #endif
    }

    function AddMutator(string mutname, optional bool bUserAdded)
    {
        local class<Mutator> mutClass;
        local Mutator mut;

        mutClass = class<Mutator>(DynamicLoadObject(mutname, class'Class'));
        if (mutClass == None)
            return;

    	if ( (mutClass.Default.GroupName != "") && (BaseMutator != None) )
    	{
    		// make sure no mutators with same groupname
    		for ( mut=BaseMutator; mut!=None; mut=mut.NextMutator )
    			if ( mut.GroupName == mutClass.Default.GroupName )
    				return;
    	}

        mut = Spawn(mutClass);
    	// mc, beware of mut being none
    	if (mut == None)
    		return;

    	// Meant to verify if this mutator was from Command Line parameters or added from other Actors
    	mut.bUserAdded = bUserAdded;

        if (BaseMutator == None)
            BaseMutator = mut;
        else
            BaseMutator.AddMutator(mut);
    }

    //
    // Return beacon text for serverbeacon.
    //
    event string GetBeaconText()
    {
    	return
    		Level.ComputerName
        $   " "
        $   Left(Level.Title,24)
        $   "\\t"
        $   BeaconName
        $   "\\t"
        $   GetNumPlayers()
    	$	"/"
    	$	MaxPlayers;
    }

    /* ProcessServerTravel()
     Optional handling of ServerTravel for network games.
    */
    function ProcessServerTravel( string URL, bool bItems )
    {
    	local playercontroller P, LocalPlayer;

        // Pass it along
        BaseMutator.ServerTraveling(URL,bItems);

    	EndLogging("mapchange");

    	// Notify clients we're switching level and give them time to receive.
    	// We call PreClientTravel directly on any local PlayerPawns (ie listen server)
    	log("ProcessServerTravel:"@URL);
    	foreach DynamicActors( class'PlayerController', P )
    		if( NetConnection( P.Player)!=None )
    			P.ClientTravel( URL, TRAVEL_Relative, bItems );
    		else
    		{
    			LocalPlayer = P;
    			P.PreClientTravel();
    		}

    	if ( (Level.NetMode == NM_ListenServer) && (LocalPlayer != None) )
            Level.NextURL = Level.NextURL
    					 $"?Team="$LocalPlayer.GetDefaultURL("Team")
    					 $"?Name="$LocalPlayer.GetDefaultURL("Name")
                         $"?Class="$LocalPlayer.GetDefaultURL("Class")
                         $"?Character="$LocalPlayer.GetDefaultURL("Character");

    #if IG_TRIBES3 // dbeswick: save game type between maps unless game type already specified
    	if ( Level.NetMode != NM_Client && InStr(Level.NextUrl, "?Game=") < 0 && InStr(Level.NextUrl, "?game=") < 0 )
    	{
    		Level.NextURL $= "?Game="$Class.Outer.Name$"."$Class.Name;
    	}
    #endif

    	 // Switch immediately if not networking.
    	if( Level.NetMode!=NM_DedicatedServer && Level.NetMode!=NM_ListenServer )
    		Level.NextSwitchCountdown = 0.0;
    }

    //
    // Accept or reject a player on the server.
    // Fails login if you set the Error to a non-empty string.
    //
    event PreLogin
    (
    	string Options,
    	string Address,
    	out string Error,
    	out string FailCode
    )
    {
    	local bool bSpectator;

        bSpectator = ( ParseOption( Options, "SpectatorOnly" ) ~= "true" );
    	AccessControl.PreLogin(Options, Address, Error, FailCode, bSpectator);
    }

    function int GetIntOption( string Options, string ParseString, int CurrentValue)
    {
    	local string InOpt;

    	InOpt = ParseOption( Options, ParseString );
    	if ( InOpt != "" )
    	{
    		log(ParseString@InOpt);
    		return int(InOpt);
    	}
    	return CurrentValue;
    }

    function bool AtCapacity(bool bSpectator)
    {
    	if ( Level.NetMode == NM_Standalone )
    		return false;

    	if ( bSpectator )
    		return ( (NumSpectators >= MaxSpectators)
    			&& ((Level.NetMode != NM_ListenServer) || (NumPlayers > 0)) );
    	else
    		return ( (MaxPlayers>0) && (NumPlayers>=MaxPlayers) );
    }

    //
    // Log a player in.
    // Fails login if you set the Error string.
    // PreLogin is called before Login, but significant game time may pass before
    // Login is called, especially if content is downloaded.
    //
    event PlayerController Login
    (
    	string Portal,
    	string Options,
    	out string Error
    )
    {
    	local Actor StartSpot;
    	local PlayerController NewPlayer;
    	local Pawn      TestPawn;
        local string          InName, InAdminName, InPassword, InChecksum, InClass, InCharacter;
    	local byte            InTeam;
        local bool bSpectator, bAdmin;
        local class<Security> MySecurityClass;

        bSpectator = ( ParseOption( Options, "SpectatorOnly" ) ~= "true" );
    	bAdmin = AccessControl.CheckOptionsAdmin(Options);

        // Make sure there is capacity except for admins. (This might have changed since the PreLogin call).
        if ( !bAdmin && AtCapacity(bSpectator) )
    	{
    		Error=GameMessageClass.Default.MaxedOutMessage;
    		return None;
    	}

    	// If admin, force spectate mode if the server already full of reg. players
    	if ( bAdmin && AtCapacity(false))
    		bSpectator = true;

    	BaseMutator.ModifyLogin(Portal, Options);

    	// Get URL options.
    	InName     = Left(ParseOption ( Options, "Name"), 20);
    	InTeam     = GetIntOption( Options, "Team", 255 ); // default to "no team"
        InAdminName= ParseOption ( Options, "AdminName");
    	InPassword = ParseOption ( Options, "Password" );
    	InChecksum = ParseOption ( Options, "Checksum" );

    	log( "Login:" @ InName );

    	// Pick a team (if need teams)
        InTeam = PickTeam(InTeam,None);

    	// Find a start spot.
    	StartSpot = FindPlayerStart( None, InTeam, Portal );

    	if( StartSpot == None )
    	{
    		Error = GameMessageClass.Default.FailedPlaceMessage;
    		return None;
    	}

    		if ( PlayerControllerClass == None )
    			PlayerControllerClass = class<PlayerController>(DynamicLoadObject(PlayerControllerClassName, class'Class'));

    		NewPlayer = spawn(PlayerControllerClass,,,StartSpot.Location,StartSpot.Rotation);

    	// Handle spawn failure.
    	if( NewPlayer == None )
    	{
    		log("Couldn't spawn player controller of class "$PlayerControllerClass);
    		Error = GameMessageClass.Default.FailedSpawnMessage;
    		return None;
    	}

    	NewPlayer.StartSpot = StartSpot;

        // Init player's replication info
        NewPlayer.GameReplicationInfo = GameReplicationInfo;
    	NewPlayer.GotoState('Spectating');

    	// Apply security to this controller

    	MySecurityClass=class<Security>(DynamicLoadObject(SecurityClass,class'class'));
        if (MySecurityClass!=None)
        {
    		NewPlayer.PlayerSecurity = spawn(MySecurityClass,NewPlayer);
    	    if (NewPlayer.PlayerSecurity==None)
    		    log("Could not spawn security for player "$NewPlayer,'Security');
        }
        else
    	    log("Unknown security class ["$SecurityClass$"] -- System is no secure.",'Security');

    	// Init player's name
    	if( InName=="" )
    		InName=DefaultPlayerName;
    	if( Level.NetMode!=NM_Standalone || NewPlayer.PlayerReplicationInfo.PlayerName==DefaultPlayerName )
    		ChangeName( NewPlayer, InName, false );

        if ( bSpectator || NewPlayer.PlayerReplicationInfo.bOnlySpectator )
    	{
            NewPlayer.PlayerReplicationInfo.bOnlySpectator = true;
    		NewPlayer.PlayerReplicationInfo.bIsSpectator = true;
            NewPlayer.PlayerReplicationInfo.bOutOfLives = true;
    		NumSpectators++;
    		return NewPlayer;
    	}

    	// Change player's team.
        if ( !ChangeTeam(newPlayer, InTeam, false) )
    	{
    		Error = GameMessageClass.Default.FailedTeamMessage;
    		return None;
    	}
    	newPlayer.StartSpot = StartSpot;

        // Init player's administrative privileges and log it
        if (AccessControl.AdminLogin(NewPlayer, InAdminName, InPassword))
        {
    		AccessControl.AdminEntered(NewPlayer, InAdminName);
        }

    	// Set the player's ID.
    	NewPlayer.PlayerReplicationInfo.PlayerID = CurrentID++;

    	if ( InClass == "" )
    	InClass = ParseOption( Options, "Class" );

        if (InClass == "")
            InClass = DefaultPlayerClassName;
        InCharacter = ParseOption(Options, "Character");
        NewPlayer.SetPawnClass(InClass, InCharacter);

    	NumPlayers++;
        bWelcomePending = true;

    	// if delayed start, don't give a pawn to the player yet
    	// Normal for multiplayer games
    	if ( bDelayedStart )
    	{
    		NewPlayer.GotoState('PlayerWaiting');
    		return NewPlayer;
    	}

    	// Try to match up to existing unoccupied player in level,
    	// for savegames and coop level switching.
    	ForEach DynamicActors(class'Pawn', TestPawn )
    	{
    		if ( (TestPawn!=None) && (PlayerController(TestPawn.Controller)!=None) && (PlayerController(TestPawn.Controller).Player==None) && (TestPawn.Health > 0)
    			&&  (TestPawn.OwnerName~=InName) )
    		{
    			NewPlayer.Destroy();
    			TestPawn.SetRotation(TestPawn.Controller.Rotation);
    			TestPawn.bInitializeAnimation = false; // FIXME - temporary workaround for lack of meshinstance serialization
    			TestPawn.PlayWaiting();
    			return PlayerController(TestPawn.Controller);
    		}
    	}

    	return newPlayer;
    }

    /* StartMatch()
    Start the game - inform all actors that the match is starting, and spawn player pawns
    */
    function StartMatch()
    {
    	local Controller P;
    	local Actor A;

    	if (GameStats!=None)
    		GameStats.StartGame();

    	// tell all actors the game is starting
    	ForEach AllActors(class'Actor', A)
    		A.MatchStarting();

    	// start human players first
    	for ( P = Level.ControllerList; P!=None; P=P.nextController )
    		if ( P.IsA('PlayerController') && (P.Pawn == None) )
    		{
                if ( bGameEnded )
                    return; // telefrag ended the game with ridiculous frag limit
                else if ( PlayerController(P).CanRestartPlayer()  )
    				RestartPlayer(P);
    		}

    	// start AI players
    	for ( P = Level.ControllerList; P!=None; P=P.nextController )
    		if ( P.bIsPlayer && !P.IsA('PlayerController') )
            {
    			if ( Level.NetMode == NM_Standalone )
    			RestartPlayer(P);
            	else
    				P.GotoState('Dead','MPStart');
    		}

    	bWaitingToStartMatch = false;
    	GameReplicationInfo.bMatchHasBegun = true;
    }

    //
    // Restart a player.
    //
    function RestartPlayer( Controller aPlayer )
    {
    	local Actor startSpot;
    	local int TeamNum;
    	local class<Pawn> DefaultPlayerClass;

    	if( bRestartLevel && Level.NetMode!=NM_DedicatedServer && Level.NetMode!=NM_ListenServer )
    		return;

    #if !IG_TRIBES3 // david: not using Unreal team object
    	if ( (aPlayer.PlayerReplicationInfo == None) || (aPlayer.PlayerReplicationInfo.Team == None) )
    		TeamNum = 255;
    	else
    		TeamNum = aPlayer.PlayerReplicationInfo.Team.TeamIndex;
    #endif

    	startSpot = FindPlayerStart(aPlayer, TeamNum);
    	if( startSpot == None )
    	{
    		log(" Player start not found!!!");
    		return;
    	}

    	if (aPlayer.PreviousPawnClass!=None && aPlayer.PawnClass != aPlayer.PreviousPawnClass)
    		BaseMutator.PlayerChangedClass(aPlayer);

    	if ( aPlayer.PawnClass != None )
    		aPlayer.Pawn = Spawn(aPlayer.PawnClass,,,StartSpot.Location,StartSpot.Rotation);

    	if( aPlayer.Pawn==None )
    	{
            DefaultPlayerClass = GetDefaultPlayerClass(aPlayer);
    		aPlayer.Pawn = Spawn(DefaultPlayerClass,,,StartSpot.Location,StartSpot.Rotation);
    	}
    	if ( aPlayer.Pawn == None )
    	{
    		log("Couldn't spawn player of type "$aPlayer.PawnClass$" at "$StartSpot);
    #if IG_SHARED
            AssertWithDescription(false,
    		"Couldn't spawn a player of class "$aPlayer.PawnClass$" at start point "$StartSpot);
    #endif
    		aPlayer.GotoState('Dead');
    		return;
    	}

        aPlayer.Pawn.Anchor = NavigationPoint(startSpot);
    	aPlayer.Pawn.LastStartSpot = PlayerStart(startSpot);
    	aPlayer.Pawn.LastStartTime = Level.TimeSeconds;
    	aPlayer.PreviousPawnClass = aPlayer.Pawn.Class;

    	aPlayer.Possess(aPlayer.Pawn);
    	aPlayer.PawnClass = aPlayer.Pawn.Class;

        aPlayer.Pawn.PlayTeleportEffect(true, true);
    	aPlayer.ClientSetRotation(aPlayer.Pawn.Rotation);
    	AddDefaultInventory(aPlayer.Pawn);
    	TriggerEvent( StartSpot.Event, StartSpot, aPlayer.Pawn);
    }

    function class<Pawn> GetDefaultPlayerClass(Controller C)
    {
        local PlayerController PC;
        local String PawnClassName;
        local class<Pawn> PawnClass;

        PC = PlayerController( C );

        if( PC != None )
    {
            PawnClassName = PC.GetDefaultURL( "Class" );
            PawnClass = class<Pawn>( DynamicLoadObject( PawnClassName, class'Class') );

            if( PawnClass != None )
                return( PawnClass );
    }

        return( class<Pawn>( DynamicLoadObject( DefaultPlayerClassName, class'Class' ) ) );
    }

    //
    // Called after a successful login. This is the first place
    // it is safe to call replicated functions on the PlayerPawn.
    //
    event PostLogin( PlayerController NewPlayer )
    {
        local class<HUD> HudClass;
        local class<Scoreboard> ScoreboardClass;
        local String SongName;

        // Log player's login.
    	if (GameStats!=None)
    	{
    		GameStats.ConnectEvent(NewPlayer.PlayerReplicationInfo);
    		GameStats.GameEvent("NameChange",NewPlayer.PlayerReplicationInfo.playername,NewPlayer.PlayerReplicationInfo);
    	}

    	if ( !bDelayedStart )
    	{
    		// start match, or let player enter, immediately
    		bRestartLevel = false;	// let player spawn once in levels that must be restarted after every death
    		bKeepSamePlayerStart = true;
    		if ( bWaitingToStartMatch )
    			StartMatch();
    		else
    		{
    #if IG_TRIBES3	// karl: This check makes savegame correctly restore players
    			if ( NewPlayer.IsA('PlayerController') && (NewPlayer.Pawn == None) )
    #endif
    			RestartPlayer(newPlayer);
    		}
    		bKeepSamePlayerStart = false;
    		bRestartLevel = Default.bRestartLevel;
    	}

    	// Start player's music.
        SongName = Level.Song;
        if( SongName != "" && SongName != "None" )
            NewPlayer.ClientSetMusic( SongName, MTRAN_Fade );

    	// tell client what hud and scoreboard to use

        if( HUDType != "" )
            HudClass = class<HUD>(DynamicLoadObject(HUDType, class'Class'));

        if( ScoreBoardType != "" )
            ScoreboardClass = class<Scoreboard>(DynamicLoadObject(ScoreBoardType, class'Class'));

    #if !IG_TRIBES3 // Alex: stomps on HUD set in PlayerCharacterController.Possess
        NewPlayer.ClientSetHUD( HudClass );
    #endif

    	if ( NewPlayer.Pawn != None )
    		NewPlayer.Pawn.ClientSetRotation(NewPlayer.Pawn.Rotation);

    #if IG_TRIBES3_VOTING   // glenn: voting support
    	if( VotingHandler != None )
    	{
    	    //log("PostLogin: votingHandler.PlayerJoint", 'voting');
    		VotingHandler.PlayerJoin(NewPlayer);
        }
        else
        {
    	    log("PostLogin: null voting handler", 'voting');
        }
    #endif

    #if IG_TRIBES3	// michaelj:  Integrated UT2004 admin login
    	if ( AccessControl != None )
    		NewPlayer.LoginDelay = AccessControl.LoginDelaySeconds;
    #endif

    #if IG_SHARED
    	PlayerLoggedIn(NewPlayer);
    #endif
    }

    #if IG_SHARED
    function PlayerLoggedIn(PlayerController NewPlayer);
    #endif

    //
    // Player exits.
    //
    function Logout( Controller Exiting )
    {
    	local bool bMessage;
    	local int Index;

    	bMessage = true;
    	if ( PlayerController(Exiting) != None )
    	{
    		if ( AccessControl.AdminLogout( PlayerController(Exiting) ) )
    			AccessControl.AdminExited( PlayerController(Exiting) );

            if ( PlayerController(Exiting).PlayerReplicationInfo.bOnlySpectator )
    		{
    			bMessage = false;
    				NumSpectators--;
    		}
    		else
            {
    			NumPlayers--;
            }

    		if( Level.NetMode != NM_Standalone )
    		{
    			for( Index=0; Index<VoiceChatters.Length; Index++ )
    			{
    				if( VoiceChatters[Index].Controller == Exiting )
    				{
    					ChangeVoiceChatter( PlayerController(Exiting), VoiceChatters[Index].IpAddr, VoiceChatters[Index].Handle, false );
    				}
    			}
    		}

    		if( Level.NetMode == NM_Client )
    		{
    			PlayerController(Exiting).ClientLeaveVoiceChat();
    		}
    	}
    	if( bMessage && (Level.NetMode==NM_DedicatedServer || Level.NetMode==NM_ListenServer) )
    		BroadcastLocalizedMessage(GameMessageClass, 4, Exiting.PlayerReplicationInfo);

    #if IG_TRIBES3_VOTING   // glenn: voting support
    	if( VotingHandler != None )
    	{
    		VotingHandler.PlayerExit(Exiting);
    		//log("Logout: votingHandler.playerExit", 'voting');
    	}
    	else
    	{
    	    log("Logout: votingHandler is none", 'voting');
    	}
    #endif

    	if ( GameStats!=None)
    		GameStats.DisconnectEvent(Exiting.PlayerReplicationInfo);
    }

    //
    // Examine the passed player's inventory, and accept or discard each item.
    // AcceptInventory needs to gracefully handle the case of some inventory
    // being accepted but other inventory not being accepted (such as the default
    // weapon).  There are several things that can go wrong: A weapon's
    // AmmoType not being accepted but the weapon being accepted -- the weapon
    // should be killed off. Or the player's selected inventory item, active
    // weapon, etc. not being accepted, leaving the player weaponless or leaving
    // the HUD inventory rendering messed up (AcceptInventory should pick another
    // applicable weapon/item as current).
    //
    event AcceptInventory(pawn PlayerPawn)
    {
    	//default accept all inventory except default weapon (spawned explicitly)
    }

    function AddGameSpecificInventory(Pawn p)
    {
    /*
        local Weapon newWeapon;
        local class<Weapon> WeapClass;
        local Inventory Inv;

        // Spawn default weapon.
        WeapClass = BaseMutator.GetDefaultWeapon();
        if( (WeapClass!=None) && (p.FindInventoryType(WeapClass)==None) )
        {
            newWeapon = Spawn(WeapClass,,,p.Location);
            if( newWeapon != None )
            {
                Inv = None;
                // search pawn's inventory for a bCanThrowWeapon==false, if we find one, don't call Bringup
                for( Inv=Inventory; Inv!=None; Inv=Inv.Inventory )
                {
                    if ( Inv.IsA('Weapon') && Weapon(Inv).bCanThrow==false )
                        break;
                }
                newWeapon.GiveTo(p);
                newWeapon.bCanThrow = false; // don't allow default weapon to be thrown out
            }
        }
        */
    }

    //
    // Spawn any default inventory for the player.
    //
    function AddDefaultInventory( pawn PlayerPawn )
    {
    /*
    	local Weapon newWeapon;
    	local class<Weapon> WeapClass;

    	// Spawn default weapon.
    	WeapClass = BaseMutator.GetDefaultWeapon();
    	if( (WeapClass!=None) && (PlayerPawn.FindInventoryType(WeapClass)==None) )
    	{
    		newWeapon = Spawn(WeapClass,,,PlayerPawn.Location);
    		if( newWeapon != None )
    		{
    			newWeapon.GiveTo(PlayerPawn);
                //newWeapon.BringUp();
    			newWeapon.bCanThrow = false; // don't allow default weapon to be thrown out
    		}
    	}
    	SetPlayerDefaults(PlayerPawn);
    	*/
    }

    /* SetPlayerDefaults()
     first make sure pawn properties are back to default, then give mutators an opportunity
     to modify them
    */
    function SetPlayerDefaults(Pawn PlayerPawn)
    {
    	PlayerPawn.AirControl = PlayerPawn.Default.AirControl;
        PlayerPawn.GroundSpeed = PlayerPawn.Default.GroundSpeed;
        PlayerPawn.WaterSpeed = PlayerPawn.Default.WaterSpeed;
        PlayerPawn.AirSpeed = PlayerPawn.Default.AirSpeed;
        PlayerPawn.Acceleration = PlayerPawn.Default.Acceleration;
        PlayerPawn.JumpZ = PlayerPawn.Default.JumpZ;
    	BaseMutator.ModifyPlayer(PlayerPawn);
    }

    function NotifyKilled(Controller Killer, Controller Killed, Pawn KilledPawn )
    {
    #if IG_SHARED
    	local Pawn P;
    	for( P=Level.PawnList; P!=None; P=P.nextPawn )
    	{
    		if ( class'Pawn'.static.checkAlive( P ) )
    		P.NotifyKilled(Killer, Killed, KilledPawn);
    	}
    #else
    	local Controller C;

    	for ( C=Level.ControllerList; C!=None; C=C.nextController )
    		C.NotifyKilled(Killer, Killed, KilledPawn);
    #endif
    }

    function KillEvent(string Killtype, PlayerReplicationInfo Killer, PlayerReplicationInfo Victim, class<DamageType> Damage)
    {
    	if ( GameStats != None )
    		GameStats.KillEvent(KillType, Killer, Victim, Damage);
    }

    function Killed( Controller Killer, Controller Killed, Pawn KilledPawn, class<DamageType> damageType )
    {
        if ( (Killed != None) && Killed.bIsPlayer )
    	{
    		Killed.PlayerReplicationInfo.Deaths += 1;
    		BroadcastDeathMessage(Killer, Killed, damageType);

    		if ( (Killer == Killed) || (Killer == None) )
    		{
    			if ( Killer == None )
    				KillEvent("K", None, Killed.PlayerReplicationInfo, DamageType);	//"Kill"
    			else
    				KillEvent("K", Killer.PlayerReplicationInfo, Killed.PlayerReplicationInfo, DamageType);	//"Kill"
    		}
    		else
    		{
    #if !IG_TRIBES3 // david: not using Unreal team object
    			if ( bTeamGame && (Killer.PlayerReplicationInfo != None)
    				&& (Killer.PlayerReplicationInfo.Team == Killed.PlayerReplicationInfo.Team) )
    				KillEvent("TK", Killer.PlayerReplicationInfo, Killed.PlayerReplicationInfo, DamageType);	//"Teamkill"
    			else
    #endif
    				KillEvent("K", Killer.PlayerReplicationInfo, Killed.PlayerReplicationInfo, DamageType);	//"Kill"
    		}
    	}
        if ( Killed != None )
    	ScoreKill(Killer, Killed);
    	DiscardInventory(KilledPawn);
        NotifyKilled(Killer,Killed,KilledPawn);
    }

    function bool PreventDeath(Pawn Killed, Controller Killer, class<DamageType> damageType, vector HitLocation)
    {
    	if ( GameRulesModifiers == None )
    		return false;
    	return GameRulesModifiers.PreventDeath(Killed,Killer, damageType,HitLocation);
    }

    function bool PreventSever(Pawn Killed,  Name boneName, int Damage, class<DamageType> DamageType)
    {
        if ( GameRulesModifiers == None )
            return false;
        return GameRulesModifiers.PreventSever(Killed, boneName, Damage, DamageType);
    }

    function BroadcastDeathMessage(Controller Killer, Controller Other, class<DamageType> damageType)
    {
    	if ( (Killer == Other) || (Killer == None) )
            BroadcastLocalized(self,DeathMessageClass, 1, None, Other.PlayerReplicationInfo, damageType);
    	else
            BroadcastLocalized(self,DeathMessageClass, 0, Killer.PlayerReplicationInfo, Other.PlayerReplicationInfo, damageType);
    }

    // %k = Owner's PlayerName (Killer)
    // %o = Other's PlayerName (Victim)
    // %w = Owner's Weapon ItemName
    static native function string ParseKillMessage( string KillerName, string VictimName, string DeathMessage );

    function Kick( string S )
    {
    	AccessControl.Kick(S);
    }

    function KickBan( string S )
    {
    	AccessControl.KickBan(S);
    }

    function bool IsOnTeam(Controller Other, int TeamNum)
    {
    #if !IG_TRIBES3 // david: not using Unreal team object
        if ( bTeamGame && (Other != None) && Other.bIsPlayer
    		&& (Other.PlayerReplicationInfo.Team != None)
    		&& (Other.PlayerReplicationInfo.Team.TeamIndex == TeamNum) )
    		return true;
    #endif
    	return false;
    }

    //-------------------------------------------------------------------------------------
    // Level gameplay modification.

    //
    // Return whether Viewer is allowed to spectate from the
    // point of view of ViewTarget.
    //
    function bool CanSpectate( PlayerController Viewer, bool bOnlySpectator, actor ViewTarget )
    {
    	return true;
    }

    /* Use reduce damage for teamplay modifications, etc.
    */
    function int ReduceDamage( int Damage, pawn injured, pawn instigatedBy, vector HitLocation, out vector Momentum, class<DamageType> DamageType )
    {
    	local int OriginalDamage;

    	OriginalDamage = Damage;

    	if( injured.PhysicsVolume.bNeutralZone )
    		Damage = 0;
    	else if ( injured.InGodMode() ) // God mode
    		return 0;

    	if ( GameRulesModifiers != None )
    		return GameRulesModifiers.NetDamage( OriginalDamage, Damage,injured,instigatedBy,HitLocation,Momentum,DamageType );

    	return Damage;
    }

    /* Discard a player's inventory after he dies.
    */
    function DiscardInventory( Pawn Other )
    {
    /*
    	Other.Weapon = None;
    	Other.SelectedItem = None;
        while ( Other.Inventory != None )
            Other.Inventory.Destroy();
     */
    }

    /* Try to change a player's name.
    */
    function ChangeName( Controller Other, coerce string S, bool bNameChange )
    {
    	local Controller C;

    	if( S == "" )
    		return;

    	Other.PlayerReplicationInfo.SetPlayerName(S);
        // notify local players
        if ( bNameChange )
    		for ( C=Level.ControllerList; C!=None; C=C.NextController )
    			if ( (PlayerController(C) != None) && (Viewport(PlayerController(C).Player) != None) )
    				PlayerController(C).ReceiveLocalizedMessage( class'GameMessage', 2, Other.PlayerReplicationInfo );
    }

    /* Return whether a team change is allowed.
    */
    function bool ChangeTeam(Controller Other, int N, bool bNewTeam)
    {
    	return true;
    }

    /* Return a picked team number if none was specified
    */
    function byte PickTeam(byte Current, Controller C)
    {
    	return Current;
    }

    /* Send a player to a URL.
    */
    function SendPlayer( PlayerController aPlayer, string URL )
    {
    	aPlayer.ClientTravel( URL, TRAVEL_Relative, true );
    }

    // VOTING TODO - integrate "FillPlayInfo" if required in GameInfo.uc

    /* Restart the game.
    */
    function RestartGame()
    {
    	local string NextMap;
        local MapList MyList;

    	if ( (GameRulesModifiers != None) && GameRulesModifiers.HandleRestartGame() )
    		return;

    	if ( bGameRestarted )
    		return;
        bGameRestarted = true;

    #ifdef IG_TRIBES3_VOTING    // glenn: voting support
    	// allow voting handler to stop travel to next map
        if ( VotingHandler != None && !VotingHandler.HandleRestartGame() )
            return;
    #endif

    	// these server travels should all be relative to the current URL
    	if ( bChangeLevels && !bAlreadyChanged && (MapListType != "") )
    	{
    #if IG_TRIBES3 // dbeswick: catch travel failures
    		bMapRotationTraveling = true;
    #endif
    		// open a the nextmap actor for this game type and get the next map
    		bAlreadyChanged = true;
            MyList = GetMapList(MapListType);
    		if (MyList != None)
    		{
    			NextMap = MyList.GetNextMap();
    			MyList.Destroy();
    		}
    		if ( NextMap == "" )
    			NextMap = GetMapName(MapPrefix, NextMap,1);

    		if ( NextMap != "" )
    		{
    			Level.ServerTravel(NextMap, false);
    			return;
    		}
    	}

    	Level.ServerTravel( "?Restart", false );
    }

    function MapList GetMapList(string MapListType)
    {
    local class<MapList> MapListClass;

    	if (MapListType != "")
    	{
            MapListClass = class<MapList>(DynamicLoadObject(MapListType, class'Class'));
    		if (MapListClass != None)
    			return Spawn(MapListClass);
    	}
    	return None;
    }

    //==========================================================================
    // Message broadcasting functions (handled by the BroadCastHandler)

    event Broadcast( Actor Sender, coerce string Msg, optional name Type )
    {
    	BroadcastHandler.Broadcast(Sender,Msg,Type);
    }

    function BroadcastTeam( Controller Sender, coerce string Msg, optional name Type )
    {
    	BroadcastHandler.BroadcastTeam(Sender,Msg,Type);
    }

    /*
     Broadcast a localized message to all players.
     Most message deal with 0 to 2 related PRIs.
     The LocalMessage class defines how the PRI's and optional actor are used.
    */
    #if IG_TRIBES3 // david: more flexibility in LocalMessage system, uses Objects instead of PlayerReplicationInfos

    event BroadcastLocalized( actor Sender, class<LocalMessage> Message, optional int Switch, optional Core.Object Related1, optional Core.Object Related2, optional Object OptionalObject, optional String OptionalString )
    {
    	BroadcastHandler.AllowBroadcastLocalized(Sender,Message,Switch,Related1,Related2,OptionalObject,OptionalString);
    }

    //
    // Paul: Added team only localized message broadcasting
    //
    event BroadcastLocalizedTeam( actor Sender, class<LocalMessage> Message, optional int Switch, optional Core.Object Related1, optional Core.Object Related2, optional Object OptionalObject, optional String OptionalString )
    {
    	BroadcastHandler.AllowBroadcastLocalizedTeam(Sender,Message,Switch,Related1,Related2,OptionalObject,OptionalString);
    }

    #else
    event BroadcastLocalized( actor Sender, class<LocalMessage> Message, optional int Switch, optional PlayerReplicationInfo RelatedPRI_1, optional PlayerReplicationInfo RelatedPRI_2, optional Object OptionalObject )
    {
    	BroadcastHandler.AllowBroadcastLocalized(Sender,Message,Switch,RelatedPRI_1,RelatedPRI_2,OptionalObject);
    }
    #endif

    //==========================================================================

    function bool CheckEndGame(PlayerReplicationInfo Winner, string Reason)
    {
    	local Controller P;

    	if ( (GameRulesModifiers != None) && !GameRulesModifiers.CheckEndGame(Winner, Reason) )
    		return false;

    	// all player cameras focus on winner or final scene (picked by gamerules)
    	for ( P=Level.ControllerList; P!=None; P=P.NextController )
    	{
    		P.ClientGameEnded();
            P.GameHasEnded();
    	}
    	return true;
    }

    /* End of game.
    */
    function EndGame( PlayerReplicationInfo Winner, string Reason )
    {
    	// don't end game if not really ready
    	if ( !CheckEndGame(Winner, Reason) )
    	{
    		bOverTime = true;
    		return;
    	}

    	bGameEnded = true;
    	TriggerEvent('EndGame', self, None);
    	EndLogging(Reason);
    }

    function EndLogging(string Reason)
    {

    	if (GameStats == None)
    		return;

    	GameStats.EndGame(Reason);
    	GameStats.Destroy();
    	GameStats = None;
    }

    /* Return the 'best' player start for this player to start from.
     */
    function Actor FindPlayerStart( Controller Player, optional byte InTeam, optional string incomingName )
    {
    	local PlayerStart N, BestStart;
    	local float NewRating, BestRating;
    	local Teleporter Tel;
    #if !IG_TRIBES3 // david: not using Unreal team object
    	local byte Team;
    #endif

    	// always pick StartSpot at start of match
        if ( (Player != None) && (Player.StartSpot != None) && (Level.NetMode == NM_Standalone)
    		&& (bKeepSamePlayerStart || bWaitingToStartMatch || ((Player.PlayerReplicationInfo != None) && Player.PlayerReplicationInfo.bWaitingPlayer))  )
    	{
    		return Player.StartSpot;
    	}

    	if ( GameRulesModifiers != None )
    	{
    		N = GameRulesModifiers.FindPlayerStart(Player,InTeam,incomingName);
    		if ( N != None )
    		    return N;
    	}

    	// if incoming start is specified, then just use it
    	if( incomingName!="" )
    		foreach AllActors( class 'Teleporter', Tel )
    			if( string(Tel.Tag)~=incomingName )
    				return Tel;

    	// use InTeam if player doesn't have a team yet
    #if !IG_TRIBES3 // david: not using Unreal team object
    	if ( (Player != None) && (Player.PlayerReplicationInfo != None) )
    	{
    		if ( Player.PlayerReplicationInfo.Team != None )
    			Team = Player.PlayerReplicationInfo.Team.TeamIndex;
    		else
    			Team = 0;
    	}
    	else
    		Team = InTeam;
    #endif

    	foreach AllActors( class 'PlayerStart', N )
    		{
    			NewRating = RatePlayerStart(N,0,Player);
    			if ( NewRating > BestRating )
    			{
    				BestRating = NewRating;
    				BestStart = N;
    			}
    		}

    	return BestStart;
    }

    /* Rate whether player should choose this NavigationPoint as its start
    default implementation is for single player game
    */
    function float RatePlayerStart(PlayerStart P, byte Team, Controller Player)
    {
    	if ( P != None )
    	{
    		if ( P.bSinglePlayer )
    		{
    			if ( P.bEnabled )
    				return 1000;
    			return 20;
    		}
    		return 10;
    	}
    	return 0;
    }

    function ScoreObjective(PlayerReplicationInfo Scorer, Int Score)
    {
    	if ( Scorer != None )
    	{
    		Scorer.Score += Score;
            /*
    		if ( Scorer.Team != None )
    			Scorer.Team.Score += Score;
            */
    	}
    	if ( GameRulesModifiers != None )
    		GameRulesModifiers.ScoreObjective(Scorer,Score);

    	CheckScore(Scorer);
    }

    /* CheckScore()
    see if this score means the game ends
    */
    function CheckScore(PlayerReplicationInfo Scorer)
    {
    	if ( (GameRulesModifiers != None) && GameRulesModifiers.CheckScore(Scorer) )
    		return;
    }

    function ScoreEvent(PlayerReplicationInfo Who, float Points, string Desc)
    {
    	if (GameStats!=None)
    		GameStats.ScoreEvent(Who,Points,Desc);
    }

    function TeamScoreEvent(int Team, float Points, string Desc)
    {
    	if ( GameStats != None )
    		GameStats.TeamScoreEvent(Team, Points, Desc);
    }

    function ScoreKill(Controller Killer, Controller Other)
    {
    	if( (killer == Other) || (killer == None) )
    	{
        	if ( Other!=None && Other.PlayerReplicationInfo!= None )
            {
    		Other.PlayerReplicationInfo.Score -= 1;
    			ScoreEvent(Other.PlayerReplicationInfo,-1,"self_frag");
            }
    	}
    	else if ( killer.PlayerReplicationInfo != None )
    	{
    		Killer.PlayerReplicationInfo.Score += 1;
    		Killer.PlayerReplicationInfo.Kills++;
    		ScoreEvent(Killer.PlayerReplicationInfo,1,"frag");
    	}

    	if ( GameRulesModifiers != None )
    		GameRulesModifiers.ScoreKill(Killer, Other);

        if ( (Killer != None) || (MaxLives > 0) )
    	CheckScore(Killer.PlayerReplicationInfo);
    }

    function bool TooManyBots(Controller botToRemove)
    {
    	return false;
    }

    static function string FindTeamDesignation(GameReplicationInfo GRI, actor A)	// Should be subclassed in various team games
    {
    	return "";
    }

    // - Parse out % vars for various messages

    static function string ParseMessageString(Mutator BaseMutator, Controller Who, String Message)
    {
    	return Message;
    }

    function ReviewJumpSpots(name TestLabel);

    //function TeamInfo OtherTeam(TeamInfo Requester)
    //{
    //	return None;
    //}

    exec function KillBots(int num);

    exec function AdminSay(string Msg)
    {
    	local controller C;

    	for( C=Level.ControllerList; C!=None; C=C.nextController )
    		if( C.IsA('PlayerController') )
    		{
    			PlayerController(C).ClearProgressMessages();
    			PlayerController(C).SetProgressTime(6);
    			PlayerController(C).SetProgressMessage(0, Msg, class'Canvas'.Static.MakeColor(255,255,255));
    		}
    }

    #if !IG_TRIBES3	// rowan: not using this
    function RegisterVehicle(Vehicle V);
    #endif

    #if IG_TRIBES3 // dbeswick: catch travel failures
    event OnServerTravelFail(string URL)
    {
    	if (bMapRotationTraveling)
    	{
    		LOG("The URL "$URL$" failed to load during the map rotation: now trying next map in rotation.");
    		bGameRestarted = false;
    		RestartGame();
    	}
    }

    event OnServerTravelSuccess(string URL)
    {
    	bMapRotationTraveling = false;
    }
    #endif

    #if IG_TRIBES3 // dbeswick: added SaveAllowed function
    event bool SaveAllowed()
    {
    	return false;
    }
    #endif

    #if IG_TRIBES3 // dbeswick: to support ?restart after savegame
    // when ?restart is specified in a url, this function determines the map used for restart.
    // if it returns "" then the current URL is used by the engine.
    event string GetRestartMap()
    {
    	return "";
    }
    #endif

    defaultproperties
    {
    	bAdminCanPause=true
        bDelayedStart=true
    	HUDType="Engine.HUD"
    	bWaitingToStartMatch=false
    	bLoggingGame=False
    	MaxPlayers=16
        GameDifficulty=+1.0
        bRestartLevel=True
        bPauseable=True
        bCanChangeSkin=True
    	bCanViewOthers=true
        bChangeLevels=True
        AutoAim=0.930000
        GameSpeed=1.000000
        MaxSpectators=2
        DefaultPlayerName="Player"
    	GameName="Game"
    	MutatorClass="Engine.Mutator"
    	BroadcastHandlerClass="Engine.BroadcastHandler"
    	DeathMessageClass=class'LocalMessage'
    	GameStatsClass="Engine.GameStats"
    	bEnableStatLogging=false
    	bAllowWeaponThrowing=true
    	AccessControlClass="Engine.AccessControl"
    	PlayerControllerClassName="Engine.PlayerController"
    	GameMessageClass=class'GameMessage'
    	GameReplicationInfoClass=class'GameReplicationInfo'
        SecurityClass="Engine.Security"
        FearCostFalloff=+0.95
        Acronym="???"

    //#if IG_TRIBES3_VOTING     // glenn: voting support
    	VotingHandlerType="TribesVoting.TribesVotingHandler"
    //#endif
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: èt 9.9.2004 16:25:34.000 - Creation time: st 23.5.2018 00:10:43.485 - Created with UnCodeX