Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Vehicles.SHover

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178

    class SHover extends Engine.SVehicle
    	abstract
    	native;

    cpptext
    {
    #ifdef WITH_KARMA
    	// Actor interface.
    	virtual UBOOL Tick(FLOAT DeltaTime, enum ELevelTick TickType);
    	virtual void PostNetReceive();

    	// SVehicle interface.
    	virtual void UpdateVehicle(FLOAT DeltaTime);

    	// SHover interface.
    	virtual void PackState();
    #endif
    }

    var		vector				FrontThrustOffset;
    var		vector				RearThrustOffset;

    var()	float				HoverSoftness;
    var()	float				HoverPenScale;
    var()	float				HoverCheckDist;

    var()	float				UprightStiffness;
    var()	float				UprightDamping;

    var()	float				MaxThrust;
    var()	float				MaxSteerTorque;
    var()	float				ForwardDampFactor;
    var()	float				LateralDampFactor;
    var()	float				SteerDampFactor;
    var()	float				PitchTorqueFactor;
    var()	float				PitchDampFactor;
    var()	float				BankTorqueFactor;
    var()	float				BankDampFactor;

    var()	float				StopThreshold;

    // MPH meter
    var		material			MPHMeterMaterial;
    var()	float				MPHMeterPosX;
    var()	float				MPHMeterPosY;
    var()	float				MPHMeterScale;
    var()	float				MPHMeterSizeY;

    // Internal
    var		float				BikeMPH;

    var		float				OutputThrust;
    var		float				OutputTurn;

    // Replicated
    struct native HoverbikeState
    {
    	var KRBVec				ChassisPosition;
    	var Quat				ChassisQuaternion;
    	var KRBVec				ChassisLinVel;
    	var KRBVec				ChassisAngVel;

    	var float				ServerThrust;
    	var	float				ServerTurn;

    	var int					bNewState;
    };

    var		HoverbikeState		BikeState;
    var		KRigidBodyState		ChassisState;
    var		bool				bNewBikeState;

    replication
    {
    	unreliable if(Role == ROLE_Authority)
    		BikeState;
    }

    simulated event bool KUpdateState(out KRigidBodyState newState)
    {
    	// This should never get called on the server - but just in case!
    	if(Role == ROLE_Authority || !bNewBikeState)
    		return false;

    	newState = ChassisState;
    	bNewBikeState = false;

    	return true;
    	//return false;
    }

    simulated function PostNetBeginPlay()
    {
    	local vector RotX, RotY, RotZ;
    	local KarmaParams kp;
    	local KRepulsor rep;

        GetAxes(Rotation,RotX,RotY,RotZ);

    	// Spawn and assign 'repulsors' to hold bike off the ground
    	kp = KarmaParams(KParams);
    	kp.Repulsors.Length = 2;

    	rep = spawn(class'KRepulsor', self,, Location + FrontThrustOffset.X * RotX + FrontThrustOffset.Y * RotY + FrontThrustOffset.Z * RotZ);
    	rep.SetBase(self);
    	kp.Repulsors[0] = rep;

    	rep = spawn(class'KRepulsor', self,, Location + RearThrustOffset.X * RotX + RearThrustOffset.Y * RotY + RearThrustOffset.Z * RotZ);
    	rep.SetBase(self);
    	kp.Repulsors[1] = rep;

        Super.PostNetBeginPlay();
    }

    simulated event Destroyed()
    {
    	local KarmaParams kp;

    	// Destroy repulsors
    	kp = KarmaParams(KParams);
    	kp.Repulsors[0].Destroy();
    	kp.Repulsors[1].Destroy();

    	Super.Destroyed();
    }

    simulated event SVehicleUpdateParams()
    {
    	local KarmaParams kp;

    	Super.SVehicleUpdateParams();

    	kp = KarmaParams(KParams);

    	kp.Repulsors[0].Softness = HoverSoftness;
    	kp.Repulsors[0].PenScale = HoverPenScale;
    	kp.Repulsors[0].CheckDist = HoverCheckDist;

    	kp.Repulsors[1].Softness = HoverSoftness;
    	kp.Repulsors[1].PenScale = HoverPenScale;
    	kp.Repulsors[1].CheckDist = HoverCheckDist;

    	KSetStayUprightParams( UprightStiffness, UprightDamping );
    }

    function DrawHUD(Canvas Canvas)
    {
    	local Color WhiteColor;
    	local float XL, YL;

    	Super.DrawHUD(Canvas);

    	WhiteColor = class'Canvas'.Static.MakeColor(255,255,255);
    	Canvas.DrawColor = WhiteColor;

    	Canvas.Style = ERenderStyle.STY_Normal;
    	Canvas.StrLen("TEST", XL, YL);

    	// Draw rev meter
    	Canvas.SetPos(MPHMeterPosX * Canvas.ClipX, MPHMeterPosY * Canvas.ClipY);
    	Canvas.DrawTileStretched(MPHMeterMaterial, (BikeMPH/MPHMeterScale) * Canvas.ClipX, MPHMeterSizeY * Canvas.ClipY);

    	Canvas.SetPos( MPHMeterPosX * Canvas.ClipX, (MPHMeterSizeY + MPHMeterPosY) * Canvas.ClipY + YL );
        Canvas.Font = class'HUD'.Static.GetConsoleFont(Canvas);
    	Canvas.DrawText(BikeMPH);
    }

    defaultproperties
    {
    	bSpecialHUD=true

    	MPHMeterMaterial=Material'InterfaceContent.BorderBoxD'
    	MPHMeterPosX=0.01
    	MPHMeterPosY=0.9
    	MPHMeterScale=70.0
    	MPHMeterSizeY=0.05
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 16:02:34.000 - Creation time: st 23.5.2018 00:10:47.044 - Created with UnCodeX