Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Tyrion.AI_AssaultShipAttack

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182

    //=====================================================================
    // AI_AssaultShipAttack
    //=====================================================================

    class AI_AssaultShipAttack extends AI_VehicleAction
    	editinlinenew;

    import enum VehiclePositionType from Vehicle;

    //=====================================================================
    // Constants

    const CLOSING_RANGE = 4000.0f;			// how close to get to target before starting fancy combat maneuvers
    const ATTACK_SPEED = 1500.0f;			// attack speed
    const HEIGHT_ABOVE_TARGET = 1500.0f;	// how high do you want to be above target when you attack?
    const DIAGONAL_DISTANCE = 5000;

    //=====================================================================
    // Variables

    var(Parameters) editinline Name targetName "Label of target (any Pawn)";

    var(InternalParameters) editconst Pawn target;
    var(InternalParameters) editconst IFollowFunction followFunction;

    var Vehicle v;
    var VehiclePositionType driverPosition;
    var Vector destination;

    var AI_Goal fireAtGoal;
    var AI_Goal followGoal;
    var ACT_Errorcodes errorCode;
    var AI_TargetMemorySensor targetMemorySensor;

    //=====================================================================
    // Functions

    //---------------------------------------------------------------------
    // callbacks from sub-goals;
    // they are only used to stop the action when any success/failure message
    // comes up that isn't an interruption
    // todo: automate this process? A new flag on goals/waitForGoals?

    function goalAchievedCB( AI_Goal goal, AI_Action child )
    {
    	super.goalAchievedCB( goal, child );

    	errorCode = ACT_SUCCESS;
    	runAction();
    }

    function goalNotAchievedCB( AI_Goal goal, AI_Action child, ACT_ErrorCodes anErrorCode )
    {
    	super.goalNotAchievedCB( goal, child, anErrorCode );

    	errorCode = anErrorCode;

    	if ( errorCode != ACT_INTERRUPTED )
    		runAction();
    }

    //---------------------------------------------------------------------

    function cleanup()
    {
    	super.cleanup();

    	followFunction = None;

    	if ( targetMemorySensor != None )
    	{
    		targetMemorySensor.deactivateSensor( self );
    		targetMemorySensor = None;
    	}

    	if ( followGoal != None )
    	{
    		followGoal.Release();
    		followGoal = None;
    	}

    	if (fireAtGoal != None )
    	{
    		fireAtGoal.Release();
    		fireAtGoal = None;
    	}
    }

    //=====================================================================
    // State code

    state Running
    {
    Begin:
    	v = vehicle();

    	if ( target == None && targetName == '' )
    	{
    		log( "AI WARNING:" @ name @ "has no target" );
    		fail( ACT_INVALID_PARAMETERS, true );
    	}

    	if ( target == None )
    		target = Pawn(v.findByLabel( class'Pawn', targetName, true ));

    	if ( v.logTyrion )
    		log( name @ "started." @ v.name @ "is attacking" @ target.name );

    	if ( target == None )
    	{
    		log( "AI WARNING:" @ name @ "can't find specified rook" );
    		fail( ACT_INVALID_PARAMETERS, true );
    	}

    	// set up purely for VehiclePursue: memory function won't work on this sensor if it's always started from scratch
    	targetMemorySensor = AI_TargetMemorySensor( class'AI_Sensor'.static.activateSensor( self, class'AI_TargetMemorySensor', vehicleResource() ) );
    	targetMemorySensor.setParameters( target, v.visionMemory );

    	//waitForResourcesAvailable( achievingGoal.priority, achievingGoal.priority );

    	// start shooting at target
    	driverPosition = VP_DRIVER;		// stupid assignment necessary or Unreal doesn't recognize the enum
    	fireAtGoal = (new class'AI_GunnerFireAtGoal'( gunnerResource(driverPosition), achievingGoal.priority,
    					target, driverPosition, false )).postGoal( self ).myAddRef();

    	while ( class'Pawn'.static.checkAlive( v ) && class'Pawn'.static.checkAlive( target ) && (followGoal == None || !followGoal.wasNotAchieved() ))
    	{
    		// 1. post followGoal - interrupt it if close to target
    		if ( VSizeSquared2D( target.Location - v.Location ) > CLOSING_RANGE * CLOSING_RANGE )
    		{
    			if ( followGoal != None )
    			{
    				followGoal.Release();
    				followGoal = None;
    			}

    			// move towards target
    			followGoal = (new class'AI_VehiclePursueGoal'( driverResource(), achievingGoal.priority, target,
    							 CLOSING_RANGE,,,, HEIGHT_ABOVE_TARGET, ATTACK_SPEED )).postGoal( self ).myAddRef();

    			while ( class'Pawn'.static.checkAlive( v ) &&
    					class'Pawn'.static.checkAlive( target ) &&
    					VSizeSquared2D( target.Location - v.Location ) > CLOSING_RANGE * CLOSING_RANGE &&
    					!followGoal.wasNotAchieved() )
    				yield();

    			followGoal.unPostGoal( self );
    		}

    		// 2. move to a point behind target - call doLocalMove *without* target flag set
    		//   (since assault ship just passes overhead and drops bombs)
    		if ( class'Pawn'.static.checkAlive( v ) && class'Pawn'.static.checkAlive( target ) && (followGoal == None || !followGoal.wasNotAchieved() ))
    		{
    			destination = target.Location - v.Location;
    			destination.Z = 0;
    			destination *= DIAGONAL_DISTANCE / VSize2D( destination );
    			destination += target.Location;
    			destination.Z += HEIGHT_ABOVE_TARGET;

    			if ( followFunction == None || followFunction.validDestination( destination ) )
    			{
    				waitForGoal( (new class'AI_VehicleLocalAttackGoal'( driverResource(), achievingGoal.priority,
    									destination, 750, ATTACK_SPEED, None )).postGoal( self ), true );
    			}
    		}
    	}

    	if ( v.logTyrion )
    		log( name @ "(" @ v.name @ ") stopped with errorCode" @ errorCode );

    	if ( class'Pawn'.static.checkDead( target ) )
    		succeed();
    	else
    		fail( errorCode );
    }

    //=====================================================================

    defaultproperties
    {
    	satisfiesGoal = class'AI_VehicleAttackGoal'
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:58.000 - Creation time: st 23.5.2018 00:10:40.932 - Created with UnCodeX