Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Tyrion.AI_DirectAttack

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193

    //=====================================================================
    // AI_DirectAttack
    // Attacks a target by moving directly towards it and firing
    //=====================================================================

    class AI_DirectAttack extends AI_CharacterAction implements IFollowFunction
    	editinlinenew;

    //=====================================================================
    // Constants

    const DEFAULT_PROXIMITY = 1000;	// how close to get to target (by default)

    //=====================================================================
    // Variables

    var(Parameters) editconst int rank "Rank of the AI; set by the ability in the class DB";
    var(Parameters) editinline Name targetName "Label of target (any Pawn)";
    var(Parameters) class<Weapon> preferredWeaponClass "AI will use this weapon if at all possible";

    var(InternalParameters) editconst Pawn target;
    var(InternalParameters) editconst IWeaponSelectionFunction weaponSelection;
    var(InternalParameters) editconst IFollowFunction followFunction;

    var AI_Goal fireAtGoal;
    var AI_Goal movementGoal;
    var ACT_Errorcodes errorCode;

    //=====================================================================
    // Functions

    //---------------------------------------------------------------------
    // callbacks from sub-goals;
    // they are only used to stop the action when any success/failure message
    // comes up that isn't an interruption
    // todo: automate this process? A new flag on goals/waitForGoals?

    function goalAchievedCB( AI_Goal goal, AI_Action child )
    {
    	super.goalAchievedCB( goal, child );

    	errorCode = ACT_SUCCESS;
    	runAction();
    }

    function goalNotAchievedCB( AI_Goal goal, AI_Action child, ACT_ErrorCodes anErrorCode )
    {
    	super.goalNotAchievedCB( goal, child, anErrorCode );

    	errorCode = anErrorCode;

    	if ( errorCode != ACT_INTERRUPTED )
    		runAction();
    }

    //---------------------------------------------------------------------
    // Selection Heuristic
    // Returns a value in the range [0, 1], indicating how suitable this action is for achieving this goal

    static function float selectionHeuristic( AI_Goal goal )
    {
    	return 0.1;		// always lower than character-specific attacks
    }

    //---------------------------------------------------------------------

    function cleanup()
    {
    	super.cleanup();

    	weaponSelection = None;
    	followFunction = None;

    	if ( movementGoal != None )
    	{
    		movementGoal.Release();
    		movementGoal = None;
    	}

    	if (fireAtGoal != None )
    	{
    		fireAtGoal.Release();
    		fireAtGoal = None;
    	}
    }

    //---------------------------------------------------------------------
    // IFollowFunction interface: should offset be updated?

    function bool updateOffset( Pawn follower, Pawn leader, int positionIndex )
    {
    	if ( followFunction != None )
    		return followFunction.updateOffset( follower, leader, positionIndex );
    	else
    		return false;
    }

    //---------------------------------------------------------------------
    // IFollowFunction interface: offset from leader pawn to actual location follower wants to go to

    function Vector offset( Pawn leader, int positionIndex )
    {
    	if ( followFunction != None )
    		return followFunction.offset( leader, positionIndex );
    	else
    		return vect(0,0,0);
    }

    //---------------------------------------------------------------------
    // IFollowFunction interface: is a given location a valid place to follow to?

    function bool validDestination( Vector point )
    {
    	if ( followFunction != None )
    		return followFunction.validDestination( point );
    	else
    		return true;
    }

    //---------------------------------------------------------------------
    // IFollowFunction interface: how close do you want to get to the target?

    function float proximityFunction()
    {
    	local float proximity;
    	local Weapon weapon;

    	if ( baseAICharacter().combatRangeCategory == CR_STAND_GROUND )
    		return 99999999.9f;

    	weapon = character().weapon;

    	if ( weaponSelection != None && weapon != None )
    		proximity = weaponSelection.firingRange( weapon.class );
    	else if ( weapon != None )
    		proximity = 0.8f * (class'AimFunctions'.static.getMaxEffectiveRange( weapon.class ) + target.CollisionRadius);

    	if ( proximity <= target.CollisionRadius )
    		proximity = DEFAULT_PROXIMITY;

    	return proximity;
    }

    //=====================================================================
    // State code

    state Running
    {
    Begin:
    	if ( target == None && targetName == '' )
    	{
    		log( "AI WARNING:" @ name @ "has no target" );
    		fail( ACT_INVALID_PARAMETERS, true );
    	}

    	if ( target == None )
    		target = Pawn(pawn.findByLabel( class'Pawn', targetName, true ));

    	if ( pawn.logTyrion )
    		log( name @ "started." @ pawn.name @ "is attacking" @ target.name @ "directly" );

    	if ( target == None )
    	{
    		log( "AI WARNING:" @ name @ "can't find specified rook" );
    		fail( ACT_INVALID_PARAMETERS, true );
    	}

    	pawn.level.speechManager.PlayDynamicSpeech( pawn, 'Attack', pawn );

    	// move towards target
    	movementGoal = (new class'AI_CombatMovementGoal'( movementResource(), achievingGoal.priority, target,, self )).postGoal( self ).myAddRef();
    	// start shooting at target
    	fireAtGoal = (new class'AI_FireAtGoal'( weaponResource(), achievingGoal.priority, target, weaponSelection, preferredWeaponClass )).postGoal( self ).myAddRef();
    	//old: WaitForAnyGoal( movementGoal, fireAtGoal );				// handles resource death
    	pause();

    	AI_Controller(pawn.controller).stopMove();

    	if ( pawn.logTyrion )
    		log( name @ "(" @ pawn.name @ ") stopped with errorCode" @ errorCode );

    	if ( class'Pawn'.static.checkDead( target ) )
    		succeed();
    	else
    		fail( errorCode );
    }

    //=====================================================================

    defaultproperties
    {
    	satisfiesGoal = class'AI_DirectAttackGoal'
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:58.000 - Creation time: st 23.5.2018 00:10:41.030 - Created with UnCodeX