Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Tyrion.AI_Sensor

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431

    //=====================================================================
    // AI_Sensor
    // The Tyrion Sensor class
    //
    // A sensor that gets updated by calls to setxxxValue
    //=====================================================================

    class AI_Sensor extends Core.DeleteableObject implements ISensorNotification
    	native
    	abstract;

    //=====================================================================
    // Constants

    const ONLY_NONE_VALUE = 1;					// for object sensors: send message only when object value is None
    const ONLY_NON_NONE_VALUE = 2;				// for object sensors: send message only when object value is non-None

    //=====================================================================
    // Variables

    var AI_SensorAction sensorAction;			// the action that is updating this sensor
    var array<AI_SensorRecipient> recipients;	// actions/sensors who are waiting for messages from this sensor
    var AI_SensorData value;					// the value of the sensor
    var bool bNotifyOnValueChange;				// notify recipients only when the sensor value changes
    var bool bNotifyIfResourceInactive;			// notify even if resource is inactive

    //=====================================================================
    // Functions

    //---------------------------------------------------------------------
    // ISensorNotification implementation

    function OnSensorMessage( AI_Sensor sensor, AI_SensorData value, Object userData );

    function AI_Resource getResource()
    {
    	return sensorAction.resource;
    }

    //---------------------------------------------------------------------
    // Constructor

    overloaded function construct( AI_SensorAction action )
    {
    	sensorAction = action;
    	value = new class'AI_SensorData';
    }

    //---------------------------------------------------------------------
    // Create a new sensor (or find pre-existing one)
    // Called by runnableActions
    // 'action' is the action setting up the sensor
    // 'resource' is what resource the sensor is collecting data on (can be None)
    // 'lowerbound' and 'upperbound' specify the range of values the action is interested in
    //    (if 'upperbound' is not specified or 0, it is set to 'lowerbound')

    static function AI_Sensor activateSensor( ISensorNotification recipient,
    								   class<AI_Sensor> sensorClass,
    								   AI_Resource resource,
    								   optional float lowerBound,
    								   optional float upperBound,
    								   optional Object userData )
    {
    	return sensorClass.static.activateSensorInternal( sensorClass, resource, lowerBound, upperBound, userData, recipient );
    }

    //---------------------------------------------------------------------
    // Create a new sentinel (or find pre-existing one)
    // Called by goal construct's
    // 'goal' is the goal setting up the sensor
    // 'resource' is what resource the sensor is collecting data on (can be None)
    // 'lowerbound' and 'upperbound' specify the range of values the action is interested in
    //    (if 'upperbound' is not specified or 0, it is set to 'lowerbound')

    static function AI_Sensor activateSentinel( AI_Goal goal,
    									   class<AI_Sensor> sentinelClass,
    									   AI_Resource resource,
    									   optional float lowerBound,
    									   optional float upperBound,
    									   optional Object userData )
    {
    	return sentinelClass.static.activateSensorInternal( sentinelClass, resource, lowerBound, upperBound, userData, goal );
    }

    //---------------------------------------------------------------------
    // Remove a sensor
    // Called by RunnableActions when they are no longer interested in a sensor value

    function deactivateSensor( ISensorNotification recipient, optional float lowerBound, optional float upperBound )
    {
    	deactivateSensorInternal( recipient, lowerBound, upperBound );
    }

    //---------------------------------------------------------------------
    // Remove a sentinel
    // Called by goals when they are no longer interested in a sensor value

    function deactivateSentinel( AI_Goal goal, optional float lowerBound, optional float upperBound )
    {
    	deactivateSensorInternal( goal, lowerBound, upperBound );
    }

    //---------------------------------------------------------------------
    // perform sensor-specific startup initializations when sensor is first activated
    // (called from "activateSensor")

    function begin();

    //---------------------------------------------------------------------
    // perform sensor-specific cleanup when sensor has no more recipients

    function cleanup();

    //---------------------------------------------------------------------
    // Notify the action / goal that set up the sensor of sensor's value

    protected function sendSensorMessage( AI_SensorRecipient recipient, AI_SensorData value )
    {
    	//log( "1. Sending sensor message to" @ recipient.recipient.name @ "(" @ recipient.recipient.getResource().name @ ")" );
    	if ( bNotifyIfResourceInactive || recipient.recipient.getResource().isActive() )
    	{
    		//log( "2. Sending sensor message to" @ recipient.recipient.name @ "(" @ recipient.recipient.getResource().name @ ")" );
    		recipient.recipient.onSensorMessage( self, value, recipient.userData );
    	}
    }

    //---------------------------------------------------------------------
    // next time this recipient's value get updated, send a message
    // regardless of whether the sensor value changed

    function sendMessageOnNextValueUpdate( ISensorNotification recipient )
    {
    	local int i;
    	local AI_SensorRecipient sensorRecipient;

    	for ( i = 0; i < recipients.length; i++ )
    	{
    		sensorRecipient = recipients[i];

    		if ( sensorRecipient.recipient == recipient )
    			 sensorRecipient.bNotify = true;
    	}
    }

    //---------------------------------------------------------------------
    // Set a sensor's value
    // Called by sensors - sets the sensors value and notifies waiting
    // actions appropriately

    function setIntegerValue( int newValue )
    {
    	local int i;
    	local AI_SensorRecipient sensorRecipient;
    	local int oldValue;
    	local array<AI_SensorRecipient> sendList;	// place to collect recipient who will receive a message (can't send message directly because recipients may modify the array)

    	oldValue = value.integerData;
    	value.dataType = SDT_INTEGER;
    	value.integerData = newValue;

    	// check if newValue in range and no notification was sent before
    	for ( i = 0; i < recipients.length; i++ )
    	{
    		sensorRecipient = recipients[i];

    		//log( name @ "setIntegerValue: Checking" @ sensorRecipient.recipient.name );
    		//log( "newvalue:" @ newValue @ " oldvalue:" @ oldValue @
    		//	"(" @ sensorRecipient.lowerbound $ ", " $ sensorRecipient.upperbound @ ")" );

    		if ( newValue >= sensorRecipient.lowerBound &&
    			 newValue <= sensorRecipient.upperBound &&
    			 ( sensorRecipient.bNotify || !bNotifyOnValueChange ||
    			   oldValue < sensorRecipient.lowerBound ||
    			   oldValue > sensorRecipient.upperBound ))
    		{
    			sensorRecipient.bNotify = false;
    			sendList[sendList.length] = sensorRecipient;
    		}
    	}

    	for ( i = 0; i < sendList.length; i++ )
    		sendSensorMessage( sendList[i], value );
    }

    //---------------------------------------------------------------------

    function setFloatValue( float newValue )
    {
    	local int i;
    	local AI_SensorRecipient sensorRecipient;
    	local float oldValue;
    	local array<AI_SensorRecipient> sendList;	// place to collect recipient who will receive a message (can't send message directly because recipients may modify the array)

    	oldValue = value.floatData;
    	value.dataType = SDT_FLOAT;
    	value.floatData = newValue;

    	// check if newValue in range and no notification was sent before
    	for ( i = 0; i < recipients.length; i++ )
    	{
    		sensorRecipient = recipients[i];

    		if ( newValue >= sensorRecipient.lowerBound &&
    			 newValue <= sensorRecipient.upperBound &&
    			 ( sensorRecipient.bNotify || !bNotifyOnValueChange ||
    			   oldValue < sensorRecipient.lowerBound ||
    			   oldValue > sensorRecipient.upperBound ))
    		{
    			//log( name @ "recipient (" @ sensorRecipient.lowerBound @ sensorRecipient.upperBound @ ") :" @ sensorRecipient @ " value" @ newValue );

    			sensorRecipient.bNotify = false;
    			sendList[sendList.length] = sensorRecipient;
    		}
    	}

    	for ( i = 0; i < sendList.length; i++ )
    		sendSensorMessage( sendList[i], value );
    }

    //---------------------------------------------------------------------

    function setCategoricalValue( int newValue )
    {
    	log( "setCategoricalValue: Not yet implemented" );
    }

    //---------------------------------------------------------------------
    // Note: if the upperbound is non-zero, a message is only sent when
    //       the object value is non-None

    function setObjectValue( Object newValue )
    {
    	local int i;
    	local AI_SensorRecipient sensorRecipient;
    	local Object oldValue;
    	local array<AI_SensorRecipient> sendList;	// place to collect recipient who will receive a message (can't send message directly because recipients may modify the array)

    	oldValue = value.objectData;
    	value.dataType = SDT_OBJECT;
    	value.objectData = newValue;

    	// check if newValue in range and no notification was sent before
    	for ( i = 0; i < recipients.length; i++ )
    	{
    		sensorRecipient = recipients[i];
    		//log( "--" @ name @ ":" @ sensorRecipient.recipient.name @ "; oldvalue:" @ oldValue @ "; newValue:" @ newValue @ "; upperBound:" @ sensorRecipient.upperBound );

    		if ( ( sensorRecipient.upperBound != ONLY_NON_NONE_VALUE || newValue != None ) &&
    			 ( sensorRecipient.upperBound != ONLY_NONE_VALUE || newValue == None ) &&
    			(!bNotifyOnValueChange || newValue != oldValue || sensorRecipient.bNotify) &&
    			bSendMessage( newValue ))
    		{
    			//log( name @ "recipient:" @ sensorRecipient.recipient.name @ "; value" @ newValue );

    			sensorRecipient.bNotify = false;
    			sendList[sendList.length] = sensorRecipient;
    		}
    	}

    	for ( i = 0; i < sendList.length; i++ )
    		sendSensorMessage( sendList[i], value );
    }

    //---------------------------------------------------------------------
    // If the sensor value is set to this object, should the sensor send a notification?
    // Overriden by individual sensors.

    function bool bSendMessage( Object object )
    {
    	return true;
    }

    //---------------------------------------------------------------------
    // Query a sensor's value

    function AI_SensorData queryValue()
    {
    	return value;
    }

    function int queryIntegerValue()
    {
    	return value.integerData;
    }

    function float queryFloatValue()
    {
    	return value.floatData;
    }

    function Object queryObjectValue()
    {
    	return value.objectData;
    }

    //---------------------------------------------------------------------
    // Clear a sensor's value

    function clearValue()
    {
    	value.clear();
    }

    //---------------------------------------------------------------------
    // How many actions are using this sensor?

    function int queryUsage()
    {
    	return recipients.length;
    }

    //---------------------------------------------------------------------
    // Create a new sensor (or find a pre-existing one)
    // low-level function called by activateSensor and activateSentinel

    protected static function AI_Sensor activateSensorInternal( class<AI_Sensor> sensorClass,
    														  AI_Resource r,
    														  optional float lowerBound,
    														  optional float upperBound,
    														  optional Object userData,
    														  optional ISensorNotification recipient)
    {
    	local int i;
    	local AI_Sensor sensor;
    	local AI_SensorRecipient sensorRecipient;

    	//log( "-> Sensor" @ sensorClass.name @ "requested by" @ recipient.name @ "on" @ r.name );

    	if ( r == None )
    		r = AI_SensorResource( class'Setup'.static.GetStaticSensorResource() );

    	if ( r == None )
    		log( "AI Error: Couldn't retrieve sensorResource in 'createSensorInternal'" );

    	//log( "## Looking for sensors...." );

    	// Check if this sensor already exists (possible optimization: use a hashTable for quicker lookup?)
    	for ( i = 0; i < r.sensors.length; i++ )
    	{
    		//log( "---> Looking at" @ r.sensors[i].name );
    		if ( sensorClass == r.sensors[i].class )
    		{
    			sensor = r.sensors[i];
    			break;
    		}
    	}

    	if ( sensor == None )
    	{
    		log( "AI WARNING: Sensor" @ sensorClass.name @ "requested by" @ recipient.name @ "but not found!" );
    		log( "AI WARNING: Check that the corresponding sensorAction has been set up for" @ r.name );
    	}
    	else
    	{
    		//for ( i = 0; i < sensor.recipients.length; i++ )
    		//	if ( sensor.recipients[i].recipient == recipient )
    		//	{
    		//		log( "AI WARNING: Activating already existing sensor" @ sensor.name @ "in" @ r );
    		//		return sensor;
    		//	}

    		// Set up new SensorRecipient
    		sensorRecipient = new(r) class'AI_SensorRecipient';
    		sensorRecipient.userData = userData;
    		sensorRecipient.recipient = recipient;

    		sensorRecipient.lowerBound = lowerBound;
    		if ( upperBound == 0.0 )
    			sensorRecipient.upperBound = lowerBound;
    		else
    			sensorRecipient.upperBound = upperBound;

    		// add it to the list of recipients
    		// recipients.Push(sensorRecipient)
    		sensor.recipients[sensor.recipients.length] = sensorRecipient;

    		if ( sensor.sensorAction.bCallBegin )
    		{
    			sensor.sensorAction.bCallBegin = false;
    			sensor.sensorAction.begin();
    		}

    		if ( sensor.recipients.length == 1 )
    			sensor.begin();

    		//if ( sensor.class == class'AI_TargetSensor' )
    		//	log( "=>" @ sensor.name @ sensor.recipients.length );
    	}

    	return sensor;
    }

    //---------------------------------------------------------------------
    // Remove a sensor
    // low-level function called by deactivateSensor and deactivateSentinel

    protected function deactivateSensorInternal( ISensorNotification recipient, optional float lowerBound, optional float upperBound )
    {
    	local int i;
    	local AI_SensorRecipient sensorRecipient;

    	// log("----> Deactivating" @ name );

    	for ( i = 0; i < recipients.length; i++ )
    	{
    		sensorRecipient = recipients[i];

    		if ( sensorRecipient.recipient == recipient &&
    			(upperBound == 0 || sensorRecipient.upperBound == upperBound) &&
    			(lowerBound == 0 || sensorRecipient.lowerBound == lowerBound) )
    		{
    			//log("----> Removing recipient" @ recipient.name @ "(length:" @ recipients.length-1 $ ")" @ "from" @ name );
    			recipients[i].Delete();
    			recipients.remove(i, 1);		// removes element - shifts the rest
    			break;
    		}
    	}

    	//if ( class == class'AI_TargetSensor' )
    	//	log( "<=" @ name @ recipients.length );

    	if ( recipients.length == 0 )
    		cleanup();
    }

    //=====================================================================

    defaultproperties
    {
    	bNotifyOnValueChange = false
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:54:22.000 - Creation time: st 23.5.2018 00:10:41.641 - Created with UnCodeX