Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# GUI.GUIList

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431
00432
00433
00434
00435
00436
00437
00438
00439
00440
00441
00442
00443
00444
00445
00446
00447
00448
00449
00450
00451
00452
00453
00454
00455
00456
00457
00458
00459
00460
00461
00462
00463
00464
00465
00466
00467
00468
00469
00470
00471
00472
00473
00474
00475
00476
00477
00478
00479
00480
00481
00482
00483
00484
00485
00486
00487
00488
00489
00490
00491
00492
00493
00494
00495
00496
00497
00498
00499
00500
00501
00502
00503
00504
00505
00506
00507
00508
00509
00510
00511
00512
00513
00514
00515
00516
00517
00518
00519
00520
00521
00522
00523
00524
00525
00526
00527
00528
00529
00530
00531
00532
00533
00534
00535
00536
00537
00538
00539
00540
00541
00542
00543
00544
00545
00546
00547
00548
00549
00550
00551
00552
00553
00554
00555
00556
00557
00558
00559
00560
00561
00562
00563
00564
00565
00566
00567
00568
00569
00570
00571
00572
00573
00574
00575
00576
00577
00578
00579
00580
00581
00582
00583
00584
00585
00586
00587
00588
00589
00590
00591
00592
00593
00594
00595
00596
00597
00598
00599
00600
00601
00602
00603
00604
00605
00606
00607
00608
00609
00610
00611
00612
00613
00614
00615
00616
00617
00618
00619
00620
00621
00622
00623
00624
00625
00626
00627
00628
00629
00630
00631
00632
00633
00634
00635
00636
00637
00638
00639
00640
00641
00642
00643
00644
00645
00646
00647
00648
00649
00650
00651
00652
00653
00654
00655
00656
00657
00658
00659
00660

    // ====================================================================
    //  Class:  GUI.GUIList
    //
    //  The GUIList is a basic list component.
    //
    //  Written by Joe Wilcox
    //  (c) 2002, Epic Games, Inc.  All Rights Reserved
    // ====================================================================
    /*=============================================================================
    	In Game GUI Editor System V1.0
    	2003 - Irrational Games, LLC.
    	* Dan Kaplan
    =============================================================================*/
    #if !IG_GUI_LAYOUT
    #error This code requires IG_GUI_LAYOUT to be defined due to extensive revisions of the origional code. [DKaplan]
    #endif
    /*===========================================================================*/

    class GUIList extends GUIVertList
            HideCategories(Menu,Object)
    		Native;

    cpptext
    {
    	void DrawItem(UCanvas* Canvas, INT Item, FLOAT X, FLOAT Y, FLOAT W, FLOAT H);
    }

    enum eSortType
    {
        SORT_AlphaItem,  // Alphabetical sorting - based off of Item
        SORT_AlphaExtra, // Alphabetical sorting - based off of ExtraStrData
        SORT_Numeric,    // strictly numerical sorting - based off of ExtraIntData
        SORT_Bool,       // sort based off of whether the ExtraBoolData is true
        SORT_IP,         // treat the ExtraStrData as an ip and sort by ip
    };

    var(GUIList) config eSortType TypeOfSort "Determines what type of sort to use for this list";
    var(GUIList) config eListElemDisplay DisplayItem "Determines which element member will be shown in this list";
    var(GUIList) EditConst bool bSortForward "If true, will sort forward, else will sort backwards";
    var(GUIList) EditConst bool bListIsDirty "If true, the list may be unsorted";
    var(GUIList) config bool bNeverSort "If true, the list should never be sorted";
    var(GUIList) bool bNativeSort "If true, a native qSort will be used (which breaks CompareItem delegates)";

    var(GUIList) config  eTextAlign	TextAlign "How is text Aligned in the control";

    var(GUIList) editinline editconst	    array<GUIListElem>	Elements;

    // Used by Sort.
    delegate bool CompareItem(GUIListElem ElemA, GUIListElem ElemB)
    {
        return false;
    }

    delegate bool ElementsEqual(GUIListElem ElemA, GUIListElem ElemB)
    {
        return false;
    }

    delegate SwapIndices( int indexA, int indexB )
    {
        Swap( indexA, indexB, true );
    }

    #if IG_TRIBES3 // Ryan: made sorting native
    delegate ReorderByIndices(int indices)
    {
    	ReorderItems(indices);
    }

    final native function qSort();
    final native function ReorderItems(int indices);
    #endif

    //////////////////////////////////////////////////////////////////////
    // Sorting (bubble sort)
    //////////////////////////////////////////////////////////////////////
    function Sort()
    {
        local int i, j, curHead, prevIndex;
        local bool compare;

        if( bNeverSort || !bListIsDirty )
            return;
        prevIndex=Index;

    	if( bNativeSort )
    	{
    		qSort();
    	}
    	else
    	{
    		i = 0;
    		j = 1;
    		curHead = 1;
    		while( curHead < Elements.Length )
    		{
    			compare = CompareItem( Elements[i], Elements[j] );
    			if( bSortForward ) //handles sorting in reverse
    				compare = !compare;
    			if( compare )
    			{
    				i = curHead;
    				j = i+1;
    				curHead = j;
    			}
    			else
    			{
    				if( prevIndex == j )
    					prevIndex = i;
    				else if( prevIndex == i )
    					prevIndex = j;
    				SwapIndices( i, j );
    				i--;
    				j--;
    				if( i < 0 )
    				{
    					i = curHead;
    					j = i+1;
    					curHead = j;
    				}
    			}
    		}
    	}

        bListIsDirty = false;
        SetIndex(prevIndex);
    }

    //////////////////////////////////////////////////////////////////////
    // Sorting (Reverse)
    //////////////////////////////////////////////////////////////////////
    function ReverseList()
    {
        local int i, j, prevIndex;
        prevIndex=Index;
        for( i = 0; i < Elements.Length / 2; i++ )
        {
            j = Elements.Length - i - 1;
            if( prevIndex == j )
                prevIndex = i;
            else if( prevIndex == i )
                prevIndex = j;
            SwapIndices( i, j );
        }
        bSortForward = !bSortForward;
        SetIndex(prevIndex);
    }

    ////////////////////////////////////////////////////////////////////////
    // Init component
    ////////////////////////////////////////////////////////////////////////
    function InitComponent(GUIComponent MyOwner)
    {
    	Super.InitComponent(MyOwner);

        switch (TypeOfSort)
        {
            case SORT_AlphaItem:
                CompareItem=AlphabeticalCompareItem;
                break;
            case SORT_AlphaExtra:
                CompareItem=AlphabeticalCompareExtra;
                break;
            case SORT_Numeric:
                CompareItem=NumericCompare;
                break;
            case SORT_Bool:
                CompareItem=BooleanCompare;
                break;
            case SORT_IP:
                CompareItem=IPCompare;
                break;
        }

        switch (DisplayItem)
        {
            case LIST_ELEM_Item:
                ElementsEqual=EqualsItem;
                break;
            case LIST_ELEM_ExtraData:
                ElementsEqual=EqualsObject;
                break;
            case LIST_ELEM_ExtraStrData:
                ElementsEqual=EqualsExtra;
                break;
            case LIST_ELEM_ExtraIntData:
                ElementsEqual=EqualsInt;
                break;
            case LIST_ELEM_ExtraBoolData:
                ElementsEqual=EqualsBool;
                break;
        }
    }

    function bool AlphabeticalCompare( string ElemA, string ElemB )
    {
        return ElemA > ElemB;
    }

    function bool AlphabeticalCompareItem( GUIListElem ElemA, GUIListElem ElemB )
    {
        return AlphabeticalCompare( ElemA.Item, ElemB.Item );
    }

    function bool AlphabeticalCompareExtra( GUIListElem ElemA, GUIListElem ElemB )
    {
        return AlphabeticalCompare( ElemA.ExtraStrData, ElemB.ExtraStrData );
    }

    function bool NumericCompare( GUIListElem ElemA, GUIListElem ElemB )
    {
        return ElemA.ExtraIntData > ElemB.ExtraIntData;
    }

    function bool BooleanCompare( GUIListElem ElemA, GUIListElem ElemB )
    {
        return !ElemA.ExtraBoolData && ElemB.ExtraBoolData;
    }

    function bool IPCompare( GUIListElem ElemA, GUIListElem ElemB )
    {
        // Not yet implemented!!!! Alphabetical compare used as placeholder!!!
        return AlphabeticalCompare( ElemA.ExtraStrData, ElemB.ExtraStrData );
    }

    function bool EqualsItem(GUIListElem ElemA, GUIListElem ElemB)
    {
        return ElemA.Item == ElemB.Item;
    }

    function bool EqualsObject(GUIListElem ElemA, GUIListElem ElemB)
    {
        return ElemA.ExtraData == ElemB.ExtraData;
    }

    function bool EqualsExtra(GUIListElem ElemA, GUIListElem ElemB)
    {
        return ElemA.ExtraStrData == ElemB.ExtraStrData;
    }

    function bool EqualsInt(GUIListElem ElemA, GUIListElem ElemB)
    {
        return ElemA.ExtraIntData == ElemB.ExtraIntData;
    }

    function bool EqualsBool(GUIListElem ElemA, GUIListElem ElemB)
    {
        return ElemA.ExtraBoolData == ElemB.ExtraBoolData;
    }

    // Accessor function for the items.

    event string SelectedText( int offsetIndex )
    {
        if( offsetIndex < 0 )
            offsetIndex = Index;
    	if ( (offsetIndex >=0) && (offsetIndex <Elements.Length) )
        {
            switch (DisplayItem)
            {
                case LIST_ELEM_Item:
                    return Elements[offsetIndex].item;
                    break;
                case LIST_ELEM_ExtraData:
                    if( Elements[offsetIndex].ExtraData != None )
                        return string(Elements[offsetIndex].ExtraData.Name);
                    break;
                case LIST_ELEM_ExtraStrData:
                    return Elements[offsetIndex].ExtraStrData;
                    break;
                case LIST_ELEM_ExtraIntData:
                    return string(Elements[offsetIndex].ExtraIntData);
                    break;
                case LIST_ELEM_ExtraBoolData:
                    return string(Elements[offsetIndex].ExtraBoolData);
                    break;
            }
        }
    	return "";
    }

    function Add(string NewItem, optional Object obj, optional string Str, optional int intData, optional bool bData, optional bool bDontReplace, optional bool bDontReAlign )
    {
        AddElement( CreateElement( NewItem, obj, Str, intData, bData ), bDontReplace, bDontReAlign );
    }

    function int AddElement( GUIListElem theElem, optional bool bDontReplace, optional bool bDontReAlign )
    {
        local int i;
        local bool compare;
        if( !bNeverSort && !bListIsDirty )
        {
            //insertion sort
            for( i = 0; i < Elements.Length; i++ )
            {
                if( bDontReplace && ElementsEqual( Elements[i], theElem ) )
                    return i;
                compare = CompareItem( theElem, Elements[i] );
                if( bSortForward ) //handles sorting in reverse
                    compare = !compare;
                if( compare )
                    return InsertElement( i, theElem, true, bDontReAlign );
                else if( i == Elements.Length-1 ) //handle the case where it sorts to the end of the list
                    return InsertElement( Elements.Length, theElem, true, bDontReAlign );
            }
        }
        if( bDontReplace )
        {
            i = FindElement( theElem );
            if( i >= 0 )
                return i;
        }
        return InsertElement( Elements.Length, theElem, false, bDontReAlign );
    }

    function int InsertElement( int NewIndex, optional GUIListElem theElem, optional bool bInsertSorted, optional bool bDontReAlign )
    {
        if( !bInsertSorted )
            bListIsDirty = true;
    	if ( (NewIndex<0) || (NewIndex>Elements.Length) )
            NewIndex = Elements.Length;

        Elements.Insert( NewIndex, 1 );
        Elements[NewIndex]=theElem;

    	ItemCount=Elements.Length;

    	if( bDontReAlign )
    	{
    	    if( bInsertSorted && NewIndex < Index )
    	    {
    	        Top++;
    	        Index++;
    	        OnChange(self);
    	    }
    	}
    	else
    	{
        	SetIndex(NewIndex);
        }

    	return NewIndex;
    }

    function Replace(int index, string NewItem, optional Object obj, optional string Str, optional int intData, optional bool bData)
    {
        ReplaceElement( Index, CreateElement( NewItem, obj, Str, intData, bData ) );
    }

    function ReplaceElement( int index, GUIListElem theElem )
    {
        bListIsDirty = true;
    	if ( (index<0) || (index>=Elements.Length) )
    		AddElement(theElem);
    	else
    		Elements[index]=theElem;
    }

    function Insert(int index, string NewItem, optional Object obj, optional string Str, optional int intData, optional bool bData )
    {
        InsertElement( index, CreateElement( NewItem, obj, Str, intData, bData ) );
    }

    event Swap(int IndexA, int IndexB, optional bool bIsSorting)
    {
    	local GUI.GUIListElem elem;
        if( !bIsSorting )
            bListIsDirty = true;

    	if ( (IndexA<0) || (IndexA>=Elements.Length) || (IndexB<0) || (IndexB>=Elements.Length) )
    		return;

    	elem = Elements[IndexA];
    	Elements[IndexA] = Elements[IndexB];
    	Elements[IndexB] = elem;
    }

    function string GetItemAtIndex(int i)
    {
    	if ((i<0) || (i>Elements.Length))
    		return "";

    	return Elements[i].Item;
    }

    function SetItemAtIndex(int i, string NewItem)
    {
    	if ((i<0) || (i>Elements.Length))
    		return;

    	Elements[i].Item = NewItem;
    }

    function object GetObjectAtIndex(int i)
    {
    	if ((i<0) || (i>Elements.Length))
    		return None;

    	return Elements[i].ExtraData;
    }

    function string GetExtraAtIndex(int i)
    {
    	if ((i<0) || (i>Elements.Length))
    		return "";

    	return Elements[i].ExtraStrData;
    }

    function SetExtraAtIndex(int i, string NewExtra)
    {
    	if ((i<0) || (i>Elements.Length))
    		return;

    	Elements[i].ExtraStrData = NewExtra;
    }

    function int GetExtraIntAtIndex(int i)
    {
    	if ((i<0) || (i>Elements.Length))
    		return 0;

    	return Elements[i].ExtraIntData;
    }

    function SetExtraIntAtIndex(int i, int NewExtra)
    {
    	if ((i<0) || (i>Elements.Length))
    		return;

    	Elements[i].ExtraIntData = NewExtra;
    }

    function GUIListElem GetAtIndex(int i)
    {
        local GUIListElem nothing;
    	if ((i<0) || (i>Elements.Length))
    		return nothing;
        return Elements[i];
    }

    function GUIListElem GetElement()
    {
        local GUIListElem nothing;
    	if ((Index<0) || (Index>Elements.Length))
    		return nothing;
        return Elements[Index];
    }

    function LoadFrom(GUIList Source, optional bool bClearFirst)
    {
    	local int i;

    	if (bClearfirst)
    		Clear();

    	for (i=0;i<Source.Elements.Length;i++)
    	{
    		AddElement(Source.GetAtIndex(i));
    	}
    }

    function Remove(int i, optional int Count)
    {
    	if (Count==0)
    		Count=1;

    	Elements.Remove(i, Count);

    	ItemCount = Elements.Length;

    	if( i == 0 )
    	    i = ItemCount;
    	SetIndex(i-1);
        if( MyScrollBar != None )
    	MyScrollBar.AlignThumb();
    }

    function RemoveItem(string Item)
    {
    	local int i;

    	// Work through array. If we find it, remove it (will reduce Elements.Length).
    	// If we don't, move on to next one.
    	i=0;
    	while(i<Elements.Length)
    	{
    		if(Item ~= Elements[i].Item)
    			Elements.Remove(i, 1);
    		else
    			i++;
    	}

    	ItemCount = Elements.Length;

    	SetIndex(i-1);
        if( MyScrollBar != None )
    	MyScrollBar.AlignThumb();
    }

    function Clear()
    {
    	Elements.Remove(0,Elements.Length);

    	Super.Clear();
    	OnChange(self);
    }

    function string Get()
    {
    	if ( (Index<0) || (Index>=ItemCount) )
    		return "";
    	else
    		return Elements[Index].Item;
    }

    function object GetObject()
    {
    	if ( (Index<0) || (Index>=ItemCount) )
    		return none;
    	else
    		return Elements[Index].ExtraData;
    }

    function string GetExtra()
    {
    	if ( (Index<0) || (Index>=ItemCount) )
    		return "";
    	else
    		return Elements[Index].ExtraStrData;
    }

    function int GetExtraIntData()
    {
    	if ( (Index<0) || (Index>=ItemCount) )
    		return 0;
    	else
    		return Elements[Index].ExtraIntData;
    }

    function bool GetExtraBoolData()
    {
    	if ( (Index<0) || (Index>=ItemCount) )
    		return false;
    	else
    		return Elements[Index].ExtraBoolData;
    }

    function int FindElement(GUIListElem theElem)
    {
    	local int i;
    	for (i=0;i<ItemCount;i++)
    	{
            if( ElementsEqual( Elements[i], theElem ) )
                return i;
    	}
    	return -1;
    }

    function string find(string Text, optional bool bExact, optional bool bDontSetIndex)
    {
    	local int i;
    	for (i=0;i<ItemCount;i++)
    	{
    		if (bExact)
    		{
    			if (Text == Elements[i].Item)
    			{
    				if( !bDontSetIndex )
    				    SetIndex(i);
    				return  Elements[i].Item;
    			}
    		}
    		else
    		{
    			if (Text ~=  Elements[i].Item)
    			{
    				if( !bDontSetIndex )
        				SetIndex(i);
    				return  Elements[i].Item;
    			}
    		}
    	}
    	return "";
    }

    // find an element by the 'extra' string
    // only sets the index if it finds the string
    // returns the string of the found item
    function string FindExtra (string ExtraText, optional bool bExact, optional bool bDontSetIndex )
    {
    	local int i;
    	for (i=0;i<ItemCount;i++)
    	{
    		if (bExact)
    		{
    			if (ExtraText == Elements[i].ExtraStrData)
    			{
    				if( !bDontSetIndex )
        				SetIndex(i);
    				return Elements[i].Item;
    			}
    		}
    		else
    		{
    			if (ExtraText ~=  Elements[i].ExtraStrData)
    			{
    				if( !bDontSetIndex )
        				SetIndex(i);
    				return Elements[i].Item;
    			}
    		}
    	}
    	return "";
    }

    #if IG_TRIBES3	// michaelj:  Integrated UT2004's FindIndex function
    function int FindIndex(string Test, optional bool bExact, optional bool bExtra, optional Object TestObject)
    {
    	local int i;

    	if (TestObject != None)
    	{
    		for (i = 0; i < Elements.Length; i++)
    			if ( TestObject == Elements[i].ExtraData )
    				return i;
    	}

    	else if (Test != "")
    	{
    		if (bExtra)
    		{
    			for (i = 0; i < Elements.Length; i++)
    				if ( (bExact && Elements[i].ExtraStrData == Test) || (!bExact && Elements[i].ExtraStrData ~= Test) )
    					return i;
    		}

    		else
    		{
    			for ( i = 0; i < Elements.Length; i++)
    				if ( (bExact && Elements[i].Item == Test) || (!bExact && Elements[i].Item ~= Test) )
    					return i;
    		}
    	}

    	return -1;
    }
    #endif

    defaultproperties
    {
    	bSortForward=True
    	bListIsDirty=false
    	bNeverSort=false
    	TypeOfSort=SORT_AlphaItem
    	bNativeSort=true
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 16:02:10.000 - Creation time: st 23.5.2018 00:10:43.811 - Created with UnCodeX