Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Engine.Mutator

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198

    //=============================================================================
    // Mutator.
    //
    // Mutators allow modifications to gameplay while keeping the game rules intact.
    // Mutators are given the opportunity to modify player login parameters with
    // ModifyLogin(), to modify player pawn properties with ModifyPlayer(), to change
    // the default weapon for players with GetDefaultWeapon(), or to modify, remove,
    // or replace all other actors when they are spawned with CheckRelevance(), which
    // is called from the PreBeginPlay() function of all actors except those (Decals,
    // Effects and Projectiles for performance reasons) which have bGameRelevant==true.
    //=============================================================================
    class Mutator extends Info
    	native
    	dependson(GameInfo);

    var Mutator NextMutator;
    //var class<Weapon> DefaultWeapon;
    var string DefaultWeaponName;
    var() string      		ConfigMenuClassName;
    var() string            GroupName; // Will only allow one mutator with this tag to be selected.
    var() localized string  FriendlyName;
    var() localized string  Description;
    var bool bUserAdded;
    var bool bAddToServerPackages;		// if true, the package this mutator is in will be added to serverpackages at load time

    /* Don't call Actor PreBeginPlay() for Mutator
    */
    event PreBeginPlay()
    {
    	if ( !MutatorIsAllowed() )
    		Destroy();
    }

    function bool MutatorIsAllowed()
    {
    	return !Level.IsDemoBuild() || Class==class'Mutator';
    }

    function Destroyed()
    {
    	local Mutator M;

    	// remove from mutator list
    	if ( Level.Game.BaseMutator == self )
    		Level.Game.BaseMutator = NextMutator;
    	else
    	{
    		for ( M=Level.Game.BaseMutator; M!=None; M=M.NextMutator )
    			if ( M.NextMutator == self )
    			{
    				M.NextMutator = NextMutator;
    				break;
    			}
    	}
    	Super.Destroyed();
    }

    // Gives the mutator an opportunity to replace an actor after it is spawned.
    // Either return the original actor, a replacement actor created with the ReplaceWith function, or 'None' to destroy the actor.
    function Actor ReplaceActor(Actor Other)
    {
    	return Other;
    }

    function Mutate(string MutateString, PlayerController Sender)
    {
    	if ( NextMutator != None )
    		NextMutator.Mutate(MutateString, Sender);
    }

    function ModifyLogin(out string Portal, out string Options)
    {
    	if ( NextMutator != None )
    		NextMutator.ModifyLogin(Portal, Options);
    }

    //Notification that a player is exiting
    function NotifyLogout(Controller Exiting)
    {
    	if (NextMutator != None)
    		NextMutator.NotifyLogout(Exiting);
    }

    /* called by GameInfo.RestartPlayer()
    	change the players jumps, etc. here
    */
    function ModifyPlayer(Pawn Other)
    {
    	if ( NextMutator != None )
    		NextMutator.ModifyPlayer(Other);
    }

    function AddMutator(Mutator M)
    {
    	if ( NextMutator == None )
    		NextMutator = M;
    	else
    		NextMutator.AddMutator(M);
    }

    /* ReplaceWith()
    Call this function (usually called from "ShouldReplace") to replace an actor Other with an actor of aClass.
    */
    function Actor ReplaceWith(actor Other, string aClassName)
    {
    	local Actor A;
    	local class<Actor> aClass;

    	if ( aClassName == "" )
    		return None;

    	aClass = class<Actor>(DynamicLoadObject(aClassName, class'Class'));
    	if ( aClass != None )
    		A = Spawn(aClass,Other.Owner,Other.Tag,Other.Location, Other.Rotation);

    	if ( A != None )
    	{
    		A.event = Other.event;
    		A.Tag = Other.Tag;
    	}

    	return A;
    }

    /* Force game to always keep this actor, even if other mutators want to get rid of it
    */
    function bool AlwaysKeep(Actor Other)
    {
    	if ( NextMutator != None )
    		return ( NextMutator.AlwaysKeep(Other) );
    	return false;
    }

    function bool IsRelevant(Actor Other, out Actor Replacement)
    {
    	local bool bRelevant;

    	Replacement = ReplaceActor(Other);

    	bRelevant = Replacement == Other;

    	if ( bRelevant && (NextMutator != None) )
    		bRelevant = NextMutator.IsRelevant(Other, Replacement);

    	return bRelevant;
    }

    singular event bool CheckRelevance(Actor Other, out Actor Replacement)
    {
    	local bool bResult;

    	if ( AlwaysKeep(Other) )
    		return true;

    	// allow mutators to remove actors
    	bResult = IsRelevant(Other, Replacement);

    	return bResult;
    }

    //
    // Called when a player sucessfully changes to a new class
    //
    function PlayerChangedClass(Controller aPlayer)
    {
    	if ( NextMutator != None )
    	NextMutator.PlayerChangedClass(aPlayer);
    }

    //
    // server querying
    //
    function GetServerDetails( out GameInfo.ServerResponseLine ServerState )
    {
    	// append the mutator name.
    	local int i;
    	i = ServerState.ServerInfo.Length;
    	ServerState.ServerInfo.Length = i+1;
    	ServerState.ServerInfo[i].Key = "Mutator";
    	ServerState.ServerInfo[i].Value = GetHumanReadableName();
    }

    function GetServerPlayers( out GameInfo.ServerResponseLine ServerState )
    {
    }

    function ServerTraveling(string URL, bool bItems)
    {
    	if (NextMutator != None)
        	NextMutator.ServerTraveling(URL,bItems);
    }

    defaultproperties
    {
        GroupName=""
        FriendlyName=""
        Description=""
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 16:01:26.000 - Creation time: st 23.5.2018 00:10:46.061 - Created with UnCodeX