Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Tyrion.AI_RocketGuyAttack

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151

    //=====================================================================
    // AI_RocketGuyAttack
    // RocketGuy AI standard attack
    //=====================================================================

    class AI_RocketGuyAttack extends AI_CharacterAction implements IWeaponSelectionFunction
    	editinlinenew;

    //=====================================================================
    // Constants

    //=====================================================================
    // Variables

    var(Parameters) int rank "Rank of the rocket guy (1)";
    var(Parameters) editinline Name targetName "Label of target (any Pawn)";
    var(Parameters) class<Weapon> preferredWeaponClass "AI will use this weapon if at all possible";

    var(InternalParameters) editconst Pawn target;
    var(InternalParameters) editconst IWeaponSelectionFunction weaponSelection;	// not used
    var(InternalParameters) editconst IFollowFunction followFunction;

    var() float minRocketRange "Minimum distance at which the Repairer equips the rocket pod";
    var() float idealRocketRange "Preferred distance at which to use the rocket pod";

    //=====================================================================
    // Functions

    //---------------------------------------------------------------------
    // Selection Heuristic
    // Returns a value in the range [0, 1], indicating how suitable this action is for achieving this goal

    static function float selectionHeuristic( AI_Goal goal )
    {
    	return 1.0;			// most suitable attack for a rocket guy
    }

    //---------------------------------------------------------------------
    // function for determining what weapon to use

    function Weapon bestWeapon( Character ai, Pawn target, class<Weapon> preferredWeaponClass )
    {
    	local Weapon w;
    	local Vector hitLocation;
    	local float timeToHit;

    	w = Weapon( ai.nextEquipment( None, class'RocketPod' ));
    	if ( w != None && w.hasAmmo() &&
    		( preferredWeaponClass == class'RocketPod' ||
    		  VDistSquared( ai.Location, target.Location ) >= minRocketRange * minRocketRange ) &&
    		w.aimClass.static.obstacleInPath( hitLocation,
    										  timeToHit,
    										  target,
    										  w,
    										  w.aimClass.static.getAimLocation( w, target )) == None &&
    		!w.aimClass.static.willHurt( w, ai, hitLocation, timeToHit ))
    		return w;

    	w = Weapon( ai.nextEquipment( None, class'EnergyBlade' ));
    	if ( w != None && VDistSquared( ai.Location, target.Location ) <= minRocketRange * minRocketRange )
    		return w;

    	return ai.weapon;	// no weapon found: keep holding what you got
    }

    //---------------------------------------------------------------------
    // best range at which to shoot weapon

    function float firingRange( class<Weapon> weaponClass )
    {
    	// always try to back up to the ideal rocket range unless holding the energy blade
    	if ( ClassIsChildOf( weaponClass, class'EnergyBlade' ))
    		return 0.8f * (class'EnergyBlade'.default.range + target.CollisionRadius);	// energy blade
    	else
    		return idealRocketRange;
    }

    //---------------------------------------------------------------------
    // are conditions met for firing this weapon?

    function bool bShouldFire( BaseAICharacter ai, Weapon weapon )
    {
    	return true;
    }

    //---------------------------------------------------------------------

    function cleanup()
    {
    	super.cleanup();

    	weaponSelection = None;
    	followFunction = None;

    	// when RocketGuyAttack deactivates, AI keeps on moving with his last direction
    	// (maybe there should be a default low-pri action that lands the AI?)
    	if ( class'Pawn'.static.checkAlive( pawn ) )
    		AI_Controller(pawn.controller).stopMove();
    }

    //=====================================================================
    // State code

    state Running
    {
    Begin:
    	if ( rank != 1 )
    	{
    		log( "AI ERROR: invalid rank" @ rank @ "given to rocket guy" @ Pawn.name );
    		fail( ACT_INVALID_PARAMETERS, true );
    	}

    	if ( target == None && targetName == '' )
    	{
    		log( "AI WARNING:" @ name @ "has no target" );
    		fail( ACT_INVALID_PARAMETERS, true );
    	}

    	if ( target == None )
    		target = Pawn(pawn.findByLabel( class'Pawn', targetName, true ));

    	if ( pawn.logTyrion )
    		log( name @ "started." @ pawn.name @ "is attacking" @ target.name );

    	if ( target == None )
    	{
    		log( "AI WARNING:" @ name @ "can't find specified rook" );
    		fail( ACT_INVALID_PARAMETERS, true );
    	}

    	waitForGoal( (new class'AI_DirectAttackGoal'( characterResource(), achievingGoal.priority, target, self, preferredWeaponClass, followFunction )).postGoal( self ) );

    	if ( class'Pawn'.static.checkDead( target ) )
    	{
    		if ( pawn.logTyrion )
    			log( name @ "stopped. TARGET DEAD!" );
    		succeed();
    	}
    	else
    		fail( ACT_GENERAL_FAILURE );
    }

    //=====================================================================

    defaultproperties
    {
    	satisfiesGoal = class'AI_AttackGoal'

    	minRocketRange = 750
    	idealRocketRange = 3000
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:54:00.000 - Creation time: st 23.5.2018 00:10:41.615 - Created with UnCodeX