Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

# Gameplay.MPTerritory

00001 00002 00003 00004 00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431
00432
00433
00434
00435
00436
00437
00438
00439
00440
00441
00442
00443
00444
00445
00446
00447
00448
00449
00450
00451
00452
00453
00454
00455
00456
00457
00458
00459
00460
00461
00462
00463
00464
00465
00466
00467
00468
00469
00470
00471
00472
00473
00474
00475
00476
00477
00478
00479
00480
00481
00482
00483
00484
00485
00486
00487
00488
00489
00490
00491
00492
00493
00494
00495
00496
00497
00498
00499
00500
00501
00502
00503
00504
00505
00506
00507
00508
00509
00510
00511
00512
00513
00514
00515
00516
00517
00518
00519
00520
00521
00522
00523
00524
00525
00526
00527
00528
00529
00530
00531
00532
00533
00534
00535
00536
00537
00538
00539
00540
00541
00542
00543
00544
00545
00546
00547
00548
00549
00550
00551
00552
00553
00554
00555
00556
00557
00558
00559
00560
00561
00562
00563
00564
00565
00566
00567
00568
00569
00570
00571
00572
00573
00574
00575
00576
00577
00578
00579
00580
00581
00582
00583
00584
00585
00586
00587
00588
00589
00590
00591
00592
00593
00594
00595
00596
00597
00598
00599
00600
00601
00602
00603
00604
00605
00606
00607
00608
00609
00610
00611
00612
00613
00614
00615
00616
00617
00618
00619
00620
00621
00622
00623
00624
00625
00626
00627
00628
00629
00630
00631
00632
00633
00634
00635
00636
00637
00638
00639
00640
00641
00642
00643
00644
00645
00646
00647
00648
00649
00650
00651
00652
00653
00654
00655
00656
00657
00658
00659
00660
00661
00662
00663
00664
00665
00666
00667
00668
00669
00670
00671
00672
00673
00674
00675
00676
00677
00678
00679
00680
00681
00682
00683
00684
00685
00686
00687
00688
00689
00690
00691
00692
00693
00694
00695
00696
00697
00698
00699
00700
00701
00702
00703
00704
00705
00706
00707
00708
00709
00710
00711
00712
00713
00714
00715
00716
00717
00718
00719
00720
00721
00722
00723
00724
00725
00726
00727
00728
00729
00730
00731
00732
00733
00734
00735
00736
00737
00738
00739
00740
00741
00742
00743
00744
00745
00746
00747
00748
00749

    class MPTerritory extends MPArea implements IRepairClient;

    var() int			teamConquerScore			"The number of points a team receives for conquering.  If bReconquerable is false, this amount is subtracted if a team loses the territory.";
    var() int			conquerTime					"The amount of uninterrupted time it takes to conquer the territory";
    var() float			individualConquerBonusScale "Each additional friend conquering a territory scales the conquering speed by this amount (1 has no effect)";
    var() int			minimumConquerers			"The mininum number of people needed in order to start conquering this territory";
    var() float			conquerInterval				"The frequency with which the territory considers who is conquering it";
    var() bool			bConquerOnce				"When true, the territory can only be conquered once";
    var bool			bReconquerable				"Can the Territory be conquered again for points after it has already been conquered?";
    var bool			bReconquerNeedsPlayers		"If bReconquerable is true, does reconquering require players to be in the Territory?  If false, a team will reconquer their territory even when none of their players are in it.";
    var() editdisplay(displayActorLabel)
    	  editcombotype(enumBaseInfo)
    	  BaseInfo		ownerBase					"An optional BaseInfo to which this Territory is attached.  Capturing the Territory also captures this base.";
    var() class<Engine.LocalMessage> TerritoryMessageClass;

    var TeamInfo		conqueringTeam;
    var TeamInfo		ownerTeam;
    var TeamInfo		previousOwnerTeam;
    var float			currentConqueringTime;

    var bool			bConquering;
    var bool			bLocalConquering;
    var bool			bContesting;
    var bool			bLocalContesting;
    var bool			bIdle;
    var bool			bLocalIdle;
    var bool			bConquered;
    var bool			bLocalConquered;
    var bool			bDelayPermanentConquer;

    var (Skins) Material conqueringSkin;
    var (Skins) Material contestedSkin;
    var (Skins) Material idleSkin;
    var (Skins) int titleSkinIndex;

    var (EffectEvents) Name conqueringEffectEvent			"The name of an effect event that loops on the territory when conquering";
    var (EffectEvents) Name startedConqueringEffectEvent	"The name of an effect event that plays once on the territory when conquering";
    var (EffectEvents) Name contestingEffectEvent			"The name of an effect event that loops on the territory when contesting";
    var (EffectEvents) Name startedContestingEffectEvent	"The name of an effect event that plays once on the territory when contesting";
    var (EffectEvents) Name idleEffectEvent					"The name of an effect event that loops on the territory when conquering";
    var (EffectEvents) Name conqueredEffectEvent			"The name of an effect event that plays once on the territory when conquered";

    var RepairRadius rr;
    var() Name socketTarget								"The name of the socket to use when attaching the tendril effect to a target actor";

    // Stats
    var(Stats)	class<Stat>	conquerStat				"Stat awarded when a player conquers a territory";

    replication
    {
    	reliable if (Role == ROLE_Authority)
    		bConquering, bContesting, bIdle, bConquered, conquerTime, currentConqueringTime;
    }

    function OnConquered()
    {
    }

    simulated function PostBeginPlay()
    {
    	Super.PostBeginPlay();

    	if (Level.NetMode != NM_Client)
    		areaTrigger.setTriggerFrequency(conquerInterval);

    	rr = new class'RepairRadius'(self, , Location);
    }

    simulated function PostNetReceive()
    {
    	Super.PostNetReceive();
    	updateEffects();
    }

    simulated function destroyed()
    {
    	super.destroyed();
    	cleanup();
    }

    function cleanup()
    {
    	Super.cleanup();

    	if (rr != None)
    		rr.destroy();
    }

    // Awkward effects handling
    simulated function updateEffects()
    {
    	if (bConquering != bLocalConquering)
    	{
    		bLocalConquering = bConquering;
    		if (bConquering)
    		{
    			SetSkin(conqueringSkin);
    			TriggerEffectEvent(conqueringEffectEvent);
    			TriggerEffectEvent(startedConqueringEffectEvent);

    			// Start animation going down from whatever position it's already in

    			AnimBlendParams(1, 1);
    			//Log("Playing down animation at rate "$ (GetAnimLength('Down') / conquerTime));
    			PlayAnim('Down', GetAnimLength('Down') / conquerTime,,1);

    			if (currentConqueringTime > 0)
    			{
    				//Log("Continuing at frame "$100 * currentConqueringTime / conquerTime);
    				SetAnimFrame(100 * currentConqueringTime / conquerTime,1,1);
    			}
    		}
    		else
    		{
    			// Reset it
    			AnimBlendParams(1, 1);
    			//Log("Playing up animation");
    			//PlayAnim('Up',,, 1);
    			SetSkin(idleSkin);
    			UnTriggerEffectEvent(conqueringEffectEvent);
    			//AnimBlendParams(1, 1);
    			if (currentConqueringTime > 0 && currentConqueringTime < conquerTime)
    			{
    				//Log("Pausing animation at "$100 * currentConqueringTime / conquerTime);
    				FreezeAnimAt(100 * currentConqueringTime / conquerTime, 1);
    			}
    		}
    	}

    	if (bContesting != bLocalContesting)
    	{
    		bLocalContesting = bContesting;
    		if (bContesting)
    		{
    			SetSkin(contestedSkin);
    			UnTriggerEffectEvent(conqueringEffectEvent);
    			TriggerEffectEvent(contestingEffectEvent);
    			TriggerEffectEvent(startedContestingEffectEvent);;
    		}
    		else
    		{
    			UnTriggerEffectEvent(contestingEffectEvent);
    			if (!bConquering)
    				SetSkin(idleSkin);
    		}
    	}

    	if (bConquered != bLocalConquered)
    	{
    		if (!bReconquerable)
    			SetSkin(idleSkin);
    		bLocalConquered = bConquered;
    		TriggerEffectEvent(conqueredEffectEvent);

    		// Quickly send the animation to the top
    		AnimBlendParams(1, 1);
    		PlayAnim('Up',,, 1);
    	}

    	if (bIdle != bLocalIdle)
    	{
    		bLocalIdle = bIdle;
    		if (bIdle)
    		{
    			SetSkin(idleSkin);
    			UnTriggerEffectEvent(conqueringEffectEvent);
    			TriggerEffectEvent(idleEffectEvent);
    		}
    	}
    }

    function OnAreaEntered(Character c)
    {
    	//c.ReceiveLocalizedMessage( class'MPTerritoryMessages', 1 );
    }

    function OnAreaExited(Character c)
    {
    	//c.ReceiveLocalizedMessage( class'MPTerritoryMessages', 2 );
    }

    function OnAreaTick()
    {
    	// Do nothing
    }

    function setTeam(TeamInfo t)
    {
    	previousOwnerTeam = ownerTeam;
    	ownerTeam = t;
    	Super.setTeam(t);

    	if (previousOwnerTeam != ownerTeam && ownerBase != None)
    		ownerBase.team = t;
    }

    function bool shouldInteractWith(Character c)
    {
    	return !c.bDontInteractWithTerritories;
    }

    auto state Ownerless
    {
    	function BeginState()
    	{
    		//Log(self$" entered Ownerless state");
    		ownerTeam = None;
    		SetSkin(IdleSkin);
    		determineInitialState();

    		bIdle = true;
    		updateEffects();
    	}

    	function EndState()
    	{
    		bIdle = false;
    		updateEffects();
    	}

    	function OnAreaEntered(Character c)
    	{
    		if (!shouldInteractWith(c))
    			return;

    		Global.OnAreaEntered(c);

    		//Log("Character entered, numPlayers = "$areaTrigger.numPlayers());

    		// If minimum number of conquerers is satisfied, start conquering
    		if (areaTrigger.numPlayers(c.team()) >= minimumConquerers)
    		{
    			//Log(self$" to Conquering from Ownerless in OnAreaEntered()");
    			GotoState('Conquering');
    		}
    	}

    	function determineInitialState()
    	{
    		local TeamInfo t;
    		t = areaTrigger.onlyRemainingTeam();

    		// If there isn't a single remaining team and there are players inside, then it's contested
    		if (t == None && areaTrigger.numPlayers() > 0)
    		{
    			//Log(self$" to Contested from Ownerless in determineInitialState()");
    			GotoState('Contested');
    			return;
    		}

    		// If there's only one team, start conquering if applicable
    		else if (t != None && (t != team() || (t == team() && bReconquerable)))
    		{
    			//Log(self$" to Conquering from Ownerless in determineInitialState()");
    			GotoState('Conquering');
    			return;
    		}

    		// Check to see if the team has been set in the editor; if it has been,
    		// start in the conquered state
    		else if (team() != None)
    		{
    			// Check for bConquerOnce, and if set, effectively delay it
    			if (bConquerOnce)
    				bDelayPermanentConquer = true;
    			setTeam(team());
    			//Log(self$" to Conquered from Ownerless in determineInitialState()");
    			GotoState('Conquered');
    			return;
    		}

    		// Otherwise, remain Ownerless
    		//Log(self$" remaining ownerless");
    	}
    }

    // The Territory has only one team in it, but more players are needed
    state AwaitingTeammates
    {
    	function BeginState()
    	{
    		//Log(self$" entered AwaitingTeammates state");
    	}

    	function OnAreaEntered(Character c)
    	{
    		if (!shouldInteractWith(c))
    			return;

    		Global.OnAreaEntered(c);

    		// If an enemy entered, the territory becomes contested
    		if (c.team() != conqueringTeam)
    		{
    			//Log(self$" to Contested from AwaitingTeammates");
    			GotoState('Contested');
    			return;
    		}

    		// Check to see if there are now enough friendlies
    		if (areaTrigger.numPlayers(conqueringTeam) >= minimumConquerers)
    		{
    			//Log(self$" to Conquering from AwaitingTeammates");
    			GotoState('Conquering');
    		}
    	}
    }

    // The Territory is in the process of being conquered
    state Conquering
    {
    	function BeginState()
    	{
    		conqueringTeam = areaTrigger.onlyRemainingTeam();
    		//Log("Conquering state entered with conqueringTeam = "$conqueringTeam);

    		if (conqueringTeam == None)
    		{
    			// I believe this happens if the player started conquering an empty territory
    		}

    		// Check to see if there are enough players to conquer it
    		if (areaTrigger.numPlayers(conqueringTeam) < minimumConquerers)
    		{
    			//Log(self$" to AwaitingTeammates from Conquering");
    			GotoState('AwaitingTeammates');
    			return;
    		}

    		Level.Game.BroadcastLocalized(self, TerritoryMessageClass, 2, conqueringTeam);
    		dispatchMessage(new class'MessageTerritoryConquering'(label));

    		bConquering = true;
    		updateEffects();
    	}

    	function EndState()
    	{
    		bConquering = false;
    		updateEffects();
    	}

    	function allocatePoints()
    	{
    		// Award points
    		Level.Game.BroadcastLocalized(self, TerritoryMessageClass, 0, conqueringTeam);
    		scoreTeam(teamConquerScore, conqueringTeam);

    		// If the territory isn't reconquerable, remove points from the conquered team
    		if (!bReconquerable && previousOwnerTeam != None && previousOwnerTeam != ownerTeam)
    			scoreTeam(-teamConquerScore, previousOwnerTeam);

    		// Somehow divvy up stats among conquerers here
    	}

    	function OnAreaTick()
    	{
    		local int i;
    		local float conquerBonusScale;

    		// Manually calculate individualConquerBonusScale ^ areaTrigger.numPlayers(conqueringTeam)
    		// The ^ operator doesn't seem to accept floats
    		conquerBonusScale = individualConquerBonusScale;
    		for (i=1; i<areaTrigger.numPlayers(conqueringTeam); i++)
    			conquerBonusScale *= conquerBonusScale;

    		// Increase conquering time
    		currentConqueringTime += conquerInterval * conquerBonusScale;
    		//Log("TERRITORY:  currentConqueringTime = "$currentConqueringTime$", bonusScale = "$conquerBonusScale);

    		// If enough time has elapsed to conquer it
    		if (currentConqueringTime >= conquerTime)
    		{
    			// The Territory was conquered
    			setTeam(conqueringTeam);
    			allocatePoints();
    			dispatchMessage(new class'MessageTerritoryConquered'(label, ownerTeam.Label));
    			OnConquered();

    			//Log(self$" to Conquered from Conquering in onAreaTick()");
    			GotoState('Conquered');
    		}
    	}

    	function OnAreaEntered(Character c)
    	{
    		if (!shouldInteractWith(c))
    			return;

    		Global.OnAreaEntered(c);

    		// If an enemy entered, the territory becomes contested
    		if (c.team() != conqueringTeam)
    		{
    			//Log(self$" to Contested from Conquering in OnAreaEntered()");
    			GotoState('Contested');
    		}
    	}

    	function OnAreaExited(Character c)
    	{
    		if (!shouldInteractWith(c))
    			return;

    		Global.OnAreaExited(c);

    		//Log(self$" had character exit "$c$" with numPlayers left = "$areaTrigger.numPlayers());
    		// Is the exiting player the last player?
    		if (areaTrigger.numPlayers() == 0)
    		{
    			if (ownerTeam == None)
    			{
    				//Log(self$"  to Ownerless from Conquering in OnAreaExited()");
    				currentConqueringTime = 0;
    				GotoState('Ownerless');
    				return;
    			}
    			else
    			{
    				// Just return to the conquered state; whoever owned it still owns it
    				//Log(self$" to Conquered from Conquering in OnAreaExited()");
    				currentConqueringTime = 0;
    				bDelayPermanentConquer = true;
    				GotoState('Conquered');
    				return;
    			}
    		}

    		// There's at least 1 player left.  Was the exiting player needed in order to keep conquering?
    		if ( areaTrigger.numPlayers(conqueringTeam) < minimumConquerers )
    		{
    			//Log(self$" to AwaitingTeammates from Conquering in OnAreaExited()");
    			GotoState('AwaitingTeammates');
    		}
    	}
    }

    state Contested
    {
    	function BeginState()
    	{
    		//Log(self$" entered contested state");
    		Level.Game.BroadcastLocalized(self, TerritoryMessageClass, 1, ownerTeam);
    		//areaTrigger.debugOutput();
    		dispatchMessage(new class'MessageTerritoryContested'(label));
    		bContesting = true;
    		bIdle = false;
    		updateEffects();
    	}

    	function EndState()
    	{
    		bContesting = false;
    		updateEffects();
    	}

    	function OnAreaExited(Character c)
    	{
    		local TeamInfo onlyRemainingTeam;

    		if (!shouldInteractWith(c))
    			return;

    		Global.OnAreaExited(c);

    		onlyRemainingTeam = areaTrigger.onlyRemainingTeam();

    		if (onlyRemainingTeam == None)
    		{
    			// There's more than one remaining team
    			// Check to make sure there are still people in the territory; if there aren't,
    			// something has gone wrong
    			if (areaTrigger.numPlayers() == 0)
    			{
    				Log("Territory error:  Area emptied while in contested state");
    			}
    			//Log(self$" continues to be contested despite the departure of "$c);
    			return;
    		}

    		// There's only one remaining team
    		// If the remaining team is a new team, or if there's already a team conquering, continue
    		// conquering; otherwise, just stay conquered
    		if (onlyRemainingTeam != None && (onlyRemainingTeam != ownerTeam)) // || conqueringTeam != None))
    		{
    			//Log(self$" to Conquering from Contested in OnAreaExited()");
    			//Log("ort = "$onlyRemainingTeam$", owner = "$ownerTeam$", conquer = "$conqueringTeam);
    			GotoState('Conquering');
    		}
    		else
    		{
    			//Log(self$" to Conquered from Contested in OnAreaExited() due to exit of "$c);
    			bDelayPermanentConquer = true;
    			GotoState('Conquered');
    		}
    	}
    }

    // The Territory has been conquered but is not reconquerable, i.e. you can't
    // keep scoring points by maintaining possession of it
    state Conquered
    {
    	function BeginState()
    	{
    		currentConqueringTime = 0;
    		//Log(self$" entered conquered state due to team "$conqueringTeam);
    		conqueringTeam = None;

    		// Manage any lattice that might be present
    		expandLattice(ownerTeam);
    		if (previousOwnerTeam != None)
    			contractLattice(previousOwnerTeam);

    		// Allow base to be spawned at
    		//if (ownerTeam != None && ownerBase != None)
    		//	ownerTeam.addBase(ownerBase);

    		// Update effects
    		bConquered = !bConquered;
    		updateEffects();

    		// If it's only conquerable once, send it to a locked state
    		if (bConquerOnce)
    		{
    			if (bDelayPermanentConquer)
    			{
    				bDelayPermanentConquer = false;
    				return;
    			}
    			//Log(self$" to PermanentlyConquered from Conquered");
    			GotoState('PermanentlyConquered');
    			return;
    		}

    		// If it's reconquerable, keep on conquering
    		//if (bReconquerable)
    		//{
    			//Log(self$" to Conquering from Conquered due to bReconquerable");
    		//	GotoState('Conquering');
    		//}
    	}
    	function OnAreaEntered(Character c)
    	{
    		if (!shouldInteractWith(c))
    			return;

    		Global.OnAreaEntered(c);

    		// If an enemy entered, the territory becomes conquering or contested
    		if (c.team() != team())
    		{
    			// Conquering if this player's team is the only one left or if this is the first player
    			// to enter the territory
    			if (c.team() == areaTrigger.onlyRemainingTeam(c))
    			{
    				//Log(self$" to Conquering from Conquered in OnAreaEntered() with team = "$team());
    				GotoState('Conquering');
    			}
    			else
    			{
    				//Log(self$" to Contested from Conquered in OnAreaEntered() due to "$c$" and ort = "$areaTrigger.onlyRemainingTeam());
    				GotoState('Contested');
    			}
    		}
    	}

    	function EndState()
    	{
    		// Don't allow this base to be considered a spawn area
    		//if (ownerTeam != None && ownerBase != None)
    		//	ownerTeam.removeBase(ownerBase);
    	}

    	// Don't show repair tendrils when conquered
    	function bool canRepair()
    	{
    		return false;
    	}
    }

    // The Territory has been conquered and can never be conquered again
    state PermanentlyConquered
    {
    	function BeginState()
    	{
    		//Log(self$" has been permanently conquered");
    		bIdle = true;
    		updateEffects();
    	}

    	function OnAreaEntered(Character c)
    	{
    		// Do nothing
    	}

    	function OnAreaExited(Character c)
    	{
    		// Do nothing
    	}

    	// Don't show repair tendrils when permanently conquered
    	function bool canRepair()
    	{
    		return false;
    	}
    }

    function enumBaseInfo(Engine.LevelInfo l, Array<BaseInfo> a)
    {
    	local BaseInfo b;

    	ForEach DynamicActors(class'BaseInfo', b)
    	{
    		a[a.length] = b;
    	}
    }

    simulated function setSkin(Material skin)
    {
    	skins[titleSkinIndex] = skin;
    }

    // Tendrils
    // IRepairClient
    simulated function bool canRepair(Rook r)
    {
    	// Only connect to living Characters
    	if (Character(r) == None || !r.isAlive())
    		return false;

    	return true;
    }

    simulated function float getRepairRadius()
    {
    	return areaTriggerClass.default.CollisionRadius;
    }

    simulated function beginRepair(Rook r)
    {
    }

    simulated function endRepair(Rook r)
    {

    }

    simulated function Pawn getFXOriginActor()
    {
    	return self;
    }

    simulated function Vector getFXTendrilOrigin(Vector targetPos)
    {
    	return Location;
    }

    simulated function Vector getFXTendrilTarget(Actor target)
    {
    	local coords socketCoords;

    	// Make sure this is a character
    	if (socketTarget != '' && Character(target) != None)
    	{
    		socketCoords = target.getBoneCoords(socketTarget, true);

    		if (socketCoords.Origin != Vect(0, 0, 0))
    			return socketCoords.Origin;
    	}

    	// Otherwise just return location
    	return target.unifiedGetPosition();
    }

    simulated function bool canStartFXTendril()
    {
    	return true;
    }

    simulated function onTendrilCreate(RepairTendril t)
    {
    	local Character c;
    	local BeamEmitter beam;
    	local Color col;

    	c = Character(t.target);
    	if (c != None)
    	{
    		if (c.team() != None)
    		{
    			col = c.team().territoryTendrilColor;

    			beam = t.getBeamEmitter();
    			if (beam != None)
    			{
    				beam.UseColorScale = true;
    				beam.ColorScale.Length = 2;
    				beam.ColorScale[0].RelativeTime = 0;
    				beam.ColorScale[0].Color = col;
    				beam.ColorScale[1].RelativeTime = 1;
    				beam.ColorScale[1].Color = col;
    			}
    		}
    	}
    }

    // End IRepairClient

    defaultproperties
    {
    	DrawType				= DT_StaticMesh
    	StaticMesh				= StaticMesh'Editor_res.TexPropCube'
    	bCollideActors			= true
    	bCollideWorld			= true
    //	bBlockActors			= true
    	bMovable				= false
    	NetUpdateFrequency		= 2
    	bNetNotify				= true
    	bAlwaysRelevant			= true

    	CollisionRadius			= 200
    	CollisionHeight			= 200

    	teamConquerScore		= 1
    	conquerTime				= 10
    	conquerInterval			= 1
    	individualConquerBonusScale = 1
    	minimumConquerers		= 1
    	bReconquerable			= false
    	bReconquerNeedsPlayers	= false
    	bConquerOnce			= false
    	TerritoryMessageClass	= class'MPTerritoryMessages'

    	conqueringEffectEvent			= Conquering
    	startedConqueringEffectEvent	= StartedConquering
    	contestingEffectEvent			= Contesting
    	startedContestingEffectEvent	= StartedContesting
    	idleEffectEvent					= Idle
    	conqueredEffectEvent			= Conquered
    	idleAnim				= Idle

    	contestedSkin			= Material'BaseObjects.CS_ContestedShader'
    	conqueringSkin			= Material'BaseObjects.CS_CapturedShader'
    	idleSkin				= Material'BaseObjects.CS_Dormant'
    	titleSkinIndex			= 1
    	socketTarget			= "capture"
    }

Overview | Package | Class | Source | Class tree | Glossary | UnrealScript Documentation
previous class next class | frames no frames

Class file time: ne 5.9.2004 15:53:20.000 - Creation time: st 23.5.2018 00:10:45.999 - Created with UnCodeX