Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# GUI.GUISlider

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238

    // ====================================================================
    //  Class:  GUI.GUISlider
    //
    //  Written by Joe Wilcox
    //  (c) 2002, Epic Games, Inc.  All Rights Reserved
    // ====================================================================
    /*=============================================================================
    	In Game GUI Editor System V1.0
    	2003 - Irrational Games, LLC.
    	* Dan Kaplan
    =============================================================================*/
    #if !IG_GUI_LAYOUT
    #error This code requires IG_GUI_LAYOUT to be defined due to extensive revisions of the origional code. [DKaplan]
    #endif
    /*===========================================================================*/

    class GUISlider extends GUIComponent
            HideCategories(Menu,Object)
    		Native;

    cpptext
    {
    		void Draw(UCanvas* Canvas);
    }

    var(GUISlider) config  float 		MinValue, MaxValue "Bounds for the slider";
    var(GUISlider) config  string		CaptionStyleName "Name of the caption style";
    var(GUISlider) config  string		LeftStyleName "Name of the left style";
    var(GUISlider) config  string		RightStyleName "Name of the right style";
    var(GUISlider) config  string		ButtonStyleName "Name of the button style";
    var(GUISlider) config  float		Value "Slider's initial value";
    var(GUISlider) config  float		Step "Step value for incrementing the slider";
    var(GUISlider) editinline  GUIStyles	CaptionStyle "The actual caption style";
    var(GUISlider) config  bool		bIntSlider "Are the values bound to be ints";
    var(GUISlider) config  bool		    bDisplayAsPercentage "Should the value be displayed in text form as a percentage?";
    var(GUISlider) editinline  GUIStyles	LeftStyle "The style displayed left of the button";
    var(GUISlider) editinline  GUIStyles	RightStyle "The style displayed right of the button";
    var(GUISlider) editinline  GUIStyles	ButtonStyle "The style displayed for the button";
    var(GUISlider) config  float		SliderHeightPercent "Sliders height as a percentage of the total component height";
    var(GUISlider) config  float		ButtonWidthPixels "The buttons width in pixels (at 800x600)";
    var(GUISlider) config  eTextAlign	CaptionJustification "How the caption is justified";

    #if IG_TRIBES3 // dbeswick:
    var float		UpdateFreq;
    var float LastChangeMessage;
    #endif

    delegate string OnDrawCaption()
    {
        local float ModifiedValue;
        local float Range;
        local string OptionalText;

        if (bDisplayAsPercentage)
        {
            // Convert to percentage
            Range = (MaxValue - MinValue);
            ModifiedValue = (1 - (Range - Value)) / Range; // convert to 0-1 decimal percentage
            ModifiedValue *= 100; // convert to 0-100% percentage
            //log(Name$": Value = "$Value$" Max = "$MaxValue$" Min = "$MinValue$" Range = "$Range$" ModifiedValue = "$ModifiedValue);
        }
        else
            ModifiedValue = Value;

        if (bDisplayAsPercentage)
            OptionalText = "%";

    	if (bIntSlider || bDisplayAsPercentage)
    		return "("$int(ModifiedValue)$OptionalText$")";
    	else
    		return "("$ModifiedValue$OptionalText$")";
    }

    function SetValue(float NewValue)
    {
    	if (NewValue<MinValue) NewValue=MinValue;
    	if (NewValue>MaxValue) NewValue=MaxValue;

    	if (bIntSlider)
    		Value = int(NewValue);
    	else
    		Value = NewValue;
    }

    function InitComponent(GUIComponent MyOwner)
    {
    	Super.InitComponent(MyOwner);
    	OnCapturedMouseMove=InternalCapturedMouseMove;
    	OnKeyEvent=InternalOnKeyEvent;
    	OnMousePressed=InternalOnMousePressed;
    #if IG_TRIBES3 // dbeswick:
    	OnMouseRelease=InternalOnMousePressed;
    #endif
    	OnXControllerEvent = InternalOnXControllerEvent;

    	CaptionStyle = Controller.GetStyle(CaptionStyleName);
    	LeftStyle = Controller.GetStyle(LeftStyleName);
    	RightStyle = Controller.GetStyle(RightStyleName);
    	ButtonStyle = Controller.GetStyle(ButtonStyleName);

    	Assert( CaptionStyle != None );
    	Assert( LeftStyle != None );
    	Assert( RightStyle != None );
    	Assert( ButtonStyle != None );
    }

    function bool InternalCapturedMouseMove(float deltaX, float deltaY)
    {
    	local float Perc, OldValue;

    	OldValue = Value;

    	if ( (Controller.MouseX >= Bounds[0]) && (Controller.MouseX<=Bounds[2]) )
    	{
    		Perc = ( Controller.MouseX - ActualLeft()) / ActualWidth();
    		Perc = FClamp(Perc,0.0,1.0);
    		Value = ( (MaxValue - MinValue) * Perc) + MinValue;
    		if (bIntSlider)
    			Value = int(Value);
    	}
    	else if (Controller.MouseX < Bounds[0])
    		Value = MinValue;
    	else if (Controller.MouseX > Bounds[2])
    		Value = MaxValue;

    	Value = FClamp(Value,MinValue,MaxValue);

    #if IG_TRIBES3 // dbeswick:
    	if (LastChangeMessage >= 1)
    	{
    		LastChangeMessage = 0;
    		if (1.0 / UpdateFreq > 0)
    			SetTimer(1.0 / UpdateFreq);
    		OnChange(self);
    	}
    #endif

    	return true;
    }

    function bool InternalOnKeyEvent(out byte Key, out byte State, float delta)
    {
    	if ( (Key==0x25 || Key==0x64) && (State==1) )	// Left
    	{
    		if (bIntSlider)
    			Adjust(-1);
    		else
    			Adjust(-0.01);
    		return true;
    	}

    	if ( (Key==0x27 || Key==0x66) && (State==1) ) // Right
    	{
    		if (bIntSlider)
    			Adjust(1);
    		else
    			Adjust(0.01);
    		return true;
    	}

    	return false;
    }

    function bool InternalOnXControllerEvent(byte Id, eXControllerCodes iCode)
    {
     	if (iCode == XC_Left || iCode == XC_PadLeft || iCode == XC_X)
        {
        	Adjust(Step*-1);
            return true;
        }

        else if (iCode == XC_Right || iCode == XC_PadRight || iCode == XC_Y)
        {
        	Adjust(Step);
            return true;
        }

        return false;

    }

    function Adjust(float amount)
    {
    	local float Perc;
    	Perc = (Value-MinValue) / (MaxValue-MinValue);
    	Perc += amount;
    	Perc = FClamp(Perc,0.0,1.0);
    	Value = ( (MaxValue - MinValue) * Perc) + MinValue;
    	FClamp(Value,MinValue, MaxValue);
    	OnChange(self);
    }

    event Click()
    {
    	Super.Click();
    	OnChange(self);
    }

    function InternalOnMousePressed(GUIComponent Sender)
    {
    #if IG_TRIBES3 // dbeswick:
    	LastChangeMessage = 1;
    #endif
    	InternalCapturedMouseMove(0,0);
    }

    #if IG_TRIBES3 // dbeswick:
    function Timer()
    {
    	LastChangeMessage = 1;
    }
    #endif

    defaultproperties
    {
    	StyleName="sty_sliderstyle"
    	bAcceptsInput=true
    	bCaptureMouse=True
    	bNeverFocus=false;
    	bTabStop=true
    	WinHeight=0.03
    	bRequireReleaseClick=true
    	CaptionStyleName="STY_SliderCaption"
    	bIntSlider=false;
    	OnClickSound=CS_Click
        Step=1;
    	bDrawStyle=false
    	ButtonStyleName="STY_SliderButton"
    	LeftStyleName="STY_SliderLeft"
    	RightStyleName="STY_SliderRight"
    	SliderHeightPercent=1.0
    	ButtonWidthPixels=16.0
    //#if IG_TRIBES3 // dbeswick:
    	UpdateFreq=30
    //#endif
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 16:02:10.000 - Creation time: st 23.5.2018 00:10:43.924 - Created with UnCodeX