Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Gameplay.Equippable

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431
00432
00433
00434
00435
00436
00437
00438
00439
00440
00441
00442
00443
00444
00445
00446
00447
00448
00449
00450
00451
00452
00453
00454
00455
00456
00457
00458
00459
00460
00461
00462
00463
00464
00465
00466
00467
00468
00469
00470
00471
00472
00473
00474
00475
00476
00477
00478
00479
00480
00481
00482
00483
00484
00485
00486
00487
00488
00489
00490
00491
00492
00493
00494
00495
00496
00497
00498
00499
00500
00501
00502
00503
00504
00505
00506
00507
00508
00509
00510
00511
00512
00513
00514
00515
00516
00517
00518
00519
00520
00521
00522
00523
00524
00525
00526
00527
00528
00529
00530
00531
00532
00533
00534
00535
00536
00537
00538
00539
00540
00541
00542
00543
00544
00545
00546
00547
00548
00549
00550
00551
00552
00553
00554
00555
00556
00557
00558
00559
00560
00561
00562
00563
00564
00565
00566
00567
00568
00569
00570
00571
00572
00573
00574
00575
00576
00577
00578
00579
00580
00581
00582
00583
00584
00585
00586
00587
00588
00589
00590
00591
00592
00593
00594
00595
00596
00597
00598
00599
00600
00601
00602
00603
00604
00605
00606
00607
00608
00609
00610
00611
00612
00613
00614
00615
00616
00617
00618
00619
00620
00621
00622
00623
00624
00625
00626
00627
00628
00629
00630
00631
00632
00633
00634
00635
00636
00637
00638
00639
00640
00641
00642
00643
00644
00645
00646
00647
00648
00649
00650
00651
00652
00653
00654
00655
00656
00657
00658
00659
00660
00661
00662
00663
00664
00665
00666
00667
00668
00669
00670
00671
00672
00673
00674
00675
00676
00677
00678
00679
00680
00681
00682
00683
00684
00685
00686
00687
00688
00689
00690
00691
00692
00693
00694
00695
00696
00697
00698
00699
00700
00701
00702
00703
00704
00705
00706
00707
00708
00709
00710
00711
00712
00713
00714
00715
00716
00717
00718
00719
00720
00721
00722
00723
00724
00725
00726
00727
00728
00729
00730
00731
00732
00733
00734
00735
00736
00737
00738
00739
00740
00741
00742
00743
00744
00745
00746
00747
00748
00749
00750
00751
00752
00753
00754
00755
00756
00757
00758
00759
00760
00761
00762
00763
00764
00765
00766
00767
00768
00769
00770
00771
00772
00773
00774
00775
00776
00777
00778
00779
00780
00781
00782
00783
00784
00785
00786
00787
00788
00789
00790
00791
00792
00793
00794
00795
00796
00797
00798
00799
00800
00801
00802
00803

    // Equippable
    // Base class for equipment that can be selected or are visible in a first-person view and can be
    // fired, thrown or take other actions in response to the user's fire button. This includes weapons, throwable
    // flags or balls, and deployables
    class Equippable extends Equipment
    	native;

    // First and third person displays
    var() Mesh			firstPersonMesh				"The mesh seen in your first-person view";
    var() Mesh			thirdPersonMesh				"The mesh seen when others look at your weapon";
    var() Mesh			firstPersonAltMesh			"The mesh seen in your first-person view if your armor uses an alternate weapon mesh";
    var() Mesh			thirdPersonAltMesh			"The mesh seen when others look at your weapon if your armor uses an alternate weapon mesh";

    var() StaticMesh	thirdPersonStaticMesh		"The mesh seen when others look at your weapon";
    var() StaticMesh	thirdPersonAltStaticMesh	"The mesh seen when others look at your weapon if your armor uses an alternate weapon mesh";
    var() Vector		thirdPersonAttachmentOffset	"Offset from attachment point for 3rd person mesh";
    var() Name			thirdPersonAttachmentBone	"The bone to attach the deployable to when in third person";

    var() private Vector	firstPersonOffset		"The position of the weapon in a first person view";
    var() private Vector	firstPersonAltOffset	"The position of the weapon in a first person view if your armor uses an alternate weapon mesh";
    var() float			firstPersonBobMultiplier	"from 0 to 1";
    var() float			firstPersonTraceLength		"Trace used to stop gun hitting wall";
    var() Vector		firstPersonTraceExtent;
    var() float			firstPersonAltTraceLength		"Trace used to stop gun hitting wall";
    var() Vector		firstPersonAltTraceExtent;
    var() bool			bFirstPersonUseTrace		"Whether a trace should be used to pull the gun away from objects in the first person";

    var() string		animPrefix					"Prefix used for arm and weapon animations";

    var() bool			automaticallyHold			"Force this equippable to enter the Held state as soon as it is spawned.";

    var float			firstPersonInterpStep;		// Used in interpolating the gun position when it hits a wall
    var float			firstPersonInterpTarget;	// "", an offset along the gun retraction vector
    var float			firstPersonInterpCurrent;	// ""

    // Delays
    var() float			unequipDuration				"The amount of time that the unequip animation takes to play";
    var() float			equipDuration				"The amount of time that the equip animation takes to play";

    // Internals
    var IFiringMotor	rookMotor;				// motor to query for firing funcitonality
    var bool			bMeshChangeOK;
    var Rook			rookOwner;
    var bool			bIsFirstPerson;
    var float			startEquippingTime;

    var byte            fireCount;						    // used for replicating firing events to other clients for sim proxies
    var byte			localFireCount;

    var byte            demoFireCount;                      // used locally for replicating firing events to the demo recording
    var byte            localDemoFireCount;

    var bool			equipped;
    var float			equipDurationCounter;
    var Vector			equippablePos;

    var Name			fireState;
    var Name			releaseFireState;

    var bool			attemptedAttach;					// prevents constant spam if attachment fails

    var() class<EquippableAnimator> animClass;

    var() string		equippedArmAnim;

    var bool			bPlayedCharacterEquipAnim;

    // Replication
    replication
    {
    	// server to client variables
    	unreliable if (Role == ROLE_Authority)
    		rookOwner, equipped;

        // server to sim proxy variables
    	unreliable if (Role == ROLE_Authority && !bNetOwner)
    		fireCount;

    	// demo recording variables
    	unreliable if (Role == ROLE_Authority && bDemoRecording)
    	    demoFireCount;

    	// client to server functions
    	reliable if (Role < ROLE_Authority)
    		sendServerRequestFire, sendServerRequestReleaseFire;
    }

    // PostBeginPlay
    simulated function PostBeginPlay()
    {
    	if (automaticallyHold)
    		GotoState('Held');

    	Super.PostBeginPlay();

    	firstPersonInterpCurrent = 0;
    	firstPersonInterpTarget = 0;
    }

    simulated function initialiseRookMotor()
    {
    	if (rookOwner != None)
    		rookMotor = rookOwner.firingMotor();
    	else
    		rookMotor = None;
    }

    // PostNetBeginPlay
    simulated function PostNetBeginPlay()
    {
    	Super.PostNetBeginPlay();

    	rookOwner = Rook(Owner);
    }

    protected function setMovementReplication(bool replicate)
    {
    	super.setMovementReplication(replicate);
    	bReplicateMovement = replicate;
    }

    function pickup(Character newOwner)
    {
    	Super.pickup(newOwner);
    	rookOwner = newOwner;
    	rookMotor = newOwner.motor;
    }

    simulated function bool keepArms()
    {
    	return false;
    }

    simulated function bool armsFirstPersonStatus(bool bNewIsFirstPerson)
    {
    	return bNewIsFirstPerson && (!bHidden || keepArms());
    }

    // selectMesh
    // Display third or first-person mesh accordingly
    simulated function selectMesh(optional bool bForceChange)
    {
    	local bool bNewIsFirstPerson;

    	// attempt to initialise rook motor if not already (case occurs on client at start)
    	if (rookMotor == None)
    	{
    		initialiseRookMotor();
    	}

    	// check for change to/from first person view
    	bNewIsFirstPerson = firstPersonStatus();

    	if (bNewIsFirstPerson != bIsFirstPerson || bForceChange || !bMeshChangeOK)
    	{
    		bIsFirstPerson = bNewIsFirstPerson;

    		if (bNewIsFirstPerson)
    		{
    			setupFirstPerson();
    		}
    		else
    		{
    			setupThirdPerson();
    		}
    	}

    	bHidden = shouldHide(bNewIsFirstPerson);
    	animClass.static.firstPersonStatus(self, armsFirstPersonStatus(bNewIsFirstPerson));
    }

    // firstPersonStatus
    // Returns true if the owning Rook has a first person view
    simulated function bool firstPersonStatus()
    {
        local PlayerController localPlayerController;
        local PlayerController ownerPlayerController;

    	// do nothing if no owner
    	if (rookOwner == None)
    		return false;

        localPlayerController = Level.GetLocalPlayerController();
        ownerPlayerController = PlayerController(rookOwner.controller);

        // handle early exit cases: no owner controller, no local controller
    	if (ownerPlayerController==None || localPlayerController==None)
    		return false;

        // normal case: check if owner controller is the current local player controller and is not in behind view

    	if (ownerPlayerController!=None && ownerPlayerController==localPlayerController && !ownerPlayerController.bBehindView)
    		return true;

        // demo recording case: check if rook is currently the view target of the demo player controller and not in behind view

        if (localPlayerController.ViewTarget==rookOwner && !localPlayerController.bBehindView)
            return true;

        // otherwise we must be in third person view

        return false;
    }

    simulated function bool useAlternateMesh()
    {
    	local Character c;

    	c = Character(rookOwner);

    	return c != None && c.armorClass != None && c.armorClass.static.useAlternateWeaponMesh();
    }

    // setupFirstPerson
    simulated function setupFirstPerson()
    {
    	if (useAlternateMesh())
    		LinkMesh(firstPersonAltMesh);
    	else
    		LinkMesh(firstPersonMesh);

    	SetDrawType(DT_Mesh);
    	bHidden = false;
    	bMeshChangeOK = true;
    }

    // moveWeapon
    simulated function moveWeapon()
    {
    	local Vector hitLocation, startTrace, endTrace, traceDir, hitNormal, traceExtent;
    	local Rotator r;
    	local float traceLength;

    	if (rookOwner == None || rookOwner.controller == None)
    		return;

    	// attempt to initialise rook motor if not already (case occurs on client at start)
    	if (rookMotor == None)
    	{
    		initialiseRookMotor();
    		if (rookMotor == None)
    			return;
    	}

    	SetRotation(rookMotor.getFirstPersonEquippableRotation(self));

    	equippablePos = rookMotor.getFirstPersonEquippableLocation(self);

    	if (bFirstPersonUseTrace)
    	{
    		if (useAlternateMesh())
    		{
    			traceLength = firstPersonAltTraceLength;
    			traceExtent = firstPersonAltTraceExtent;
    		}
    		else
    		{
    			traceLength = firstPersonTraceLength;
    			traceExtent = firstPersonTraceExtent;
    		}

    		traceDir = Vector(Rotation);
    		startTrace = equippablePos + traceDir * traceLength * 0.5;
    		endTrace = equippablePos + traceDir * traceLength;

    		// prevent equippable from sticking in walls
    		if (Trace(hitLocation, hitNormal, endTrace, startTrace, true, traceExtent) != None)
    		{
    			firstPersonInterpTarget = VSize(endTrace - equippablePos) - VSize(hitLocation - equippablePos);
    		}
    		else
    		{
    			firstPersonInterpTarget = 0;
    		}

    		calculateInterpolation();

    		// Retract equippable on a vector back and slightly down (avoids near clipping probs)
    		if (firstPersonInterpCurrent != 0)
    		{
    			r = rookOwner.controller.GetViewRotation();
    			r.Pitch += 4096;
    			Normalize(r);

    			equippablePos -= Vector(r) * firstPersonInterpCurrent;
    		}
    	}

    	if (Level.NetMode != NM_DedicatedServer)
    	{
    		r = rookOwner.controller.GetViewRotation();
    		equippablePos -= Vector(r) * ((Level.GetLocalPlayerController().DefaultFOV - 85) * 0.3);
    	}

    	//LOG(firstPersonInterpCurrent$", "$firstPersonInterpTarget);
    	if (bIsFirstPerson)
    		SetLocation(equippablePos);

    	animClass.static.setLocRot(self, equippablePos, rookMotor.getFirstPersonEquippableRotation(self));
    }

    // setupThirdPerson
    simulated function setupThirdPerson()
    {
    	local Rook attachRook;
    	local name attachBoneName;

    	// attempt to initialise rook motor if not already (case occurs on client at start)
    	if (rookMotor == None)
    		return;

    	// if we have no third person mesh, that's ok (like deployable turret weapon)
    	if ((thirdPersonMesh == None && thirdPersonStaticMesh == None)|| (useAlternateMesh() && thirdPersonAltMesh == None && thirdPersonStaticMesh == None))
    	{
    		bMeshChangeOK = true;
    		SetDrawType(DT_Mesh);
    		LinkMesh(None);
    		return;
    	}

    	// using static meshes
    	if (thirdPersonStaticMesh != None || thirdPersonAltStaticMesh != None)
    	{
    		LinkMesh(None);	// clear possible skeletal mesh

    		if (useAlternateMesh())
    			SetStaticMesh(thirdPersonAltStaticMesh);
    		else
    			SetStaticMesh(thirdPersonStaticMesh);
    		SetDrawType(DT_StaticMesh);
    	}
    	// else skeletal meshes (old support code)
    	else
    	{
    		SetStaticMesh(None);	// clear possible static mesh

    		if (useAlternateMesh())
    			LinkMesh(thirdPersonAltMesh);
    		else
    			LinkMesh(thirdPersonMesh);
    		SetDrawType(DT_Mesh);
    	}

    	bHidden = false;

    	rookMotor.getThirdPersonEquippableAttachment(self, attachRook, attachBoneName);
    	if (attachRook != None && attachBoneName != '')
    	{
    		SetBase(None);
    		if (!attachRook.AttachToBone(self, attachBoneName))
    		{
    			LOG("Warning: Rook "$attachRook.Name$" has no bone "$attachBoneName$", hiding equippable " $ class.name);
    			SetDrawType(DT_None);
    			return;
    		}

    		SetRelativeLocation(thirdPersonAttachmentOffset);
    	}

    	bMeshChangeOK = true;
    }

    simulated function calculateInterpolation()
    {
    	local float interpDiffNormal, interpDiffSize;

    	if (bIsFirstPerson)
    	{
    		interpDiffSize = firstPersonInterpTarget - firstPersonInterpCurrent;
    		if (interpDiffSize != 0)
    			interpDiffNormal = (firstPersonInterpTarget - firstPersonInterpCurrent) / interpDiffSize;
    		firstPersonInterpCurrent += interpDiffNormal * (firstPersonInterpStep * interpDiffSize);
    	}
    }

    // Tick
    simulated function Tick(float DeltaTime)
    {
    	if (!equipped)
    	{
    		GotoState('Unequipping');
    		return;
    	}

    	attachWeaponHack();

    	moveWeapon();

    	selectMesh();

    	checkFireCount();
    }

    simulated function attachWeaponHack()
    {
    	local Rook rookAttach;
    	local name boneNameAttach;

    	// hack, otherwise weapon does not sometimes get attached
    	if ((!bIsFirstPerson) && (!attemptedAttach) && (rookOwner != None) && (Level.NetMode == NM_Client) && (DrawType != DT_None) &&
    			(DrawType != DT_Mesh || Mesh != None) && (DrawType != DT_StaticMesh || StaticMesh != None))
    	{
    		// attempt to initialise rook motor if not already (case occurs on client at start)
    		if (rookMotor == None)
    		{
    			initialiseRookMotor();
    		}

    		if (rookMotor != None)
    		{
    			rookMotor.getThirdPersonEquippableAttachment(self, rookAttach, boneNameAttach);
    			if (rookAttach != None)
    			{
    				attemptedAttach = true; // We only ever attempt to attach once. If it fails, stiff ****
    				rookAttach.AttachToBone(self, boneNameAttach);
    			}
    		}
    	}
    }

    simulated function checkFireCount()
    {
        local bool demoPlayback;

        // initialize fire counts first time

        if (localFireCount==0 && fireCount!=0)
            localFireCount = fireCount;

        if (localDemoFireCount==0 && demoFireCount!=0)
            localDemoFireCount = demoFireCount;

        // determine if we are in demo playback

    	if (Level.GetLocalPlayerController() != None)
    		demoPlayback = DemoController(Level.GetLocalPlayerController()) != None || Level.GetLocalPlayerController().bDemoOwner;
    	else
    		demoPlayback = false;

    	if (demoPlayback && demoFireCount!=localDemoFireCount)
    	{
    	    // firing in demo playback

            handleFire();

        	onThirdPersonFireCount();

    	    handleReleaseFire();

    	    localDemoFireCount = demoFireCount;
    	}
    	else if (Level.NetMode==NM_Client && Role<=ROLE_SimulatedProxy && fireCount!=localFireCount)
    	{
    	    // 3rd person firing for simulated proxies

        	onThirdPersonFireCount();

    	    localFireCount = fireCount;
    	}
    }

    // onThirdPersonFireCount
    // Do muzzle flashes or animation effects here
    simulated function onThirdPersonFireCount()
    {
    }

    // fire
    event simulated bool fire(optional bool _fireOnce)
    {
    	if (Role != ROLE_Authority)
    		sendServerRequestFire();

    	return handleFire();
    }

    event simulated bool releaseFire(optional bool bClientOnly)
    {
    	if (Role != ROLE_Authority && !bClientOnly)
    		sendServerRequestReleaseFire();

    	return handleReleaseFire();
    }

    // sendServerRequestFire
    // Sent to the server to request a projectile
    private function bool sendServerRequestFire()
    {
    	return handleFire();
    }

    // sendServerRequestReleaseFire
    // Sent to the server to request a projectile
    protected function bool sendServerRequestReleaseFire()
    {
    	return handleReleaseFire();
    }

    // handleFire
    // overridden in state
    private function bool handleFire()
    {
    	return false;
    }

    // handleReleaseFire
    // overridden in state
    protected function bool handleReleaseFire()
    {
    	return false;
    }

    function bool canUnequip()
    {
    	return true;
    }

    // unEquip
    // Disables the weapon and prevents it from being drawn
    function unEquip()
    {
    	equipped = false;
    }

    // equip
    // Makes the weapon active and readies it for firing
    function equip()
    {
    	if (rookOwner != None)
    		equipped = true;
    }

    simulated state Held
    {
    	simulated function Tick(float DeltaTime)
    	{
    		if (equipped)
    			GotoState('Equipping');
    	}
    }

    // Idle state
    simulated state Idle
    {
    	simulated function BeginState()
    	{
    		TriggerEffectEvent('Idle');
    		// NOTE: weapons override this, and do not call the base class... must update weapon if you do extra stuff here
    	}

    	simulated function EndState()
    	{
    		UnTriggerEffectEvent('Idle');
    		// NOTE: weapons override this, and do not call the base class... must update weapon if you do extra stuff here
    	}

    	simulated protected function bool handleFire()
    	{
    		local Character character;

    		GotoState(fireState);

    		// remove invincibility if you fire a weapon
    		character = Character(Owner);
    		if (character != None && character.bTempInvincible)
    			character.removeTempInvincibility();

    		return true;
    	}

    	simulated function Tick(float Delta)
    	{
    		Global.Tick(Delta);

    		if (rookMotor != None && rookMotor.shouldFire(self))
    		{
    			fire();
    			return;
    		}

    		if (!IsInState('Idle')) // State change is possible in Global.Tick
    			return;

    		if (bIsFirstPerson)
    			if (!IsAnimating())
    				playIdleAnim();
    	}
    }

    simulated function playIdleAnim()
    {
    	animClass.static.playEquippableAnim(self, 'Idle');
    }

    // FirePressed
    // Entered when the fire button is pressed, do your shooting code here
    simulated state FirePressed
    {
    	simulated protected function bool handleReleaseFire()
    	{
    		GotoState(releaseFireState);
    		return true;
    	}
    }

    // FireReleased state
    // This state is entered when firing stops. Charge up weapons will override this to implement attacking after charging
    simulated state FireReleased
    {
    }

    simulated state Equipping
    {
    	simulated function Tick(float Delta)
    	{
    		moveWeapon();

    		equipDurationCounter += Delta;
    		if (equipDurationCounter >= equipDuration)
    		{
    			TriggerEffectEvent('Equipped');
    			GotoState('Idle');
            }
    		else
    		{
    			if (!equipped)
    				GotoState('Unequipping');
    		}
    	}

    Begin:
    	if (!equipped)
    		GotoState('Unequipping');

    	selectMesh(true);

    	TriggerEffectEvent('Equipping');

    	playEquipAnim();

    	equipDurationCounter = 0;
    }

    simulated function bool shouldPlayEquipAnim()
    {
    	// solve anim ordering problems on clients
    	if (Level.NetMode == NM_Client && Character(rookOwner) != None && Character(rookOwner).weapon != self)
    		return false;

    	return true;
    }

    simulated function playEquipAnim()
    {
    	if (!shouldPlayEquipAnim())
    		return;

    	animClass.static.playEquippableAnim(self, 'Select');
    }

    simulated state Unequipping
    {
    	simulated function BeginState()
    	{
    		super.BeginState();
    	}

    	simulated function Tick(float Delta)
    	{
    		moveWeapon();
    	}

    Begin:
    	playUnequipAnim();

    	Sleep(unequipDuration);

    	GotoState('Held');
    }

    simulated function playUnequipAnim()
    {
    	if (!shouldPlayEquipAnim())
    		return;

    	animClass.static.playEquippableAnim(self, 'Deselect');
    }

    simulated state Dropped
    {
    	simulated function BeginState()
    	{
    		equipped = false;

    		setDroppedMesh();

    		SetBase(None);
    		rookOwner = None;
    		rookMotor = None;

    		Super.BeginState();
    	}

    	simulated function Tick(float Delta) {}
    	simulated function onMessage(Message m) {}
    }

    simulated function setDroppedMesh()
    {
    	if (thirdPersonMesh != None)
    	{
    		LinkMesh(thirdPersonMesh);
    		SetDrawType(DT_Mesh);
    	}
    	else if (thirdPersonStaticMesh != None)
    	{
    		LinkMesh(None);
    		SetStaticMesh(thirdPersonStaticMesh);
    		SetDrawType(DT_StaticMesh);
    	}
    }

    function drawDebug(HUD debugHUD);

    simulated function bool shouldHide(bool bIsFirstPerson)
    {
    	if (bIsFirstPerson)
    	{
    		// hide when players are zoomed in first person
    		if (Character(rookOwner) != None && Character(rookOwner).isZoomed())
    			return true;

    		// bHideFirstPersonWeapon
    		if (PlayerCharacterController(rookOwner.Controller) != None && PlayerCharacterController(rookOwner.Controller).bHideFirstPersonWeapon)
    			return true;
    	}

    	return false;
    }

    simulated function Vector getFirstPersonOffset()
    {
    	if (useAlternateMesh())
    		return firstPersonAltOffset;
    	else
    		return firstPersonOffset;
    }

    simulated function setFirstPersonOffset(Vector v)
    {
    	if (useAlternateMesh())
    		firstPersonAltOffset = v;
    	else
    		firstPersonOffset = v;
    }

    // PRECACHING
    static simulated function PrecacheEquippableRenderData(LevelInfo Level, class<Equippable> EquipClass)
    {
    	Level.AddPrecacheMesh(EquipClass.default.firstPersonMesh);
    	Level.AddPrecacheMesh(EquipClass.default.thirdPersonMesh);
    	Level.AddPrecacheMesh(EquipClass.default.firstPersonAltMesh);
    	Level.AddPrecacheMesh(EquipClass.default.thirdPersonAltMesh);

    	Level.AddPrecacheStaticMesh(EquipClass.default.thirdPersonStaticMesh);
    	Level.AddPrecacheStaticMesh(EquipClass.default.thirdPersonAltStaticMesh);
    }

    simulated function UpdatePrecacheRenderData()
    {
    	Super.UpdatePrecacheRenderData();
    	PrecacheEquippableRenderData(Level, Class);
    }

    defaultproperties
    {
    	bNoRepMesh = true	// client always sets the correct mesh
    	bReplicateMovement = false

    	bCanDrop = true

    	triggeredBy = "all"

    	DrawType = DT_Mesh

    	firstPersonTraceLength = 100
    	firstPersonTraceExtent = (X=1,Y=10,Z=1)
    	firstPersonAltTraceLength = 100
    	firstPersonAltTraceExtent = (X=1,Y=10,Z=1)
    	firstPersonBobMultiplier = 0.15
    	firstPersonInterpStep = 0.25
    	bFirstPersonUseTrace = true

    	fireState = FirePressed
    	releaseFireState = FireReleased

    	attemptedAttach = false

    	animClass = class'EquippableAnimator'

    	thirdPersonAttachmentBone = "weapon"
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:10.000 - Creation time: st 23.5.2018 00:10:43.314 - Created with UnCodeX